(SOLVED) Link ON stacked GRAPH BAR

March 15, 2012, 03:40 PM

dreddy_23

I am looking to get a link to be just on BMW column.

The code is below.

GRAPH FILE CAR
SUM
SEATS
BY MODEL
ACROSS CAR
ON GRAPH SET LOOKGRAPH VBRSTK1
ON GRAPH SET GRMERGE ON
ON GRAPH SET GRAPHSTYLE *
setPlace(true);
ENDSTYLE
ON GRAPH SET STYLE *
TYPE=DATA, TARGET='_blank', FOCEXEC=TEST.fex,$
END

Any help is apreciated.

Thanks,
DREDDY.

This message has been edited. Last edited by: dreddy_23,

March 15, 2012, 03:42 PM

Francis Mariani

I'm not near a computer right now so I can't verify, but try the WHEN clause:

TYPE=DATA, WHEN=CAR EQ 'BMW',  TARGET='_blank', FOCEXEC=TEST.fex,$

Francis

Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server

March 15, 2012, 04:09 PM

dreddy_23

I have tried this. It is dislaying the the GRAPH with no error but link doesn't show up.

This message has been edited. Last edited by: dreddy_23,

March 15, 2012, 05:00 PM

Dan Satchell

If it's always the same column, then this works. If the column number will be dynamic, then you have to get more creative.

GRAPH FILE CAR
 SUM SEATS
 BY MODEL
 ACROSS CAR
 ON GRAPH SET LOOKGRAPH VBRSTK1
 ON GRAPH SET GRMERGE ON
 ON GRAPH SET GRAPHSTYLE *
  setPlace(true); 
 ENDSTYLE
 ON GRAPH SET STYLE *
  TYPE=DATA, COLUMN=SEATS(3), TARGET='_blank', FOCEXEC=TEST.fex,$
 ENDSTYLE
END

March 16, 2012, 02:04 AM

Danny-SRL

Carrying on from Dan's suggestion, here is a more general solution:

  
-* File dreddy01.fex
-SET &CAR=BMW;
TABLE FILE CAR
SUM
CAR NOPRINT
COMPUTE LL/I3=LL+1;
BY CAR NOPRINT
WHERE TOTAL CAR EQ '&CAR';
ON TABLE SET HOLDLIST PRINTONLY
ON TABLE SAVE
END
-RUN
-READ SAVE,&POS
-RUN
GRAPH FILE CAR
SUM 
SEATS
BY MODEL
ACROSS CAR
ON GRAPH SET LOOKGRAPH VBRSTK1
ON GRAPH SET GRMERGE ON
ON GRAPH SET GRAPHSTYLE *
setPlace(true); 
ENDSTYLE
ON GRAPH SET STYLE *
TYPE=DATA, COLUMN=SEATS(&POS), TARGET='_blank', FOCEXEC=TEST.fex,$
END

March 16, 2012, 12:39 PM

dreddy_23

Thanks Dan and Danny.
Both the solutions worked fine.

Dreddy.

March 16, 2012, 03:07 PM

Dan Satchell

Another approach:

DEFINE FILE CAR
 DRILL_FLAG/I1 = IF (CAR EQ 'BMW') THEN 1 ELSE 0 ;
END
-*
GRAPH FILE CAR
 SUM DRILL_FLAG NOPRINT
 BY MODEL
-*
 SUM SEATS
 BY MODEL
 ACROSS CAR
 ON GRAPH SET LOOKGRAPH VBRSTK1
 ON GRAPH SET GRMERGE ON
 ON GRAPH SET GRAPHSTYLE *
  setPlace(true);
 ENDSTYLE
 ON GRAPH SET STYLE *
  TYPE=DATA, COLUMN=SEATS(*), WHEN=DRILL_FLAG NE 0, TARGET='_blank', FOCEXEC=TEST.fex,$
 ENDSTYLE
END