Hi Team,

I've been tasked with building a compound PDF report that has a three level deep Drill-Through. I have no problem building the Drill-Through from the first report to the second, and from the second to the third. When I try to combine the code, however, I do not get the desired behaviour. The first report will drill through to the second report just fine. The second report will only return the focus to the first summary report instead of drilling down to the third report.

I've searched for examples of a three level drill-through, and have not found any. Is this even possible, and if so, how?

Cheers,

Joey
WF 7.1 on Redhat Linux running Tomcat
Informix on Unix

If you are using a single fex to contain multiple outputs then you must use dialog manager and labels
to direct you to the correct part of the code.

That means passing a second variable which is the label name on your drilldown.

Hmm, I'm only vaguely familiar with DM. I usually use Drill-Downs to new reports or the OLAP functionality with dimensions.
If I remember correctly, you are talking about using Goto statements and labels? How does that fit in with the whole Compound PDF deal with Drill Downs. Do you have a code example or a piece of documentation you could refer me to, please?

tia,

Joey

Joey,

The example below does what you need. If you open your PDFs in the browser window the back is useful. If you open them directly in Acrobat then just delete those bits of code.

-*
-*Change FOCEXURL to point to your server
-*
SET FOCEXURL=http://localhost:9080/ibi_apps/WFServlet
-DEFAULTS &TARGET='REPORT1'
-GOTO &TARGET
-REPORT1
TABLE FILE CAR
"Report Number 1"
SUM
RETAIL_COST
SALES
DEALER_COST
BY
COUNTRY
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=DATA,
COLUMN=N1,
FOCEXEC=TARGET(COUNTRY=N1 TARGET='REPORT2'),
$
ENDSTYLE
END
-RUN
-EXIT
-REPORT2
TABLE FILE CAR
"Report Number 2"
"back"
SUM
RETAIL_COST
SALES
DEALER_COST
BY COUNTRY
BY CAR
WHERE COUNTRY EQ '&COUNTRY'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=HEADING,LINE=2,ITEM=1,
FOCEXEC=TARGET(TARGET='REPORT1'),
$
TYPE=DATA,
COLUMN=N2,
FOCEXEC=TARGET(COUNTRY='&COUNTRY.EVAL' CAR=N2 TARGET='REPORT3'),
$
ENDSTYLE
END
-RUN
-EXIT
-REPORT3
TABLE FILE CAR
"Report Number 3"
"back"
SUM
RETAIL_COST
SALES
DEALER_COST
BY COUNTRY
BY CAR
BY MODEL
WHERE COUNTRY EQ '&COUNTRY'
WHERE CAR EQ '&CAR'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=HEADING,LINE=2,ITEM=1,
FOCEXEC=TARGET(COUNTRY='&COUNTRY.EVAL' TARGET='REPORT2'),
$
ENDSTYLE
END
-RUN
-EXIT

I see. Thank you very much for your time!

Hi,

You mentioned Drillthrough, so here is an example . With Drillthrough-functionality you can create a single compound pdf-document with "internal drilldowns".

Regards,
Mika

SET SQUEEZE=ON
SET PAGE-NUM = OFF

TABLE FILE GGSALES
HEADING CENTER
"Report 1"
"Sales Summary by Category"
" "
SUM UNITS BUDUNITS DOLLARS BUDDOLLARS
BY CATEGORY
ON TABLE PCHOLD FORMAT PDF OPEN
ON TABLE SET STYLE *
TYPE=REPORT, FONT=ARIAL, $
TYPE=DATA, TOPGAP=0.1, $
TYPE=DATA, COLUMN=CATEGORY, DRILLTHROUGH=DOWN(CATEGORY), $
END

TABLE FILE GGSALES
SUM UNITS BUDUNITS DOLLARS BUDDOLLARS
BY CATEGORY NOPRINT
BY PRODUCT NOPRINT
ON CATEGORY PAGE-BREAK
HEADING CENTER
"Report 2"
"Sales by Category with Product Summary"
" "
"Category: " "
ON PRODUCT SUBHEAD
"Product: " "
ON PRODUCT UNDER-LINE
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=DATA, TOPGAP=0.1, $
TYPE=REPORT, FONT=ARIAL, $
TYPE=SUBHEAD, LINE=1, ITEM=2, DRILLTHROUGH=DOWN(CATEGORY PRODUCT), $
END

TABLE FILE GGSALES
SUM UNITS BUDUNITS DOLLARS BUDDOLLARS
BY CATEGORY NOPRINT
BY PRODUCT NOPRINT
BY REGION NOPRINT
BY CITY
ON PRODUCT PAGE-BREAK
ON REGION UNDER-LINE
ON REGION SUB-TOTAL
HEADING CENTER
"Report 3"
"Sales Detail Report"
" "
"Category: Product: " "
ON REGION SUBHEAD
"Region: " "
ON TABLE PCHOLD FORMAT PDF CLOSE
ON TABLE SET STYLE *
TYPE=DATA, TOPGAP=0.1, $
TYPE=REPORT, FONT=ARIAL, $
TYPE=HEADING, LINE=4, ITEM=2, DRILLTHROUGH=FIRST(CATEGORY), COLOR=GREEN, $
END

WebFOCUS 7.6.x
PMF 5.2.x

Yes, this is exactly what I ended up doing. At first, I was looking for a way to drill-through to level two and then offer the user a choice of drilling back up or drilling down to level 3. Does not seem possible, so I now offer a drill-through to level 2, another drill through to level 3 and then a drill-through back to level 1.

Cheers,

Joey