Hi Focals i need a logic to build this:

COUNTRY DISTINCT BODYTYPE
ENGLAND CONVERTIBLE, HARDTOP, SEDAN
FRANCE SEDAN
ITALY COUPE, ROADSTER, SEDAN
JAPAN SEDAN
W GERMANY SEDAN

With my code:

TABLE FILE CAR
PRINT   
 DST.BODYTYPE
BY  COUNTRY
END

I got this:

COUNTRY DISTINCT BODYTYPE
ENGLAND CONVERTIBLE
HARDTOP
SEDAN
FRANCE SEDAN
ITALY COUPE
ROADSTER
SEDAN
JAPAN SEDAN
W GERMANY SEDAN

Thanks to all!!!

Christian

This message has been edited. Last edited by: ChristianP,

Hi Christian,

Try this:

  
TABLE FILE CAR
BY COUNTRY
RANKED BY BODYTYPE
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE HOLD
END
TABLE FILE HOLD
SUM BODYTYPE AS ''
BY COUNTRY AS ''
ACROSS RANK NOPRINT
HEADING
"COUNTRY<+0>DISTINCT BODYTYPES"
ON TABLE SET STYLE *
TYPE=HEADING, HEADALIGN=INTERNAL, $
END

Or, to get a comma-delimited list (and ensure it's alphabetised):

  
TABLE FILE CAR
COUNT ENTRIES
BY COUNTRY
BY BODYTYPE
ON TABLE HOLD
END
DEFINE FILE HOLD
BODYTYPE_LIST/A500V= 
IF (COUNTRY EQ LAST COUNTRY)
 THEN  BODYTYPE_LIST || (', ' | BODYTYPE)
 ELSE  BODYTYPE ;
END
TABLE FILE HOLD
WRITE LST.BODYTYPE_LIST AS BODYTYPES
BY COUNTRY
END

Or, if you want to use without hold file try below code

 TABLE FILE CAR
SUM
COMPUTE COL1/A500V = IF COUNTRY EQ LAST COUNTRY THEN LAST COL1 || (', ' | BODYTYPE) ELSE BODYTYPE;
COMPUTE CNTR/I11 = IF COUNTRY EQ LAST COUNTRY THEN LAST CNTR + 1 ELSE 1; NOPRINT
BY COUNTRY
BY TOTAL HIGHEST 1 CNTR NOPRINT
BY BODYTYPE NOPRINT
END
-EXIT 

By,
Kumaravel.M