Is there a cammand that does the equivalent of a BYDISPLAY for multiple SUM fields with the OVER command? IF I code:

TABLE FILE QMR_REVENUE
SUM   REVENUE_AMOUNT AS 'REVENUE'
      OVER PRODUCT_FAMILY_BEGINNING_BALAN AS 'UNITS'
      OVER MOU_FAMILY AS 'MOUs'
BY   GRP_TITLE
BY   DATATYPE_PARENT
BY   EVP_MINUS_1
BY   ST_TITLE
BY   GRP_SUF

I get

					01/01/2005
Datatype Parent	Evp Minus 1	ST_TITLE	GRP_SUF		
ACTUALS	CONSUMER_ONLY	AZ	39682	REVENUE	135,843.12
				         UNITS	.00
				         MOUs	$.00
ACTUALS	CONSUMER_ONLY	AZ	ACCESS OTHER	REVENUE	47,932.88
				       UNITS	.00
				       MOUs	$.00

What I want is

					01/01/2005
Datatype Parent	Evp Minus 1	ST_TITLE	GRP_SUF		
ACTUALS	CONSUMER_ONLY	AZ	39682	REVENUE	135,843.12
ACTUALS	CONSUMER_ONLY	AZ	39682    UNITS	.00
ACTUALS	CONSUMER_ONLY	AZ	39682    MOUs	$.00
ACTUALS	CONSUMER_ONLY	AZ	ACCESS OTHER	REVENUE	47,932.88
ACTUALS	CONSUMER_ONLY	AZ	ACCESS OTHER      UNITS	.00
ACTUALS	CONSUMER_ONLY	AZ	ACCESS OTHER      MOUs	$.00

I have BYDISPLAY on and it does repeat the information except for the "SUM OVER" fields.

Thanks.

This message has been edited. Last edited by: Matthew,

hhmmm. i don't think so. good try, but BYDISPLAY wouldn't work with OVER, not designed for that. Its designed for BY where there are multiple records for each BY field...in your case, you really only have 1 record per BY, even tho you're making it sorta look like 3.
FML is probably the best way to do it for you;
or you could do it the hard way; make 3 separate files
DEFINE FILE ...
MYLABEL/A10='REVENUE';
MYDATA/D11.2=REVENUE_AMOUNT ;
END
TABLE FILE ..
PRINT GRP_TITLE DATATYPE_PARENT EVP_MINUS_1 ST_TITLE GRP_SUF MYLABEL MYDATA
ON TABLE HOLD AS H1
END
DEFINE FILE ...
MYLABEL/A10='UNITS;
MYDATA/D11.2=PRODUCT_FAMILY_BEGINNING_BALAN ;
END
TABLE FILE ..
PRINT GRP_TITLE DATATYPE_PARENT EVP_MINUS_1 ST_TITLE GRP_SUF MYLABEL MYDATA
ON TABLE HOLD AS H2
END
DEFINE FILE ...
MYLABEL/A10='MOUs';
MYDATA/D11.2=MOU_FAMILY ;
END
TABLE FILE ..
PRINT GRP_TITLE DATATYPE_PARENT EVP_MINUS_1 ST_TITLE GRP_SUF MYLABEL MYDATA
ON TABLE HOLD AS H3
END
-RUN
TABLE FILE H1
PRINT *
ON TABLE HOLD AS H4
MORE
FILE H2
MORE
FILE H3
END
-*
-* now do a straight print, or...
SET BYDISPLAY = ON
TABLE FILE H4
SUM MYDATA BY {all those fields}
BY MYFIELD
ON TABLE do whatever
...now you'll have to do some creative formatting to get the dollars to print with a $
Not at all an elegant solution, but you can clearly see the idea, yes?

This message has been edited. Last edited by: susannah,

Thanks for the suggestion. I had this as three separate files and was trying to get it all into one. I'll keep the three files for now unless there is some way to accomplish getting the extra data labels to show on the SUM OVER fields.

ah, then you're ready for FML. Read up on it. You'll really like it. (doc serv will come along and point you.)

I prefer the easy method, use the following for HTML or modify for another format.

DEFINE FILE CAR
DUMMY/A1=' ';
END
TABLE FILE CAR
PRINT COUNTRY AS '' MODEL AS '' CAR AS '' DEALER_COST AS 'Dealer Cost'
OVER COUNTRY AS '' MODEL AS '' CAR AS '' RETAIL_COST AS 'Retail Cost'
BY DUMMY NOPRINT
BY COUNTRY NOPRINT
BY CAR NOPRINT
BY MODEL NOPRINT
ON DUMMY SUBHEAD
"Country <+0>Model <+0>Car <+0>Costs"
ON TABLE SET STYLESHEET *
TYPE = REPORT, GRID = OFF, $
TYPE = SUBHEAD, HEADALIGN = INTERNAL, $
TYPE = SUBHEAD, LINE=1, ITEM=1,COLSPAN=1, STYLE = BOLD, JUSTIFY=LEFT, $
TYPE = SUBHEAD, LINE=1, ITEM=2,COLSPAN=1, STYLE = BOLD, JUSTIFY=LEFT, $
TYPE = SUBHEAD, LINE=1, ITEM=3,COLSPAN=1, STYLE = BOLD, JUSTIFY=LEFT, $
TYPE = SUBHEAD, LINE=1, ITEM=4,COLSPAN=1, STYLE = BOLD, JUSTIFY=LEFT, $
ENDSTYLE
END
-RUN

Greetings,

For information on FML, please refer to the WebFOCUS Creating Financial Reports 7.1 (DN4500710.0505) manual.

You can buy, view, and/or download this manual from the i-Base: The Technical Documentation Library.

If you have an InfoResponse ID, log on to the Tech Support Web site and then access i-Base. By logging in first, you can download the PDF file and/or view the HTMLHelp version.

Hope this helps.

Regards,
Jennifer