I turned my complicated report into to a Simple Car Fex...and I need the Total on the Top instead of Bottom. Anything I try gets strange result because of the Two Verbs and the ACROSS.
Any thoughts?
SET NODATA=0

TABLE FILE CAR
SUM SALES AS 'Total'
BY MODEL AS 'Site'
SUM RETAIL AS ' '
BY MODEL AS 'Site'
ACROSS COUNTRY AS ' '
ON TABLE SUMMARIZE
HEADING
"Vulnerable Workstations"
ON TABLE SET PAGE-NUM OFF
ON TABLE COLUMN-TOTAL AS 'Total'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='Letter',
SQUEEZE=ON,
ORIENTATION=LANDSCAPE,$
END

Here's a start

DEFINE FILE CAR
 TMODEL/A24 WITH MODEL ='*TOTAL';
 A__/D7=SALES;
 B__/D7=RETAIL_COST;
END
TABLE FILE CAR
SUM A__   BY TMODEL AS MODEL
SUM B__   BY TMODEL AS MODEL  ACROSS COUNTRY
ON TABLE SET ASNAMES ON       ON TABLE HOLD AS HOLD1
END
TABLE FILE CAR
SUM A__   BY MODEL
SUM B__   BY MODEL            ACROSS COUNTRY
ON TABLE SET ASNAMES ON       ON TABLE HOLD AS HOLD2
END
TABLE FILE HOLD1 WRITE * ON TABLE HOLD AS HOLD3 FORMAT FOCUS
END
MODIFY FILE HOLD3
FIXFORM FROM HOLD2
MATCH *
ON MATCH REJECT
ON NOMATCH INCLUDE
DATA ON HOLD2
END
TABLE FILE HOLD3
PRINT *
END

Or try this one:

TABLE FILE CAR
SUM SALES NOPRINT
SUM SALES AS 'Total'
BY MODEL AS 'Site'
SUM RETAIL AS ' '
BY MODEL AS 'Site'
ACROSS COUNTRY AS ' '
ON TABLE SUMMARIZE
HEADING
"Vulnerable Workstations"
"Total: {SALES "
ON TABLE SET PAGE-NUM OFF
ON TABLE COLUMN-TOTAL AS 'Total'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='Letter',
SQUEEZE=ON,
ORIENTATION=LANDSCAPE,$
END


Spot marker issue in total line

LEAH...you solution is good on Sales..but can't get retail up there...

Jack,

Yours worked great...just got to figure out how to make my comlicated report go that.

Thanks...

Try adding the RETAIL to the first sum statement and noprint, then add it to the heading as well.

SUM SALES NOPRINT RETAIL NOPRINT
...
HEADING
" Total Sales : {SALES Retail: {RETAIL "

or...

TABLE FILE CAR
SUM SALES   RETAIL NOPRINT  
BY MODEL AS 'Site' 
SUM RETAIL AS   ' '
BY MODEL  
ACROSS COUNTRY AS ' '
ON TABLE SUMMARIZE
 
HEADING
"Vulnerable Workstations"
"Total:SALES: <TOT.SALES RETAILCOST: <TOT.RETAIL "
ON TABLE SET PAGE-NUM OFF
ON TABLE COLUMN-TOTAL 
END

Prarie,

You could always resort to using FML, although it would probably require a large amount of pre-extracting data, reading into variables to produce the ACROSS COLUMNS values and also the individual FOR values, but it will give what you want for output?

SET NODATA=0

SET FORMULTIPLE = ON
TABLE FILE CAR
SUM SALES NOPRINT
    RETAIL AS ''
ACROSS COUNTRY AS ''
 COLUMNS 'Total' AND 'ENGLAND' AND 'FRANCE' AND 'ITALY' AND 'JAPAN' AND 'W GERMANY'
FOR MODEL
'$$$$$$$$$$$$$$$$$$$$$$$' AS 'Total' LABEL ModelTot OVER
" " OVER
'100 LS 2 DOOR AUTO'        LABEL Model01 OVER
'2000 4 DOOR BERLINA'       LABEL Model02 OVER
'2000 GT VELOCE'            LABEL Model03 OVER
'2000 SPIDER VELOCE'        LABEL Model04 OVER
'2002 2 DOOR'               LABEL Model05 OVER
'2002 2 DOOR AUTO'          LABEL Model06 OVER
'3.0 SI 4 DOOR'             LABEL Model07 OVER
'3.0 SI 4 DOOR AUTO'        LABEL Model08 OVER
'504 4 DOOR'                LABEL Model09 OVER
'530I 4 DOOR'               LABEL Model10 OVER
'530I 4 DOOR AUTO'          LABEL Model11 OVER
'B210 2 DOOR AUTO'          LABEL Model12 OVER
'COROLLA 4 DOOR DIX AUTO'   LABEL Model13 OVER
'DORA 2 DOOR'               LABEL Model14 OVER
'INTERCEPTOR III'           LABEL Model15 OVER
'TR7'                       LABEL Model16 OVER
'V12XKE AUTO'               LABEL Model17 OVER
'XJ12L AUTO'                LABEL Model18 OVER
RECAP ModelTot(2) = ModelTot(3) + ModelTot(5) + ModelTot(7) + ModelTot(9) + ModelTot(11); OVER
RECAP Model01(2) = Model01(3) + Model01(5) + Model01(7) + Model01(9) + Model01(11); OVER
RECAP Model02(2) = Model02(3) + Model02(5) + Model02(7) + Model02(9) + Model02(11); OVER
RECAP Model03(2) = Model03(3) + Model03(5) + Model03(7) + Model03(9) + Model03(11); OVER
RECAP Model03(2) = Model03(3) + Model03(5) + Model03(7) + Model03(9) + Model03(11); OVER
RECAP Model04(2) = Model04(3) + Model04(5) + Model04(7) + Model04(9) + Model04(11); OVER
RECAP Model05(2) = Model05(3) + Model05(5) + Model05(7) + Model05(9) + Model05(11); OVER
RECAP Model06(2) = Model06(3) + Model06(5) + Model06(7) + Model06(9) + Model06(11); OVER
RECAP Model07(2) = Model07(3) + Model07(5) + Model07(7) + Model07(9) + Model07(11); OVER
RECAP Model08(2) = Model08(3) + Model08(5) + Model08(7) + Model08(9) + Model08(11); OVER
RECAP Model09(2) = Model09(3) + Model09(5) + Model09(7) + Model09(9) + Model09(11); OVER
RECAP Model10(2) = Model10(3) + Model10(5) + Model10(7) + Model10(9) + Model10(11); OVER
RECAP Model11(2) = Model11(3) + Model11(5) + Model11(7) + Model11(9) + Model11(11); OVER
RECAP Model12(2) = Model12(3) + Model12(5) + Model12(7) + Model12(9) + Model12(11); OVER
RECAP Model13(2) = Model13(3) + Model13(5) + Model13(7) + Model13(9) + Model13(11); OVER
RECAP Model14(2) = Model14(3) + Model14(5) + Model14(7) + Model14(9) + Model14(11); OVER
RECAP Model15(2) = Model15(3) + Model15(5) + Model15(7) + Model15(9) + Model15(11); OVER
RECAP Model16(2) = Model16(3) + Model16(5) + Model16(7) + Model16(9) + Model16(11); OVER
RECAP Model17(2) = Model17(3) + Model17(5) + Model17(7) + Model17(9) + Model17(11); OVER
RECAP Model18(2) = Model18(3) + Model18(5) + Model18(7) + Model18(9) + Model18(11); OVER
" "
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='Letter',
SQUEEZE=ON,
ORIENTATION=LANDSCAPE,$
ENDSTYLE
END

T

.... or to make it flexible by using variables as mentioned above -

SET NODATA=0
SET FORMULTIPLE = ON
SET HOLDLIST = PRINTONLY

TABLE FILE CAR
BY COUNTRY
ON TABLE SAVE
END
-RUN

-SET &Columns = 'COLUMNS ''Total''';
-READ SAVE, &Country
-REPEAT :Loop1 WHILE &IORETURN EQ 0;
-SET &Columns = &Columns | ' AND ''' | &Country || '''';
-READ SAVE, &Country
-:Loop1

TABLE FILE CAR
BY MODEL
ON TABLE SAVE
END
-RUN

TABLE FILE CAR
SUM SALES NOPRINT
    RETAIL AS ''
ACROSS COUNTRY AS ''
&Columns
FOR MODEL
'$$$$$$$$$$$$$$$$$$$$$$$' AS 'Total' LABEL ModelTot OVER
RECAP ModelTot(2) = ModelTot(3) + ModelTot(5) + ModelTot(7) + ModelTot(9) + ModelTot(11); OVER
" " OVER
-SET &Cnt = 1;
-READ SAVE, &Model
-REPEAT :Loop2 WHILE &IORETURN EQ 0;
'&Model.EVAL' LABEL Model&Cnt.EVAL OVER
RECAP Model&Cnt.EVAL(2) = Model&Cnt.EVAL(3) + Model&Cnt.EVAL(5) + Model&Cnt.EVAL(7)
                        + Model&Cnt.EVAL(9) + Model&Cnt.EVAL(11); OVER
-SET &Cnt = &Cnt + 1;
-READ SAVE, &Model
-:Loop2
" "
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='Letter',
SQUEEZE=ON,
ORIENTATION=LANDSCAPE,$
ENDSTYLE
END

Enjoy

T