quote:

Our disks drives must be made of gold/diamonds/oil because they're very expensive.

quote:

Process: Deleting Hold Files As Your Program Runs

Background:
As a Focus Executable runs, it creates a directory on the server to hold all the data it gathers for immediate and later usage. These files are created as HOLDNAME.ftm (where HOLDNAME is the name you gave it in the 'ON TABLE HOLD AS HOLDNAME' statement). These files can be quite large and can add up in the space consumed on the server. On more than one occasion, we have had situations where all the hold files together caused the server to run out of disk space.

Beginning immediately, it will be considered a best programming practice to clean up large hold files during program execution.


File:
Server > Apps > Standards > DELHOLD.FEX

The program is documented well and fills in some blanks.


When to Use:
Use this in programs where you will generate large datasets and have the potential to run for a long time. Only use this cleanup process when you are done with the file and will not be joining it back or using it again (i.e. via TABLE FILE).


Usage:

TABLE FILE CAR
PRINT
*
ON TABLE HOLD AS FILE1
END
-RUN

-* THE &VERBOSE_DELHOLDFILE PARAMETER IS OPTIONAL.  IF YOU DON'T WANT 
-* SYSTEM MESSAGES BACK, YOU CAN LEAVE IT OUT.
-SET &VERBOSE_DELHOLDFILE = 'ON';

-* THIS VARIABLE MUST MATCH THE HOLDFILE NAME YOU WANT TO DELETE!!!
-SET &HOLDFILETODELETE    = 'FILE1';

-MRNOEDIT -INCLUDE DELHOLD

-*******************************************************************************
-* DELHOLD.FEX
-*******************************************************************************
-* AUTHOR:  Blake Thompson
-*
-* DATE:    20110715
-*
-* PURPOSE: Keep temporary agent directories clean of old hold files during
-*          long running processes or processes that consume lots of diskspace.
-*
-*******************************************************************************
-* REQUIREMENTS
-*******************************************************************************
-* SET THE &HOLDFILETODELETE variable with the name of the holdfile you specified
-* in your program.
-*
-* You MUST set a -RUN before calling this (i.e. after your ON TABLE HOLD statement).
-*
-*******************************************************************************
-* USAGE:
-*******************************************************************************
-*
-*  TABLE FILE CAR
-*  PRINT
-*  *
-*  ON TABLE HOLD AS FILE1
-*  END
-*  -RUN
-*
-*  -SET &HOLDFILETODELETE = 'FILE1';
-*  -MRNOEDIT -INCLUDE DELHOLD
-*
-*******************************************************************************
-* OPTIONS:
-*******************************************************************************
-* -SET &VERBOSE_DELHOLDFILE = 'ON';
-* TO SEE SYSTEM MESSAGES (GOOD FOR DEBUG)
-*
-* YOU CAN IGNORE THE VARIABLE IF YOU YOU DON'T WANT FEEDBACK.
-*
-*******************************************************************************
 
 
-*TABLE FILE CAR
-*PRINT
-**
-*ON TABLE HOLD AS FILE1
-*END
-*-RUN
 
-DEFAULT &VERBOSE_DELHOLDFILE = 'OFF';
 
-*-SET &HOLDFILETODELETE = 'FILE1';
-SET &HOLDFILETODELETE = &HOLDFILETODELETE | '.ftm';
 
-IF &VERBOSE_DELHOLDFILE = 'ON' THEN GOTO DOMSG1 ELSE GOTO SKIPMSG1;
-DOMSG1
-WINNT echo =========BEFORE============
-WINNT cd
-WINNT dir /b
-SKIPMSG1
 
 
-WINNT del &HOLDFILETODELETE
 
 
-IF &VERBOSE_DELHOLDFILE = 'ON' THEN GOTO DOMSG2 ELSE GOTO SKIPMSG2;
-DOMSG2
-WINNT echo.
-WINNT echo =========AFTER=============
-WINNT cd
-WINNT dir /b
-SKIPMSG2