Hi All
Whats the best way to align labels and data for a report that is in SUBHEAD (no PRINT Columns)
In a PDF Format
Thanks

Here is the code

TABLE FILE CAR
SUM 
     'CAR.CAR.CAR' NOPRINT
BY 'CAR.CAR.COUNTRY' NOPRINT
BY 'CAR.CAR.MODEL' NOPRINT
     
ON CAR.CAR.COUNTRY SUBHEAD
"Country <+0 Car <+0 Model <+0 Bodytype"
     
ON CAR.CAR.MODEL SUBHEAD
"<CAR.CAR.COUNTRY <CAR.CAR.CAR <CAR.CAR.MODEL <CAR.CAR.BODYTYPE "
HEADING
"PDF Sample Report  Under SUBHEAD"
FOOTING
""
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     PAGESIZE='Letter',
     SQUEEZE=ON,
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=TITLE,
     STYLE=-UNDERLINE,
$
TYPE=TABHEADING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=TABFOOTING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=HEADING,
     LINE=1,
     JUSTIFY=CENTER,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     BY=1,
     FONT='ARIAL NARROW',
     COLOR='WHITE',
     BACKCOLOR='BLUE',
$
TYPE=SUBHEAD,
     BY=1,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=1,
     LINE=1,
     OBJECT=TEXT,
     ITEM=2,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=1,
     LINE=1,
     OBJECT=TEXT,
     ITEM=3,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=1,
     LINE=1,
     OBJECT=FIELD,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=1,
     LINE=1,
     OBJECT=FIELD,
     ITEM=2,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=1,
     LINE=1,
     OBJECT=FIELD,
     ITEM=3,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=2,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=2,
     LINE=1,
     OBJECT=TEXT,
     ITEM=2,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=2,
     LINE=1,
     OBJECT=TEXT,
     ITEM=3,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=2,
     LINE=1,
     OBJECT=FIELD,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=2,
     LINE=1,
     OBJECT=FIELD,
     ITEM=2,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBHEAD,
     BY=2,
     LINE=1,
     OBJECT=FIELD,
     ITEM=3,
     JUSTIFY=LEFT,
     WIDTH=1.000,
$
TYPE=SUBFOOT,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBTOTAL,
     BACKCOLOR=RGB(210 210 210),
$
TYPE=ACROSSVALUE,
     SIZE=9,
$
TYPE=ACROSSTITLE,
     STYLE=BOLD,
$
TYPE=GRANDTOTAL,
     BACKCOLOR=RGB(210 210 210),
     STYLE=BOLD,
$
ENDSTYLE
END


  

This message has been edited. Last edited by: <Kathryn Henning>,

quote:

"<CAR.CAR.COUNTRY <CAR.CAR.CAR <CAR.CAR.MODEL <CAR.CAR.BODYTYPE "

Be very careful when using fields within headings etc. as a space character between fields is considered as another column!

ON MODEL SUBHEAD
"<COUNTRY<CAR<MODEL<BODYTYPE"

A quick tip to help you understand why columns are, seemingly, not respected in the output is to just add a different "backcolor" to each column in your style section so that it stands out.

TABLE FILE CAR
BY COUNTRY NOPRINT
BY MODEL NOPRINT
ON COUNTRY SUBHEAD
"Country<+0 Car<+0 Model<+0 Bodytype"
ON MODEL SUBHEAD
"<COUNTRY <CAR <MODEL <BODYTYPE"
HEADING
"PDF Sample Report Under SUBHEAD"
ON TABLE SET PAGE NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
  units=in, pagesize='letter', squeeze=on, orientation=landscape, $
  type=report, grid=off, font='arial', size=9, $
  type=heading, line=1, justify=center, size=12, style=bold, $
  type=subhead, size=10, style=bold, by=1, font='arial narrow', color='white', backcolor='blue', $
  type=subhead, by=1, item=1, justify=left, width=1.50, $
  type=subhead, by=1, item=2, justify=left, width=1.00, $
  type=subhead, by=1, item=3, justify=left, width=2.00, $
  type=subhead, by=1, item=4, justify=left, width=1.50, wrap=1.50, $
  type=subhead, by=2, item=1, justify=left, width=1.50, backcolor=red, $
  type=subhead, by=2, item=2, justify=left, width=1.00, backcolor=blue, $
  type=subhead, by=2, item=3, justify=left, width=2.00, backcolor=green, $
  type=subhead, by=2, item=4, justify=left, width=1.50, backcolor=aqua, wrap=1.50, $
ENDSTYLE
END

T

This message has been edited. Last edited by: Tony A,

Thanks Tony..
I do use color to help myself.. I worked on creating HTML and Excel format for the long report I am working, now on PDF format.

On my end, did not see Item=4 wrap?
After the last column (Item=4) color runs off right to the end of the page.. Is there a way show color only for the length of the Last Item?

Thanks

 
TABLE FILE CAR
BY COUNTRY NOPRINT
BY MODEL NOPRINT
ON COUNTRY SUBHEAD
"Country<+0>Car<+0>Model<+0>Bodytype"
ON MODEL SUBHEAD
"<COUNTRY<+0><CAR<+0><MODEL<+0><BODYTYPE"
HEADING
"PDF Sample Report Under SUBHEAD"
ON TABLE SET PAGE NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
  UNITS=IN, PAGESIZE='LETTER', SQUEEZE=ON, ORIENTATION=LANDSCAPE, $
  TYPE=REPORT, GRID=OFF, FONT='ARIAL', SIZE=9, $
-* Label Row
  TYPE=HEADING, LINE=1, JUSTIFY=CENTER, SIZE=12, STYLE=BOLD, $
-* Font and Color of the Label Row Contents NO WIDTH 
  TYPE=SUBHEAD, SIZE=10, STYLE=BOLD, BY=1,FONT='ARIAL NARROW', COLOR='WHITE', BACKCOLOR='BLUE', $
-* Size/Width of the Label Contents  (Color and Font size come from above line)
  TYPE=SUBHEAD, BY=1, ITEM=1, JUSTIFY=LEFT, WIDTH=1.5,$
  TYPE=SUBHEAD, BY=1, ITEM=2, JUSTIFY=LEFT, WIDTH=1.00, $
  TYPE=SUBHEAD, BY=1, ITEM=3, JUSTIFY=LEFT, WIDTH=2.00, $
  TYPE=SUBHEAD, BY=1, ITEM=4, JUSTIFY=LEFT, WIDTH=1.50, WRAP=1, $
  TYPE=SUBHEAD, BY=2, ITEM=1, JUSTIFY=LEFT, WIDTH=1.50, BACKCOLOR=RED, $
  TYPE=SUBHEAD, BY=2, ITEM=2, JUSTIFY=LEFT, WIDTH=1.00, BACKCOLOR=YELLOW, $
  TYPE=SUBHEAD, BY=2, ITEM=3, JUSTIFY=LEFT, WIDTH=2.00, BACKCOLOR=GREEN, $
  TYPE=SUBHEAD, BY=2, ITEM=4, JUSTIFY=LEFT, WIDTH=1.50, BACKCOLOR=AQUA, WRAP=1, $
ENDSTYLE
END


 

quote:

On my end, did not see Item=4 wrap?

Shorten the width and wrap sizes to something less than the length of displayed values - e.g. 0.5.

quote:

After the last column (Item=4) color runs off right to the end of the page.. Is there a way show color only for the length of the Last Item?

Easy, add a trailing > after the last field -

ON MODEL SUBHEAD
"<COUNTRY<+0><CAR<+0><MODEL<+0><BODYTYPE>"

T

Thanks Again..

Why it would not wrap the label row Item=4 ?

How do you use > when its a text in the subhead to control the running of color to the right of the column..?

Thanks

 
TABLE FILE CAR
BY COUNTRY NOPRINT
BY MODEL NOPRINT
ON COUNTRY SUBHEAD
"Country<+0>Car<+0>Model<+0>Bodytype Bodytpe Wrap<+0>"
ON MODEL SUBHEAD
"<COUNTRY<+0><CAR<+0><MODEL<+0><BODYTYPE>"
HEADING
"PDF Sample Report Under SUBHEAD"
ON TABLE SET PAGE NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
  UNITS=IN, PAGESIZE='LETTER', SQUEEZE=ON, ORIENTATION=LANDSCAPE, $
  TYPE=REPORT, GRID=OFF, FONT='ARIAL', SIZE=9, $
-* Label Row
  TYPE=HEADING, LINE=1, JUSTIFY=CENTER, SIZE=12, STYLE=BOLD, $
-* Font and Color of the Label Row Contents NO WIDTH
  TYPE=SUBHEAD, SIZE=10, STYLE=BOLD, BY=1,FONT='ARIAL NARROW', COLOR='WHITE', BACKCOLOR='BLUE', $
-* Size/Width of the Label Contents  (Color and Font size come from above line)
  TYPE=SUBHEAD, BY=1, ITEM=1, JUSTIFY=LEFT, WIDTH=1.5,$
  TYPE=SUBHEAD, BY=1, ITEM=2, JUSTIFY=LEFT, WIDTH=1.00, $
  TYPE=SUBHEAD, BY=1, ITEM=3, JUSTIFY=LEFT, WIDTH=2.00, $
  TYPE=SUBHEAD, BY=1, ITEM=4, OBJECT=TEXT, JUSTIFY=LEFT, WIDTH=.500, WRAP=.500, $
  TYPE=SUBHEAD, BY=2, ITEM=1, JUSTIFY=LEFT, WIDTH=1.50, BACKCOLOR=RED, $
  TYPE=SUBHEAD, BY=2, ITEM=2, JUSTIFY=LEFT, WIDTH=1.00, BACKCOLOR=YELLOW, $
  TYPE=SUBHEAD, BY=2, ITEM=3, JUSTIFY=LEFT, WIDTH=.500, BACKCOLOR=GREEN,WRAP=.5, $
  TYPE=SUBHEAD, BY=2, ITEM=4, JUSTIFY=LEFT, WIDTH=.500, BACKCOLOR=AQUA, WRAP=.5, $
ENDSTYLE
END

 

When it's text, force the next column by adding a non-printed character or space.

ON COUNTRY SUBHEAD
"Country<+0>Car<+0>Model<+0>Bodytype<+0> "
ON MODEL SUBHEAD
"<COUNTRY<CAR<MODEL<BODYTYPE>"

T

Quote from help files -

For PDF reports, WRAP is supported only with embedded fields, not text.

T

Thanks Tony..
I changed the text to define field.

quote:

Thanks Tony..

A pleasure, glad to have assisted

T