SQUEEZE · ACROSS

December 19, 2006, 02:59 PM

Francis Mariani

SQUEEZE · ACROSS · EXL2K

TABLE FILE CAR
SUM
SALES
ACROSS SEATS
BY COUNTRY
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLESHEET *
TYPE=DATA, ACROSSCOLUMN=SALES, SQUEEZE=3.0, COLOR=GREEN, $
TYPE=DATA, COLUMN=COUNTRY, SQUEEZE=4.0, COLOR=BLUE, $
ENDSTYLE
END

The Squeeze tag doesn't work for either column, it has no effect on the width of the column in Excel. The COLOR tag works, which means my stylesheet is targeting the correct columns.

I think this is not working because it is an across column, but there is no documentation supporting my theory.

According to the manual:

quote:

Syntax: How to Set Column Width in Excel 2000

TYPE=REPORT, [COLUMN=column,] SQUEEZE={ON|OFF|n}, $

where:

column

Identifies a particular column. If COLUMN is not included in the declaration, the column width specified with SQUEEZE is applied to the entire report.

n

Represents a specific numeric value that the column width can be set to. The value represents the measure specified with the UNITS parameter (the default is inches).

This is the most commonly used SQUEEZE setting in an Excel 2000 report.

Note:

ON/OFF settings for SQUEEZE are not meaningful for EXL2K.

SQUEEZE turns off data wrapping. If a data value is wider than the specified width of the column, it is hidden from view. You can adjust column width in Excel after the spreadsheet has been generated.

Interestingly, in another section of the documentation:

quote:

SQUEEZE can be used as either a SET parameter or a StyleSheet attribute. To control wrapping using SQUEEZE, use the following syntax within a StyleSheet.

TYPE =type, SQUEEZE=value, $

where:

type

Is the report component you wish to affect, such as REPORT, HEADING, or TITLE.

value

Is one of the following:

ON turns on data wrapping. This is the default for HTML output.

OFF turns off data wrapping. This is the default for PDF and PostScript.

n represents a specific numeric value to which the column width can be set (valid only in PDF and PostScript) The value represents the measure specified with the UNITS parameter.

"valid only in PDF and PostScript" - confusing, non?

December 19, 2006, 03:16 PM

mgrackin

Francis,

The way you coded the request does not work in WF 7.1.3 either.

Reread the Documentation and it indicates TYPE=REPORT statements work for Excel.

The following DOES work in WF 7.1.3

TABLE FILE CAR
SUM
SALES
ACROSS SEATS
BY COUNTRY
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLESHEET *
TYPE=REPORT, COLUMN=P2, SQUEEZE=3.00,$
TYPE=REPORT, COLUMN=P3, SQUEEZE=3.00,$
TYPE=REPORT, COLUMN=P4, SQUEEZE=3.00,$
TYPE=DATA, ACROSSCOLUMN=SALES, COLOR=GREEN, $
TYPE=DATA, COLUMN=COUNTRY, COLOR=BLUE, $
ENDSTYLE
END

December 19, 2006, 03:24 PM

Francis Mariani

Mickey, thank you! I did not read the doc correctly!

this also works:

TABLE FILE CAR
SUM
SALES
ACROSS SEATS COLUMNS 1 AND 2 AND 3 AND 4 AND 5 AND 6
BY COUNTRY
ON TABLE PCHOLD FORMAT EXL2K
ON TABLE SET PAGE NOLEAD
ON TABLE SET STYLESHEET *
TYPE=REPORT, ACROSSCOLUMN=SALES, SQUEEZE=4.00,$
ENDSTYLE
END

Thanks very much.