This is really annoying because the styling parser in my head can work this out but WF cannot.

Here's a simplified example of my real world report:

I need to
- highlight certain rows
- wrap certain columns

Somehow these two requirements are colliding with other WF styling. In the example below, the addition of TYPE=DATA, $ causes the SALES column to not have the background colour. The TYPE=DATA, $, or TYPE=DATA, COLOR=NAVY, $ simulates the other WF styling in the report, this causes the problem and I see no relation with this and TYPE=DATA, BACKCOLOR=RED, WHEN= COUNTRY EQ 'FRANCE', $

TABLE FILE CAR
SUM
SALES AS 'WIDE COLUMN TITLE'

BY COUNTRY

ON TABLE SET STYLE *

UNITS=PTS,
$

TYPE=REPORT, COLUMN=SALES, WRAP=50, $

TYPE=DATA, 
-*COLOR=NAVY,
$

TYPE=DATA, BACKCOLOR=RED, WHEN= COUNTRY EQ 'FRANCE', $

ENDSTYLE

ON TABLE PCHOLD FORMAT EXL2K
END

This message has been edited. Last edited by: Francis Mariani,

What I want


What I get

This certainly doesn't look right.

The back colour style should take the inherited attributes and change them

Can't understand why is the wrap affecting the background colour.

Have you added an extra style to fix it ?

TYPE=DATA, COLUMN=SALES, BACKCOLOR=RED, WHEN= COUNTRY EQ 'FRANCE', $

How about adding the opposite condition as well?
Not sure if this will work in your real program.

  
TABLE FILE CAR
SUM
   SALES AS 'WIDE COLUMN TITLE'
BY COUNTRY
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
UNITS=PTS,$
TYPE=REPORT,COLUMN=SALES,WRAP=50,$
TYPE=DATA,COLOR=NAVY,BACKCOLOR=NONE,WHEN=COUNTRY NE 'FRANCE',$
TYPE=DATA,COLOR=NAVY,BACKCOLOR=RED,WHEN=COUNTRY EQ 'FRANCE',$
ENDSTYLE
END

Unfortunately, I can't declare the opposite style, I have multiple colours being set - so there is no opposite

I suspect you will end up with one massive stylesheet.

Case-opening time I guess...

Hi,
Though I could not see the image attached(my computer problem) but going through the thread it seems the requirement is to put conditional backcolor in data column.
Following code change might be helpful,please review once.
TABLE FILE CAR
SUM
SALES AS 'WIDE COLUMN TITLE'

BY COUNTRY

ON TABLE SET STYLE *

UNITS=PTS,
$

TYPE=DATA, BACKCOLOR=RED, WHEN= COUNTRY EQ 'FRANCE', $
TYPE=DATA, COLUMN=SALES, WRAP=50, $

TYPE=DATA,
-*COLOR=NAVY,
$


ENDSTYLE

ON TABLE PCHOLD FORMAT EXL2K
END

I think the source of the problem is that the report-wide style on the SALES column already defines a style for cells in that column. That style has been set, so any subsequent styling for matching cells is ignored.

What helps is to also specify conditional styling for those specific cells, as conditional styles override default styles:

TABLE FILE CAR
SUM
SALES AS 'WIDE COLUMN TITLE'

BY COUNTRY

ON TABLE SET STYLE *

UNITS=PTS,
$

TYPE=REPORT, COLUMN=SALES, WRAP=50,$

TYPE=DATA, 
-*COLOR=NAVY,
$

TYPE=DATA, BACKCOLOR=RED, WHEN=COUNTRY EQ 'FRANCE', $
TYPE=DATA, COLUMN=SALES, BACKCOLOR=RED, WHEN=COUNTRY EQ 'FRANCE', $

ENDSTYLE

ON TABLE PCHOLD FORMAT EXL2K
END

"the report-wide style on the SALES column already defines a style for cells in that column" - I expect WF styling to behave like CSS.

jvb, moving the style

TYPE=DATA,
-*COLOR=NAVY,
$

to the bottom makes no difference.

Wep5622,

your suggestion works!

I end up with this in my stylesheet:

TYPE=REPORT, COLUMN=PREV_AMOUNT_ABS       , WRAP=80, $
TYPE=REPORT, COLUMN=PREV_EARLIEST_DTE     , WRAP=70, $
TYPE=REPORT, COLUMN=PROB_OF_FORCASTED_DEAL, WRAP=50, $
TYPE=REPORT, COLUMN=PROBABILITY_PREV      , WRAP=50, $

TYPE=DATA, COLUMN=PREV_AMOUNT_ABS       , BACKCOLOR=RGB(188 211 217)   , WHEN= NEW_INVESTMENT EQ 'T'        , $ Blue
TYPE=DATA, COLUMN=PREV_EARLIEST_DTE     , BACKCOLOR=RGB(188 211 217)   , WHEN= NEW_INVESTMENT EQ 'T'        , $ Blue
TYPE=DATA, COLUMN=PROB_OF_FORCASTED_DEAL, BACKCOLOR=RGB(188 211 217)   , WHEN= NEW_INVESTMENT EQ 'T'        , $ Blue
TYPE=DATA, COLUMN=PROBABILITY_PREV      , BACKCOLOR=RGB(188 211 217)   , WHEN= NEW_INVESTMENT EQ 'T'        , $ Blue
TYPE=DATA, COLUMN=PREV_AMOUNT_ABS       , BACKCOLOR=RGB(179 221 155)   , WHEN= INFLOW_FLAG    EQ 'TRUE'     , $ Green
TYPE=DATA, COLUMN=PREV_EARLIEST_DTE     , BACKCOLOR=RGB(179 221 155)   , WHEN= INFLOW_FLAG    EQ 'TRUE'     , $ Green
TYPE=DATA, COLUMN=PROB_OF_FORCASTED_DEAL, BACKCOLOR=RGB(179 221 155)   , WHEN= INFLOW_FLAG    EQ 'TRUE'     , $ Green
TYPE=DATA, COLUMN=PROBABILITY_PREV      , BACKCOLOR=RGB(179 221 155)   , WHEN= INFLOW_FLAG    EQ 'TRUE'     , $ Green
TYPE=DATA, COLUMN=PREV_AMOUNT_ABS       , BACKCOLOR=RGB(214 214 214)   , WHEN= STATUS_FLAG    EQ 'History'  , $ Grey
TYPE=DATA, COLUMN=PREV_EARLIEST_DTE     , BACKCOLOR=RGB(214 214 214)   , WHEN= STATUS_FLAG    EQ 'History'  , $ Grey
TYPE=DATA, COLUMN=PROB_OF_FORCASTED_DEAL, BACKCOLOR=RGB(214 214 214)   , WHEN= STATUS_FLAG    EQ 'History'  , $ Grey
TYPE=DATA, COLUMN=PROBABILITY_PREV      , BACKCOLOR=RGB(214 214 214)   , WHEN= STATUS_FLAG    EQ 'History'  , $ Grey
TYPE=DATA, COLUMN=PREV_AMOUNT_ABS       , BACKCOLOR=RGB(255 123 123)   , WHEN= FORECAST_GROUP EQ 'Cancelled', $ Red
TYPE=DATA, COLUMN=PREV_EARLIEST_DTE     , BACKCOLOR=RGB(255 123 123)   , WHEN= FORECAST_GROUP EQ 'Cancelled', $ Red
TYPE=DATA, COLUMN=PROB_OF_FORCASTED_DEAL, BACKCOLOR=RGB(255 123 123)   , WHEN= FORECAST_GROUP EQ 'Cancelled', $ Red
TYPE=DATA, COLUMN=PROBABILITY_PREV      , BACKCOLOR=RGB(255 123 123)   , WHEN= FORECAST_GROUP EQ 'Cancelled', $ Red

quote:

Originally posted by Francis Mariani:
"the report-wide style on the SALES column already defines a style for cells in that column" - I expect WF styling to behave like CSS.

Yeah, that's what I expected initially as well. I've learned the hard way that it does not.

Wep5622, thanks for your assistance.

Glad Wep5622 could help

Frankie, it works fine in 768 just as you wrote it. i tried changing TYPE=REPORT, to TYPE=TITLE, just for grins. made no dif. both ways worked fine, regardless of output type.
so its 77 wierdness, i guess.

I think v7.705 introduced some bugs, or quirks that I haven't met before. Fix... Break... Fix... Break... Fix... Break... Fix... Break... Fix... Break... Fix... Break... Fix... Break... Fix... Break... Fix... Break...

I get the impression that in past releases some things worked unintentionally.

With 7.7 IBI has done a lot of code tightening (sometimes too much IMHO, like not allowing an END statement at the end of a single-line JOIN statement) and such unintended "features" started breaking.

That wouldn't really be a problem if IBI were aware of such usage and implemented a fix, but perhaps we have been a bit more creative in our usage than they expected :P