Heading Items position in EXL2K [SOLVED]

October 07, 2009, 06:39 AM

Jérény Deidda

Hi,

I would like to align my heading items with my columns : ie Titre with O10NOM1, ISIN with O10N001,...

How can I do? I tried with "POSITION=my column" in the stylesheet but it didn't work

  
TABLE FILE TAB010
PRINT
O10NOM1 AS 'Titre'
O10N001 AS 'ISIN'
GTI AS 'Genre de titre'
COMPUTE MNT/D20.2C = O10MNT2; AS 'Evaluation'
DEVISE AS 'Devise'
COMPUTE POIDSTAN/D7.2% = O10PMT2TAN; AS '% du TNA du compartiment'
BY O10SOC NOPRINT
BY HIGHEST 10 O10MNT2 NOPRINT
WHERE O10DATE EQ LASTVNIDATE;
ON O10SOC SUBHEAD
"<LIBCOMPART : <DATEVNI"
"Titre<+0>ISIN<+0>Genre de titre<+0>Evaluation<+0>Devise<+0>% du TNA du compartiment"
ON O10SOC SUBFOOT
"<TOTTAN"
""
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
UNITS=CM,ORIENTATION=PORTRAIT,SQUEEZE=ON,$
TYPE=TITLE,COLOR=WHITE,$
TYPE=DATA,COLUMN=DEVISE,JUSTIFY=CENTER,$
TYPE=SUBHEAD,LINE=1,JUSTIFY=CENTER,STYLE=BOLD+ITALIC,COLOR=NAVY,$
TYPE=SUBHEAD,LINE=2,STYLE=BOLD,COLOR=WHITE,BACKCOLOR=NAVY,$
TYPE=SUBFOOT,JUSTIFY=RIGHT,STYLE=BOLD,$
ENDSTYLE
END

This message has been edited. Last edited by: Jérény Deidda,

October 07, 2009, 08:02 AM

<JG>

Position only works for PDF.

For EXL2K read up on HEADALIGN and COLSPAN

October 07, 2009, 08:26 AM

Jérény Deidda

I tried but no success

Do you have an example?

October 07, 2009, 08:42 AM

Tom Flynn

TABLE FILE TAB010
PRINT
   O10NOM1 AS '' 
   O10N001 AS '' 
   GTI  AS '' 
COMPUTE MNT/D20.2C = O10MNT2; AS ''
DEVISE AS ''
COMPUTE POIDSTAN/D7.2% = O10PMT2TAN; AS ''
BY O10SOC NOPRINT
BY HIGHEST 10 O10MNT2 NOPRINT
WHERE O10DATE EQ LASTVNIDATE;
ON O10SOC SUBHEAD
"<LIBCOMPART : <DATEVNI"
"Titre<+0>ISIN<+0>Genre de titre<+0>Evaluation<+0>Devise<+0>% du TNA du compartiment"
ON O10SOC SUBFOOT
"<TOTTAN"
""
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
UNITS=CM,ORIENTATION=PORTRAIT,SQUEEZE=ON,$
TYPE=TITLE,COLOR=WHITE,$
TYPE=DATA,COLUMN=DEVISE,JUSTIFY=CENTER,$

TYPE=SUBHEAD, HEADALIGN=BODY, JUSTIFY=CENTER, $

TYPE=SUBHEAD,LINE=1,STYLE=BOLD+ITALIC,COLOR=NAVY,$
TYPE=SUBHEAD,LINE=2,STYLE=BOLD,COLOR=WHITE,BACKCOLOR=NAVY,$
TYPE=SUBFOOT,JUSTIFY=RIGHT,STYLE=BOLD,$
ENDSTYLE
END
-EXIT

October 07, 2009, 08:52 AM

Jérény Deidda

Thanks Tom,

it's 90% of that I want. The problem remains for the first line of my heading who must be center on all the 6 columns.

I succeed to obtain what I wanted with this code:

TABLE FILE TAB010
PRINT
O10NOM1 AS 'Titre'
O10N001 AS 'ISIN'
GTI AS 'Genre de titre'
COMPUTE MNT/D20.2C = O10MNT2; AS 'Evaluation'
DEVISE AS 'Devise'
COMPUTE POIDSTAN/D7.2% = O10PMT2TAN; AS '% du TNA du compartiment'
BY O10SOC NOPRINT
BY HIGHEST 10 O10MNT2 NOPRINT
WHERE O10DATE EQ LASTVNIDATE;
ON O10SOC SUBHEAD
"<LIBCOMPART : <DATEVNI"
"---------------------------<+0>Titre<+0>------------------------------------<+0>ISIN<+0>-----------<+0>Genre de titre<+0>-----<+0>Evaluation<+0>-<+0>Devise<+0>-<+0>% du TNA du compartiment"
ON O10SOC SUBFOOT
"<TOTTAN"
""
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
UNITS=CM,ORIENTATION=PORTRAIT,SQUEEZE=ON,$
TYPE=TITLE,COLOR=WHITE,$
TYPE=DATA,COLUMN=DEVISE,JUSTIFY=CENTER,$
TYPE=SUBHEAD,LINE=1,JUSTIFY=CENTER,STYLE=BOLD+ITALIC,COLOR=NAVY,$
TYPE=SUBHEAD,LINE=2,STYLE=BOLD,COLOR=WHITE,BACKCOLOR=NAVY,HEADALIGN=BODY,$
TYPE=SUBHEAD,LINE=2,ITEM=1,COLOR=NAVY,$
TYPE=SUBHEAD,LINE=2,ITEM=3,COLOR=NAVY,$
TYPE=SUBHEAD,LINE=2,ITEM=5,COLOR=NAVY,$
TYPE=SUBHEAD,LINE=2,ITEM=7,COLOR=NAVY,$
TYPE=SUBHEAD,LINE=2,ITEM=9,COLOR=NAVY,$
TYPE=SUBHEAD,LINE=2,ITEM=11,COLOR=NAVY,$
TYPE=SUBHEAD,LINE=2,ITEM=12,SIZE=9,$
TYPE=SUBFOOT,JUSTIFY=RIGHT,STYLE=BOLD,$
ENDSTYLE
END

October 07, 2009, 09:43 AM

Tony A

Jérény,

Use a combination of COLSPAN and HEADALIGN=BODY with a DEFINE to achieve your first line -

DEFINE FILE CAR
  MY_HEADING/A50 = COUNTRY || (' : ' | CAR);
END
TABLE FILE CAR
  SUM RCOST
      DCOST
      SEATS
   BY COUNTRY
   BY CAR
   BY MODEL
WHERE COUNTRY EQ 'ENGLAND'
ON COUNTRY SUBHEAD
  "<MY_HEADING "
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLE *
  UNITS=CM, ORIENTATION=PORTRAIT, SQUEEZE=ON, HEADALIGN=BODY, $
  TYPE=SUBHEAD, LINE=1, ITEM=1, COLSPAN=6, JUSTIFY=CENTER, $
ENDSTYLE
END

In FOCUS since 1986	WebFOCUS Server 8.2.01M, thru 8.2.07 on Windows Svr 2008 R2
	WebFOCUS App Studio 8.2.06 standalone on Windows 10