Sorry guys. I never professed to be a teacher. I was just giving another example of how it could be accomplished. I guess I should have broken it out for those that like to see the fields built one at a time.

Maybe this helps:

DEFINE FILE CAR
TAX/D12.4 = .08125;
SALESTAX/D12.4 = RETAIL_COST * TAX;
-*MULTIPLY SALESTAX BY 100 AND CONVERT TO ALPHA
FTOA_SALESTAX/A14 = FTOA(SALESTAX*100, '(D12.2)', 'A14');
-*FIND THE POSITION OF THE DECIMAL
POSIT_DECIMAL/I2 = POSIT(FTOA_SALESTAX, 14, '.', 1, 'I2');
-*USE SUBSTR TO KEEP EVERYTHING TO THE LEFT OF THE DECIMAL
SUBSTR_SALESTAX/A14 = SUBSTR(14, FTOA_SALESTAX, 1, POSIT_DECIMAL-1, 14, 'A14');
-*REMOVE THE COMMAS
STRIP_SALESTAX/A14 = STRIP(14,SUBSTR_SALESTAX, ',', 'A14');
-*CONVERT BACK TO NUMERIC AND DEVIDE BY 100
TRUNC_SALESTAX/D12.2 = EDIT(STRIP_SALESTAX)/100;
END

TABLE FILE CAR
PRINT
RETAIL_COST
TAX
SALESTAX
TRUNC_SALESTAX
COMPUTE DRIVEOUT/D12.2 = RETAIL_COST + TRUNC_SALESTAX;
ON TABLE PCHOLD FORMAT EXL2K
END
-EXIT

Thanks Glenda that was helpful!!!

That a lot of steps to truncate something thou...

Try:

DEFINE FILE CAR
INVAL/D12.4 WITH CAR = 3456.7891 ;
MYT/D12.4 = INT(INVAL*10)/10 ;
END
TABLE FILE CAR
PRINT INVAL MYT
IF RECORDLIMIT EQ 1
END

Nice and clean. Works with

MYT/D12.1 = INT(INVAL*10)/10 ; 

as well.

No Glenda...that's a lot of nice stuff.

DEFINE FILE CAR
VAL1/D12.4 WITH CAR = 3456.7891 ;
VAL2/D12 = INT(VAL1);
VAL3/D12.4 = VAL1 - VAL2;
END
TABLE FILE CAR
PRINT VAL1 VAL2 VAL3
IF RECORDLIMIT EQ 1
END

VAL1/D12.4 WITH CAR=3456.7891;
VAL2/D2.4  = DMOD(VAL1, 1, VAL2);
END

DEFINE FILE CAR
VAL1/D12.5=1234.5678;
VALUPDEC/D12.2=VAL1;
VALUPPACK/P12.2=VAL1;
VALDOWNDEC/D12.2=VAL1-.005;
VALDOWNPACK/P12.2=VAL1-.005;
END
TABLE FILE CAR
PRINT
 COUNTRY 
 VAL1
 VAL1/D12.2
 VALUPDEC
 VALUPDEC/D12.5
 VALUPPACK
 VALUPPACK/D12.5
 VALDOWNDEC
 VALDOWNDEC/D12.5
 VALDOWNPACK
 VALDOWNPACK/D12.5
ON TABLE SET PAGE-NUM OFF
ON TABLE COLUMN-TOTAL
END