can a string date ex 20080601 be converted to June 2008? I can not seem to get this to work.

Thanks,

Joe

This message has been edited. Last edited by: Kerry,

Joe,

Where do you need the date? In a heading? in a column? in a DM variable?

Here is one example:

  
-* File JOE1.fex
DEFINE FILE CAR
DATE1/A8YYMD=DECODE COUNTRY (ENGLAND '20070101' FRANCE '20060801' ITALY '20050929' ELSE '20080512');
DATES/YYMD=DATE1;
DATEM/MtrYY=DATES;
END
TABLE FILE CAR
PRINT DATEM DATES DATE1
BY COUNTRY
END

I don't know if you were looking for Dialogue Manager or just in a DEFINE, but I assumed DM.

-SET &GETMTH='20080601' ;
-SET &YM_DATE=CHGDAT('YYMD','MYYX',&GETMTH,'A17');
-SET &YM_LABEL=LCWORD(17,&YM_DATE,'A17');
-TYPE &YM_LABEL

Hi Darin,

The solution works to change to 'June 01 2008', but is there an option to put a comma after the date value so it looks like 'June 01, 2008'?

Thanks.

Best Regards,

Jimmy Pang

Here's one way, there are many:

  
-SET &LST_MO     = DATECVT(DATEADD((DATECVT(&YYMD,'I8YYMD','YYMD')),'M', - 1 ),'YYMD','I8YYMD');
-SET &DT_EOM     = DATECVT((DATEMOV((DATECVT(&LST_MO,'I8YYMD','YYMD')),'EOM')),'YYMD','I8YYMD');
-SET &ENG_DATE1  = LCWORD(17,CHGDAT('YYMD', 'MDYYX', &DT_EOM.EVAL, 'A17'), 'A17');
-SET &ENG_MO     = GETTOK('&ENG_DATE1.EVAL', 17, 1, ' ', 17, 'A17');
-SET &ENG_DA     = GETTOK('&ENG_DATE1.EVAL', 17, 2, ' ', 17, 'A17');
-SET &ENG_YR     = GETTOK('&ENG_DATE1.EVAL', 17, 3, ' ', 17, 'A17');
-SET &ENG_DATE   = &ENG_MO || (' ' | &ENG_DA) || ',' || (' ' | &ENG_YR);
-TYPE &ENG_DATE

This is for the last day of the previous month, but, gives you an example...

For just Month, Year:

  
-SET &ENG_DATE   = &ENG_MO  || ',' || (' ' | &ENG_YR);

hth

Thanks Tom!

That is exactly what I need.
Thanks again.

Best Regards,

Jimmy Pang

And another:

-SET &DATE1 = '20080601';
-SET &DATE2 = CHGDAT('YYMD','YYMXD',&DATE1,'A20');
-SET &DATE3 = LCWORD(20,&DATE2,'A20');
-SET &DATE4 = EDIT(&DATE3,'$$$$$999999999999999') || (', ' | EDIT(&DATE3,'9999$'));

Thanks Dan.
That's another creative way to resolve the issue.

Best Regards,

Jimmy Pang