May 04, 2005, 08:30 PM
<new2focus>How to wrap a column on pdf reports
How can I display both the columns in a single page? When I set WRAP=OFF it is not displaying the enitre content of the second column. Also how can I explicitly specify width for each column?
DEFINE FILE CAR
CAR_INFO/A60 = '[' || CAR || '-' || MODEL || '-' || BODYTYPE || ']';
LARGE_TEXT/A600 = IF COUNTRY EQ LAST COUNTRY
THEN (SUBSTR(600, LARGE_TEXT, 1, ARGLEN(600, LARGE_TEXT, 'I3'), ARGLEN(600, LARGE_TEXT, 'I3'), 'A535')
|| ' - ' || CAR_INFO) ELSE CAR_INFO;
END
TABLE FILE CAR
SUM LARGE_TEXT
BY COUNTRY
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SET STYLE *
UNITS=IN, PAGESIZE='A4', SQUEEZE=ON, ORIENTATION=LANDSCAPE,
LEFTMARGIN=0.39, RIGHTMARGIN=0.39, TOPMARGIN=0.0, BOTTOMMARGIN=0.0, $
-*TYPE=REPORT, GRID=OFF, WRAP=OFF, TOPGAP=0.03, BOTTOMGAP=0.06,
TYPE=REPORT, GRID=OFF, WRAP=7, TOPGAP=0.03, BOTTOMGAP=0.06,
FONT='HELVETICA', SIZE=8, COLOR='BLACK', BACKCOLOR='NONE', STYLE=NORMAL, $
TYPE=TITLE, BORDER=LIGHT, BACKCOLOR='LIGHT GREY', STYLE=-UNDERLINE+BOLD+ITALIC, $
TYPE=DATA, BORDER=LIGHT, $
ENDSTYLE
END
May 04, 2005, 09:06 PM
reFOCUSingGive this a try:
DEFINE FILE CAR
CAR_INFO/A60 = '[' || CAR || '-' || MODEL || '-' || BODYTYPE || ']';
LARGE_TEXT/A600 = IF COUNTRY EQ LAST COUNTRY
THEN (SUBSTR(600, LARGE_TEXT, 1, ARGLEN(600, LARGE_TEXT, 'I3'), ARGLEN(600, LARGE_TEXT, 'I3'), 'A535')
|| ' - ' || CAR_INFO) ELSE CAR_INFO;
END
TABLE FILE CAR
SUM LARGE_TEXT
BY COUNTRY
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SET STYLE *
UNITS=IN, PAGESIZE='A4', SQUEEZE=ON, ORIENTATION=LANDSCAPE,LEFTMARGIN=0.39, RIGHTMARGIN=0.39, TOPMARGIN=0.0, BOTTOMMARGIN=0.0, $
TYPE=REPORT, GRID=OFF,TOPGAP=0.03, BOTTOMGAP=0.06,FONT='HELVETICA', SIZE=8, COLOR='BLACK', BACKCOLOR='NONE', STYLE=NORMAL, $
TYPE=REPORT,COLUMN=COUNTRY,SQUEEZE=0.75,$
TYPE=REPORT,COLUMN=LARGE_TEXT,WRAP=7.00,$
TYPE=TITLE, BORDER=LIGHT, BACKCOLOR='LIGHT GREY', STYLE=-UNDERLINE+BOLD+ITALIC, $
TYPE=DATA, BORDER=LIGHT, $
ENDSTYLE
END
These lines where changed/added:
TYPE=REPORT, GRID=OFF,TOPGAP=0.03, BOTTOMGAP=0.06,FONT='HELVETICA', SIZE=8, COLOR='BLACK', BACKCOLOR='NONE', STYLE=NORMAL, $
TYPE=REPORT,COLUMN=COUNTRY,SQUEEZE=0.75,$
TYPE=REPORT,COLUMN=LARGE_TEXT,WRAP=7.00,$
May 04, 2005, 11:00 PM
S.J. KadishWe are trying to wrap PDF using DevStudio 5.2.6 and the wrap does not work. The code works fine with EXL2K but in PDF the second and third line of text overwrite the first line of text and it looks horrible. Since we are trying to get the report onto one legal page we don't have a lot of options.
Any thoughts?
May 05, 2005, 12:23 PM
<new2focus>Thanks Curtis.. Those 2 lines did the magic! Have a gr8 day!