I'm trying to grab two values from one record of one table. Then read those two values into two variables. The documentation I've found does not seem to work for me.

Here's my example:
TABLE FILE FRRGENB

PRINT
FRRGENB.FRRGENB.FRRGENB_PERIOD_FROM_DATE
FRRGENB.FRRGENB.FRRGENB_PERIOD_TO_DATE
WHERE ( FRRGENB.FRRGENB.FRRGENB_GRNT_CODE EQ '&GRNT_CODE' ) AND ( FRRGENB.FRRGENB.FRRGENB_BILL_INV_SEQ_NO EQ &FRRGENB_BILL_INV_SEQ_NO );
ON TABLE NOTOTAL
ON TABLE SAVE AS BILL
END
-RUN
-READ BILL, &FROM.A8., &TO.A8.
-TYPE FromDate: &FROM
-TYPE ToDate: &TO
-CLOSE Z_DATES

Which gives me:
0 NUMBER OF RECORDS IN TABLE= 2 LINES= 2
ALPHANUMERIC RECORD NAMED BILL
0 FIELDNAME ALIAS FORMAT LENGTH
FRRGENB_PERIOD_FROM_DATE FRRGENB_PERI> HYYMDS 17
FRRGENB_PERIOD_TO_DATE FRRGENB_PERI> HYYMDS 17
TOTAL 34
FromDate: 20120602
ToDate: 20120602


If I alter the commas I only get 0's in my second variable:
TABLE FILE FRRGENB

PRINT
FRRGENB.FRRGENB.FRRGENB_PERIOD_FROM_DATE
FRRGENB.FRRGENB.FRRGENB_PERIOD_TO_DATE
WHERE ( FRRGENB.FRRGENB.FRRGENB_GRNT_CODE EQ '&GRNT_CODE' ) AND ( FRRGENB.FRRGENB.FRRGENB_BILL_INV_SEQ_NO EQ &FRRGENB_BILL_INV_SEQ_NO );
ON TABLE NOTOTAL
-*ON TABLE HOLD AS Z_DATES FORMAT BINARY
ON TABLE SAVE AS BILL
END
-RUN
-READ BILL &FROM.A8. &TO.A8.
-TYPE FromDate: &FROM
-TYPE ToDate: &TO
-CLOSE Z_DATES

That gives me:
0 NUMBER OF RECORDS IN TABLE= 2 LINES= 2
ALPHANUMERIC RECORD NAMED BILL
0 FIELDNAME ALIAS FORMAT LENGTH
FRRGENB_PERIOD_FROM_DATE FRRGENB_PERI> HYYMDS 17
FRRGENB_PERIOD_TO_DATE FRRGENB_PERI> HYYMDS 17
TOTAL 34
FromDate: 20120602
ToDate: 00000000


This gives me the same results: -READ BILL &FROM.A8.,- ,&TO.A8.

This message has been edited. Last edited by: Kevin Patterson,

Try these two different approaches:

Using -READ:

SET HOLDLIST = PRINTONLY
SET ASNAMES  = ON
-*
TABLE FILE IBISAMP/EMPLOYEE
SUM MAX.PAY_DATE/YYMD MAX.DAT_INC/YYMD
ON TABLE SAVE AS DATES
END
-RUN
-READ DATES &FROM_DATE.8. &TO_DATE.8.
-TYPE FROM_DATE=&FROM_DATE
-TYPE TO_DATE=&TO_DATE

Using -READFILE:

SET HOLDLIST = PRINTONLY
SET ASNAMES  = ON
-*
TABLE FILE IBISAMP/EMPLOYEE
SUM MAX.PAY_DATE/YYMD MAX.DAT_INC/YYMD
ON TABLE HOLD AS DATES
END
-RUN
-READFILE DATES
-TYPE PAY_DATE=&PAY_DATE
-TYPE DAT_INC=&DAT_INC

Love READFILE, so useful.

Okay, I've got it pulling multiple fields now. I think my issue was not using the two sets:
SET HOLDLIST = PRINTONLY
SET ASNAMES = ON

Thank you very much for the help!