Trying to center the titles of the datacolums beneath the across column MODEL shows the first titles (for DEALER_COST and RETAIL_COST) centered the remaining column tiltes are shown right justified (try the code).

Any idea?


TABLE FILE CAR
SUM
DEALER_COST AS 'D'
RETAIL_COST AS 'R'
BY COUNTRY
BY CAR
ACROSS MODEL AS ''
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
UNITS=CM, SQUEEZE=ON,
$
TYPE=REPORT,
BORDER=0.5, BORDER-COLOR=BLACK,
$
TYPE=TITLE, COLUMN=DEALER_COST,
JUSTIFY=CENTER,
$
TYPE=TITLE, COLUMN=RETAIL_COST,
JUSTIFY=CENTER,
$
TYPE=ACROSSVALUE, ACROSS=MODEL,
JUSTIFY=CENTER,
$
ENDSTYLE
END


This message has been edited. Last edited by: MichaelBalle,

Here you go enjoy!

TABLE FILE CAR
SUM
DEALER_COST AS 'D'
RETAIL_COST AS 'R'
BY COUNTRY
BY CAR
ACROSS MODEL AS ''
ON TABLE SET PAGE-NUM OFF
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET STYLE *
UNITS=CM, SQUEEZE=ON,
$
TYPE=REPORT,
BORDER=0.5, BORDER-COLOR=BLACK,
$
TYPE=TITLE, COLUMN=DEALER_COST(*),
JUSTIFY=CENTER,
$
TYPE=TITLE, COLUMN=RETAIL_COST(*),
JUSTIFY=CENTER,
$
TYPE=ACROSSVALUE, ACROSS=MODEL,
JUSTIFY=CENTER,
$
ENDSTYLE
END

Thanks for your support - the solution works fine.