Hi,

I want my Subhead to look structured.
I got more than 1 subhead, and I want it to look like a table without borders, like
"car: "house: "kitchen: and I want the ":" to be underneath each other and the variables <... as well.

is there a command sothat I can arrange them?
I tried with
TYPE=SUBHEAD, ITEM=1, WIDTH=1.7, JUSTIFY=LEFT, WRAP = 1, $
but it lets me just decide how large the fields (for the variables for example) are.

Thanks

This message has been edited. Last edited by: FP Mod Chuck,

WebFOCUS 8.1.05
Windows, All Outputs

Something such as this ?

DEFINE FILE GGSALES
YR      /YY   = DATE;
UNIT97  /P8C  = IF YR EQ 1997 THEN UNITS      ELSE 0;
UNIT96  /P8C  = IF YR EQ 1996 THEN UNITS      ELSE 0;
DOL97   /P8C  = IF YR EQ 1997 THEN DOLLARS    ELSE 0;
DOL96   /P8C  = IF YR EQ 1996 THEN DOLLARS    ELSE 0;
BDG97   /P8C  = IF YR EQ 1997 THEN BUDDOLLARS ELSE 0;
BDG96   /P8C  = IF YR EQ 1996 THEN BUDDOLLARS ELSE 0;
END
TABLE FILE GGSALES
SUM
    UNIT97 NOPRINT
    UNIT96 NOPRINT
    DOL97  NOPRINT
    DOL96  NOPRINT
    BDG97  NOPRINT
    BDG96  NOPRINT
    COMPUTE UNITVAR  /P8C  = UNIT97 - UNIT96; NOPRINT
    COMPUTE DOLVAR   /P8C  = DOL97  - DOL96;  NOPRINT
    COMPUTE BDGVAR   /P8C  = BDG97  - BDG96;  NOPRINT
    COMPUTE UNITCPX  /A20V = 'Nb Units: '  | FPRINT(UNIT97,  'P8C', 'A10V'); NOPRINT
    COMPUTE DOLCPX   /A20V = 'Sales $: '   | FPRINT(DOL97,   'P8C', 'A10V'); NOPRINT
    COMPUTE BDGCPX   /A20V = 'Bdg $: '     | FPRINT(BDG97,   'P8C', 'A10V'); NOPRINT
    COMPUTE UNITPPX  /A20V = 'Nb Units: '  | FPRINT(UNIT96,  'P8C', 'A10V'); NOPRINT
    COMPUTE DOLPPX   /A20V = 'Sales $: '   | FPRINT(DOL96,   'P8C', 'A10V'); NOPRINT
    COMPUTE BDGPPX   /A20V = 'Bdg $: '     | FPRINT(BDG96,   'P8C', 'A10V'); NOPRINT
    COMPUTE VARUNITX /A20V = 'Var Units: ' | FPRINT(UNITVAR, 'P8C', 'A10V'); NOPRINT
    COMPUTE VARDOLX  /A20V = 'Var Sales: ' | FPRINT(DOLVAR,  'P8C', 'A10V'); NOPRINT
    COMPUTE VARBDGX  /A20V = 'Var Bdg: '   | FPRINT(BDGVAR,  'P8C', 'A10V'); NOPRINT

BY REGION NOPRINT

SUBHEAD
"<REGION <+0>1997"
"<UNITCPX<DOLCPX<BDGCPX"
" "
"1996 <+0>Variance"
"<UNITPPX<DOLPPX<BDGPPX<VARDOLX<VARDOLX<VARBDGX"
SUBFOOT
"------------------------------------------------------------------------------------"

ON TABLE PCHOLD FORMAT HTML
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
$
TYPE=REPORT,
     BORDER-TOP=OFF,
     BORDER-BOTTOM=OFF,
     BORDER-LEFT=OFF,
     BORDER-RIGHT=OFF,
     SIZE=10,
     JUSTIFY=CENTER,
$
TYPE=SUBHEAD, LINE=1, OBJECT=FIELD, ITEM=1, WIDTH=3.000, SIZE=12, COLOR=RGB(8 97 74), JUSTIFY=RIGHT, $
TYPE=SUBHEAD, LINE=1, OBJECT=TEXT,  ITEM=2, WIDTH=3.000, SIZE=12, COLOR=RGB(8 97 74), JUSTIFY=LEFT, $
TYPE=SUBHEAD, LINE=2, OBJECT=FIELD, ITEM=1, WIDTH=2.000, SIZE=12, STYLE=BOLD, JUSTIFY=RIGHT, $
TYPE=SUBHEAD, LINE=2, OBJECT=FIELD, ITEM=2, WIDTH=2.000, SIZE=12, STYLE=BOLD, JUSTIFY=CENTER, $
TYPE=SUBHEAD, LINE=2, OBJECT=FIELD, ITEM=3, WIDTH=2.000, SIZE=12, STYLE=BOLD, JUSTIFY=LEFT, $
TYPE=SUBHEAD, LINE=3, OBJECT=TEXT,  ITEM=1, WIDTH=6.000, COLOR=RGB(8 97 74), $
TYPE=SUBHEAD, LINE=4, OBJECT=TEXT,  ITEM=1, WIDTH=3.000, COLOR=RGB(8 97 74), $
TYPE=SUBHEAD, LINE=4, OBJECT=TEXT,  ITEM=2, WIDTH=3.000, COLOR=RGB(8 97 74), $
TYPE=SUBHEAD, LINE=5, OBJECT=FIELD, ITEM=1, WIDTH=1.000, $
TYPE=SUBHEAD, LINE=5, OBJECT=FIELD, ITEM=2, WIDTH=1.000, $
TYPE=SUBHEAD, LINE=5, OBJECT=FIELD, ITEM=3, WIDTH=1.000, $
TYPE=FOOTING, LINE=5, OBJECT=FIELD, ITEM=4, WIDTH=1.000, $
TYPE=SUBHEAD, LINE=5, OBJECT=FIELD, ITEM=5, WIDTH=1.000, $
TYPE=SUBHEAD, LINE=5, OBJECT=FIELD, ITEM=6, WIDTH=1.000, $
ENDSTYLE
END