Hi,

I am trying to align my HEADER1A to the left and HEADER1B to the right on the same header line in Excel file. Does anyone know how to do it? Thank you.

 
 
DEFINE FILE XXX
HEADER1A/A16 = 'Form: CMS-21E';
HEADER1B/A24 = 'RUN DATE:'|'&DATE';

 
TABLE FILE xxx

"<HEADER1A  <HEADER1B"
 

Thanks,
Pku

This message has been edited. Last edited by: Pku,

This works for HTML:

DEFINE FILE CAR
HEADER1A/A16 = 'FORM: CMS-21E';
HEADER1B/A24 = 'RUN DATE:'|'&DATE';
END
 
TABLE FILE CAR
SUM 
SALES
BY COUNTRY
BY CAR
BY MODEL
BY SEATS

HEADING
"<HEADER1A<HEADER1B"
ON TABLE SET STYLE *
TYPE=HEADING, HEADALIGN=INTERNAL, $
TYPE=HEADING, ITEM=2, JUSTIFY=RIGHT, COLOR=BLUE, $
ENDSTYLE

END

EXL2K is a little nasty. This appears to work (someone else may have a better idea):

DEFINE FILE CAR
HEADER1A/A16 = 'FORM: CMS-21E';
HEADER1B/A24 = 'RUN DATE:'|'&DATE';
END
 
TABLE FILE CAR
SUM 
SALES
BY COUNTRY
BY CAR
BY MODEL
BY SEATS

HEADING
"<HEADER1A <+0> <+0> <HEADER1B"

ON TABLE SET STYLE *
TYPE=HEADING, HEADALIGN=BODY, $
ENDSTYLE

ON TABLE PCHOLD FORMAT EXL2K
END

Put one "<+0> " per column to have the second part of the Heading aligned to the last column.

Hi Francis,

I tried your technique, but it did not work.(I did have "<+0>" per column to push the second header to the last column).

Thanks,
Pku

There must be a space character after each <+0>

In our shop, when we want to right justify part of the header and left justify the rest of the header in EXCEL the way you described, we use the method that Francis described.

Remember also, to make sure to include line I've bolded TYPE=HEADING, HEADALIGN=BODY, $in Francis code below or "<+0>" will not work.

DEFINE FILE CAR
HEADER1A/A16 = 'FORM: CMS-21E';
HEADER1B/A24 = 'RUN DATE:'|'&DATE';
END
 
TABLE FILE CAR
SUM 
SALES
BY COUNTRY
BY CAR
BY MODEL
BY SEATS

HEADING
"<HEADER1A <+0> <+0> <HEADER1B"

ON TABLE SET STYLE *
[B]TYPE=HEADING, HEADALIGN=BODY, $[/B]
ENDSTYLE

ON TABLE PCHOLD FORMAT EXL2K
END

Goodness me. I tried.

There is no way to do this as far as I know by using the HOLD FORMAT EXL2K. There is a way to fool the browser to open the HTML output as an Excel file. Then you can use HOLD FORMAT HTML and all the supported formatting that goes along with it. The key is SET HTMLFORMTYPE = XLS.

SET HTMLFORMTYPE = XLS
DEFINE FILE CAR
HEADER1A/A16 = 'FORM: CMS-21E';
HEADER1B/A24 = 'RUN DATE:'|'&DATE';
END
TABLE FILE CAR
SUM
SALES
BY COUNTRY
BY CAR
BY MODEL
BY SEATS
-**********
-* No space between fields in the HEADING
-**********
HEADING
"<HEADER1A<HEADER1B"
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=HEADING, HEADALIGN=BODY,$
TYPE=HEADING, LINE=1, OBJECT=FIELD, ITEM=1, COLSPAN=2,$
TYPE=HEADING, LINE=1, OBJECT=FIELD, ITEM=2, COLSPAN=3, JUSTIFY=RIGHT,$
ENDSTYLE
ON TABLE HOLD FORMAT HTML
END
-RUN
-HTMLFORM BEGIN
!IBI.FIL.HOLD;
-HTMLFORM END

While perhaps ugly, the code I posted works in WF 5.3.2 and 7.6.5.

Francis,

Absolutely. And it is not ugly, it is going by the book...

The real problem is that one has to use different coding per output type.

This is very similar to Mickey's answer, but I wanted to point out that you can PCHOLD the file format EXL2K and that you don't need the OBJECT in the stylesheet. It is a whole lot easier to count the number of items without worrying whether they are text or fields.

 DEFINE FILE CAR
HEADER1A/A16 = 'FORM: CMS-21E';
HEADER1B/A24 = 'RUN DATE:'|'&DATE';
END
 
TABLE FILE CAR
SUM 
SALES
BY COUNTRY
BY CAR
BY MODEL
BY SEATS

HEADING
"<HEADER1A<HEADER1B"

ON TABLE SET STYLE *
TYPE=HEADING, HEADALIGN=BODY, $
TYPE=HEADING,
ITEM=1,
COLSPAN=2,
$
TYPE=HEADING,
ITEM=2,
COLSPAN=3,
JUSTIFY=RIGHT,
$
ENDSTYLE

ON TABLE PCHOLD FORMAT EXL2K
END

I tried going directly to EXL2K format and for some reason it would not respect the COLSPAN. However, it looks like it does even though the manual says it does not.

Definitely use the solution from PBrightwell.

I got it. Thanks all.

Pku

This message has been edited. Last edited by: Pku,