I have been working with this for a while now and I am at a loss for why this happens, but when I use the CNT.DST funcntion in a report with an across it seems to break the tabpageno functionality. For example if you run this:

 
TABLE FILE CAR
SUM 
     CNT.DST.CAR.BODY.SEATS AS 'COUNT,DISTINCT,CAR.BODY.SEATS'
BY  LOWEST CAR.ORIGIN.COUNTRY
BY  CAR.COMP.CAR
BY  CAR.CARREC.MODEL
ACROSS CAR.BODY.BODYTYPE
     
-*ON CAR.ORIGIN.COUNTRY SUBHEAD
-*"For <CAR.ORIGIN.COUNTRY "  
-*WHEN 1 EQ 0;
-*ON CAR.ORIGIN.COUNTRY SUBTOTAL AS 'Sub-Total: '  
-*WHEN 1 EQ 0;
-*ON CAR.ORIGIN.COUNTRY SUBFOOT
-*"Total for <CAR.ORIGIN.COUNTRY : <CAR.COMP.CAR "  
-*WHEN 1 EQ 0;
ON CAR.ORIGIN.COUNTRY PAGE-BREAK 
HEADING
"Page <TABPAGENO Of <TABLASTPAGE"
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = endeflt,
$
TYPE=REPORT,
     GRAPHCOLOR='GREEN',
	 size=8,
$
-*TYPE=REPORT,
-*     OBJECT=MENU,
-*     COLOR='WHITE',
-*     HOVER-COLOR=RGB(66 70 73),
-*     BACKCOLOR=RGB(102 102 102),
-*     HOVER-BACKCOLOR=RGB(218 225 232),
-*     BORDER-COLOR='WHITE',
-*$
-*TYPE=REPORT,
-*     OBJECT=STATUS-AREA,
-*     COLOR='WHITE',
-*     BACKCOLOR=RGB(102 102 102),
-*$
-*TYPE=REPORT,
-*     OBJECT=CURRENT-ROW,
-*     HOVER-BACKCOLOR=RGB(218 225 232),
-*     BACKCOLOR=RGB(200 200 200),
-*$
-*TYPE=REPORT,
-*     OBJECT=CALC-AREA,
-*     COLOR='WHITE',
-*     BACKCOLOR=RGB(102 102 102),
-*$
ENDSTYLE
END

 

The header comes up as "Page . of .", but if I take out the DST and just do CNT.CAR.BODY.SEATS or if I remove "ACROSS CAR.BODY.BODYTYPE" then everything works fine.

Has anyone run across anything like this before?

-Ed

This message has been edited. Last edited by: smithec,

Nooo....
This seems to be a B U G!
Open a case with IBI.

I get this error message in 7.6.10. Looks like CNT.DST is not supported in ACROSS for release 7.6.10.

(FOC1864) THE DST OPERATOR IS NOT SUPPORTED WITH ACROSS/FOR/NOSPLIT  

Did a search for FOC1864 and found this in 7.7.03 documentation.
Looks like they added support for ACROSS in 7.7.03 because the message has changed.
Maybe you need to update to the current hotfix of 7.7.03.
Best thing would be to open a case as Danny suggested.
http://ecl.informationbuilders...e/source/topic22.htm

  
(FOC1864) THE DST OPERATOR IS NOT SUPPORTED WITH NOSPLIT

One workaround would be to dump the distinct count to a hold file and then join the hold file back to the datasource.

  
TABLE FILE CAR
SUM
    CNT.DST.SEATS AS 'DST_CNT_SEAT'
BY COUNTRY
BY CAR
BY MODEL
BY BODYTYPE
ON TABLE SET ASNAMES ON
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE HOLD AS H1 FORMAT XFOCUS
END


JOIN INNER
     FILE H1   AT COUNTRY AND CAR AND MODEL AND BODYTYPE TAG T1 TO ALL
     FILE CAR  AT COUNTRY AND CAR AND MODEL AND BODYTYPE TAG T2 AS J1
   WHERE T1.COUNTRY = T2.COUNTRY;
   WHERE T1.CAR = T2.CAR;
   WHERE T1.MODEL = T2.MODEL;
   WHERE T1.BODYTYPE = T2.BODYTYPE;
END


TABLE FILE H1
SUM 
     MAX.DST_CNT_SEAT AS 'COUNT,DISTINCT,CAR.BODY.SEATS'

BY  LOWEST COUNTRY
BY  CAR
BY  MODEL
ACROSS BODYTYPE

ON COUNTRY PAGE-BREAK
HEADING
"Page <TABPAGENO Of <TABLASTPAGE"
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE ROW-TOTAL AS 'TOTAL'
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET BYDISPLAY ON
ON TABLE SET STYLE *
UNITS=IN,PAGESIZE='Letter',LEFTMARGIN=0.250000,RIGHTMARGIN=0.250000,TOPMARGIN=0.250000,BOTTOMMARGIN=0.250000,SQUEEZE=ON,ORIENTATION=LANDSCAPE,$
TYPE=REPORT,FONT='ARIAL',SIZE=8,COLOR='BLACK',STYLE=NORMAL,BORDER=OFF,LEFTGAP=0.05,RIGHTGAP=0.05,$
ENDSTYLE
END

I have opened a case about this and IBI has confirmed this is a bug. From what support said this is present all the way up the chain. Hard to believe I'm the first to try this, but apparently I'm the first to notice/report it.

Some have probably noticed but are using workarounds. Its hard to get a bug fixed unless its top priority. Not sure how big of team they have for bug fixes. I know that there are other bugs that have lasted for years and are not touched even though there are a lot of complaints. The product does have limitations and gotchas like any other software tool. You will learn how to tackle these as you continue your career in WebFocus development.