Hi all,

I'm hoping that someone out there is using the new PPT functionality in 7.6.8 and could help me with using this in conjunction with a PPT template to produce a presentation with multiple report-driven slides.

I have a PPT presentation that I have saved to my apps directory as an MHT file. I am able to successfully use this template in reports where I am inserting single slides.

However, when attempting to insert multiple slides using multiple, different requests, all of my attempts thus far have failed for various reasons. Below are the four major attempts I have tried, using the standard CAR table. Of course, you will need to create your own PPT template and rename my PPT_Test.MHT for these to run on your own system.

The problems I'm seeing are included at the top of each as a comment. Thank you in advance for any advice offered.


-*============== BEGIN TEST1 =================
-* DUPLICATES EACH REQUEST ON SECOND SLIDE ITERATION.
-* IF ONE OF THE SLIDES CONTAINS A GRAPH (FORMATTED AS GIF OR JPG), THAT SLIDE IS
-* REPEATED 8 OR 10 TIMES.
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'ENGLAND';
ON TABLE PCHOLD FORMAT PPT OPEN TEMPLATE 'PPT_Test' SLIDENUMBER 3
END
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'FRANCE';
ON TABLE PCHOLD FORMAT PPT CLOSE TEMPLATE 'PPT_Test' SLIDENUMBER 5
END
-EXIT
-*============== END TEST1 =================

-*============== BEGIN TEST2 =================
-* DUPLICATES EACH REQUEST ON SECOND SLIDE ITERATION
-* IF ONE OF THE SLIDES CONTAINS A GRAPH (FORMATTED AS GIF OR JPG), THAT SLIDE IS
-* REPEATED 8 OR 10 TIMES.
SET COMPOUND = OPEN
-RUN
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'ENGLAND';
ON TABLE PCHOLD FORMAT PPT TEMPLATE 'PPT_Test' SLIDENUMBER 3
END
-RUN
SET COMPOUND = CLOSE
-RUN
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'FRANCE';
ON TABLE PCHOLD FORMAT PPT TEMPLATE 'PPT_Test' SLIDENUMBER 5
END
-RUN
-EXIT
-*============== END TEST2 =================

-*============== BEGIN TEST3 =================
-* RETURNS BACK-TO-BACK SLIDES BEGINNING ON SLIDE 5. SHOULD RETURN
-* ON SLIDE 3 AND SLIDE 5.
-* IF ONE OF THE SLIDES CONTAINS A GRAPH ON GIF/JPG, THAT SLIDE IS
-* REPEATED 8 OR 10 TIMES.
COMPOUND LAYOUT PCHOLD FORMAT PPT
SECTION=S1, LAYOUT=ON, MERGE=OFF, ORIENTATION=LANDSCAPE, $
PAGELAYOUT=1, $
COMPONENT=England, TYPE=REPORT, POSITION=(1 1), DIMENSION=(4 4), $
PAGELAYOUT=2, $
COMPONENT=France, TYPE=REPORT, POSITION=(1 1), DIMENSION=(4 4), $
END
SET COMPONENT=England
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'ENGLAND';
ON TABLE HOLD FORMAT PPT OPEN TEMPLATE 'PPT_Test' SLIDENUMBER 3
END
SET COMPONENT=France
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'FRANCE';
ON TABLE HOLD FORMAT PPT CLOSE TEMPLATE 'PPT_Test' SLIDENUMBER 5
END
COMPOUND END
-EXIT
-*============== END TEST3 =================

-*============== BEGIN TEST4 =================
-* WORKS PERFECTLY WITH TWO SLIDES, BUT NOT, OF COURSE, WITH MORE
-* DUE TO THE PROBLEM OF USING THE SAME HOLD NAME. I HAVE ALSO ATTEMPTED
-* TO 'MORE' THESE TOGETHER USING DIFFERENT HOLD NAMES WITHOUT SUCCESS.
APP HOLD SESSION
APP FI PPTCOMP DISK PPTCOMP.MHT
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'FRANCE';
ON TABLE HOLD AS PPTCOMP1 FORMAT PPT TEMPLATE 'PPT_Test' SLIDENUMBER 3
END
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'ITALY';
ON TABLE HOLD AS PPTCOMP2 FORMAT PPT TEMPLATE 'PPT_Test' SLIDENUMBER 5
END
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'ENGLAND';
ON TABLE PCHOLD FORMAT PPT TEMPLATE 'PPTCOMP' SLIDENUMBER 7
END
-EXIT
-*============== END TEST4 =================

This message has been edited. Last edited by: Kerry,

Michael,

I have not tried the PPT templates myself but I would hazard a guess that the usage is the same as using Excel template functionality, where by you hold the intermediate PPTs as template formats themselves.

Search the forum for EXCEL TEMPLATE and you will, no doubt, find many a post relating usage.

Good luck

T

The issue is actually to do with the way IB have implemented the
template feature for PowerPoint compound reports.

The way it works is very simple but totally unlike it is actually
implemented in PowerPoint.

In PowerPoint different sheets can use different masters within a template
and each one can be totally different.
Each master in PPT 2003 can consist of exactly 1 master and 1 master title sheet.

However within WebFOCUS you can only apply 1 template SHEETNUMBER to a report
otherwise you get exactly the results that you are seeing.

If you look at the composer tool you will see that you apply the sheet number
at document level and not at report level.

The same rule applies when you code a compound PDF manually as in your examples.

HOWEVER any styling that you want to apply MUST be in the Master sheet and not
the Master Title sheet if using PPT 2003.
(WebFOCUS does accept PPT 2007 masters with the new method of master and
multiple layout sheets, but it treats them exactly like PPT 2003).

Think of it this way.

Where you have a multi-page template for WebFOCUS the target sheet is where you want
the WebFOCUS content to be inserted, WebFOCUS will insert multiple sheets at that point
based on the template Master sheet.

Any sheets before that point or any sheets after the last sheet inserted by WebFOCUS are for
any static content that you wish to have, if using a PPT 2003 or 2007 template then the output is
exactly what was on that sheet in the template file, both layout and content.

Any content that was on the sheet used as the SHEETNUMBER in your request is erased
and you get the template master with the WebFOCUS inserted content.

Also very important is that content sizing is absolutely required as overflow can also cause
pages to appear multiple times as well (part of your graph issue I would think).

quote:

APP HOLD SESSION
APP FI PPTCOMP DISK PPTCOMP.MHT
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'FRANCE';
ON TABLE HOLD AS PPTCOMP1 FORMAT PPT TEMPLATE 'PPT_Test' SLIDENUMBER 3
END
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'ITALY';
ON TABLE HOLD AS PPTCOMP2 FORMAT PPT TEMPLATE 'PPT_Test' SLIDENUMBER 5
END
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'ENGLAND';
ON TABLE PCHOLD FORMAT PPT TEMPLATE 'PPTCOMP' SLIDENUMBER 7
END
-EXIT

Actually having just looked at this again the reason this does not work for you
is that you are not quite going about it the correct way.

 
APP HOLD SESSION
APP FI PPTCOMP1 DISK PPTCOMP1.MHT
APP FI PPTCOMP2 DISK PPTCOMP2.MHT
APP FI PPTCOMP3 DISK PPTCOMP3.MHT
-* for as many reports as you have
-*
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'FRANCE';
ON TABLE HOLD AS PPTCOMP1 FORMAT PPT TEMPLATE 'PPT_Test' SLIDENUMBER 3
END
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'ITALY';
ON TABLE HOLD AS PPTCOMP2 FORMAT PPT TEMPLATE 'PPTCOMP1' SLIDENUMBER 5
END
TABLE FILE CAR
PRINT RCOST BY COUNTRY BY CAR BY MODEL
WHERE COUNTRY EQ 'ENGLAND';
ON TABLE PCHOLD FORMAT PPT TEMPLATE 'PPTCOMP2' SLIDENUMBER 7
END
-EXIT
 

The way it works is one of the older compounding methods used for Excel

Basically the first output uses your real template and each output then becomes the
template for the subsequent output.

However the rule about the template master still applies and all pages will have
that single master layout.