2 questions


1. - Whe saying

USE 
 MYDATABASE FOCUS A NEW
END

what does the the keyword "NEW" do?
Does it create a completly new FOCUS table?
do i need to have a MASTER file already made to do this?

2. I'm trying to update a database via a alpha data file, which has a new field. I added taht field to my FOCUS table MASTER. however now i keep getting an error saying :

>                                                                   
(FOC322) FILE DESCRIPTION CHANGED AFTER DATA ENTERED (FILE/SEGMENT) 
MYDATABSE                                                             
                                       
>                                                                   

USE
dbname NEW
END

> Is for Databases that don't exist yet, and you will create during the session with a DYNAM to allocate to it, and a CREATE FILE to write-out a new FOCUS file. For what you are doing now, I don't think you will need USE.

> What you are doing is creating a new field to an existing database. To do this, you have 2 ways to add the field correctly. 1) You can use a TABLE/HOLD using the old MASTER (MFD), and MODIFY FILE new MFD - FIXFORM from HOLD etc. 2) You can use the REBUILD Utility - just enter: REBUILD. You want to first DUMP the old file without any MFD changes. Then edit the MFD and add the new field (or do a copy/rename of the old/new MFD), then: REBUILD LOAD.

Either way, once you load, the new FOCUS file will have the new field. Whether you supply a value for it during the reload or REBUILD is up to you and your application.

Hope this helps. Jim

1) NEW Indicates that the data source has yet to be created.

2) I've had issues with REBUILD so I do it the tried and tested way...... Not that easy I'm afraid, you can sometimes get away with adding a field to end of a particular segment -
but it is not recommended (so long as it does not exceed the 4K page limit).

i) You could dump each segment of the data into 1 hold file per segment making sure the hold files are
permanently catalogued (just in case something goes wrong)

ii) Then change your master file desciption.

iii) issue your use

iv) issue your create file statement

v) Reload the data segment by segment

-------------------------------------------
So for example if your master looks like:

FILE=MYFILE, SUFFIX=FOC
SEGNAME=ROOT_SEG, SEGTYPE=S2, $
FIELD=FIELD1, ALIAS=FIELD1, FORMAT=A8, INDEX=I, $
FIELD=FIELD2, ALIAS=FIELD2, FORMAT=A20 , $
FIELD=FIELD3, ALIAS=FIELD3, FORMAT=I3 , $
$
SEGNAME=CHILD1, SEGTYPE=S1, PARENT=ROOT_SEG, $
FIELD=FIELD4, ALIAS=FIELD4, FORMAT=I9, INDEX=I, $
FIELD=FIELD5, ALIAS=FIELD5, FORMAT=A9, INDEX=I, $
$
SEGNAME=CHILD2, SEGTYPE=S1, PARENT=CHILD1, $
FIELD=FIELD6, ALIAS=FIELD6, FORMAT=I5, INDEX=I, $
FIELD=FIELD7, ALIAS=FIELD7, FORMAT=A5, INDEX=I, $

-*********************************************************
-* FEX TO DUMP DATA SEG BY SEG
-* NOTE THE 'BY' SEQUENCES ECHO THE KEYS IUN THE DATABASE
-* SO TO FULLY QUALIFY THE CONTENTS OF FIELD7
-* YOU NEED TO KNOW FIELD1 & FIELD2 (S2 SEG)
-* YOU NEED TO KNOW FIELD4 (S1 SEG)
-* YOU NEED TO KNOW FIELD6 (S1 SEG)
-*********************************************************
FILEDEF DUMPSEG01 DISK &APPROOT..\MYAPP\DUMPSEG01.FTM
FILEDEF DUMPSEG02 DISK &APPROOT..\MYAPP\DUMPSEG02.FTM
FILEDEF DUMPSEG03 DISK &APPROOT..\MYAPP\DUMPSEG03.FTM

TABLE FILE MYFILE
PRINT FIELD3
BY FIELD1
BY FIELD2
ON TABLE HOLD AS DUMPSEG01 FORMAT ALPHA
END

TABLE FILE MYFILE
PRINT FIELD5
BY FIELD1
BY FIELD2
BY FIELD4
ON TABLE HOLD AS DUMPSEG02 FORMAT ALPHA
END

TABLE FILE MYFILE
PRINT FIELD7
BY FIELD1
BY FIELD2
BY FIELD4
BY FIELD6
ON TABLE HOLD AS DUMPSEG03 FORMAT ALPHA
END

DOS COPY DUMPSEG*.MAS &APPROOT..\MYAPP\DUMPSEG.MAS

-**********************************************************
-* NOW CREATE YOU NEW MASTER FILE
-**********************************************************
FILE=MYFILE, SUFFIX=FOC
SEGNAME=ROOT_SEG, SEGTYPE=S2, $
FIELD=FIELD1, ALIAS=FIELD1, FORMAT=A8, INDEX=I, $
FIELD=FIELD2, ALIAS=FIELD2, FORMAT=A20 , $
FIELD=FIELD3, ALIAS=FIELD3, FORMAT=I3 , $
$
SEGNAME=CHILD1, SEGTYPE=S1, PARENT=ROOT_SEG, $
FIELD=FIELD4, ALIAS=FIELD4, FORMAT=I9, INDEX=I, $
FIELD=FIELD5, ALIAS=FIELD5, FORMAT=A9, INDEX=I, $
$
SEGNAME=CHILD2, SEGTYPE=S1, PARENT=CHILD1, $
FIELD=FIELD6, ALIAS=FIELD6, FORMAT=I5, INDEX=I, $
FIELD=FIELD7, ALIAS=FIELD7, FORMAT=A5, INDEX=I, $
FIELD=FIELDX, ALIAS=FIELDX, FORMAT=A5, INDEX=I, $
-***********************************************************
-* NOW ISSUE CREATE AND USE FOR FOCUS DB
-***********************************************************
FILEDEF DUMPSEG01 DISK &APPROOT..\MYAPP\DUMPSEG01.FTM
FILEDEF DUMPSEG02 DISK &APPROOT..\MYAPP\DUMPSEG02.FTM
FILEDEF DUMPSEG03 DISK &APPROOT..\MYAPP\DUMPSEG03.FTM

USE
D:\IBI\APPS\MYAPPS\MYFILE.FOC NEW
END

CREATE FILE MYFILE
-RUN
-***********************************************************
-* SEG 1 LOAD
-***********************************************************
MODIFY FILE MYFILE
FIXFORM FROM DUMPSEG01
DATA ON DUMPSEG01
END

-***********************************************************
-* SEG 2 LOAD
-***********************************************************
MODIFY FILE MYFILE
FIXFORM FROM DUMPSEG02
DATA ON DUMPSEG02
-*
MATCH FIELD1
ON MATCH REJECT
ON NOMATCH CONTINUE
-*
MATCH FIELD4
ON MATCH REJECT
ON NOMATCH INCLUDE
END

-***********************************************************
-* SEG 3 LOAD
-***********************************************************
MODIFY FILE MYFILE
FIXFORM FROM DUMPSEG03
DATA ON DUMPSEG03
-*
MATCH FIELD1
ON MATCH REJECT
ON NOMATCH CONTINUE
-*
MATCH FIELD4
ON MATCH REJECT
ON NOMATCH CONTINUE
-*
MATCH FIELD6
ON MATCH REJECT
ON NOMATCH INCLUDE
END

-************************************************************
-*NOW YOU CAN POPULATE FIELDX SAFELY
-************************************************************

GOOD LUCK
P

Thanks!