I have a group of reports that report against a directory of flatfiles (csv's).

//nasserver/dev/inbound this synonym is called elasped_time_csv.

Now we are ready to go in to production so I need to change these reports to report against flatfiles
located in a different location.

//nasserver/prod/inbound.

I have already added the new ODBC adapter for the new location.

Questions:

Can I copy the current synonym then text edit the new location in and rename the copy to prod_elasped_time_csv?

Once I have the new synonym is there a better way to update the reports then going in to the source of each report and adding 'prod_' to every instance of 'elasped_time_csv" ?

I was thinking of just editing the location of the flatfiles in the synonym, to the production location, but I still need a set a reports that report against the development server flatfiles.

This message has been edited. Last edited by: Kerry,

Can you post a sample master file and access file?

I'm thinking that you do not need another data adapter.
The csv file that is defined in the DATASET of the master file is the default data source.
You should be able to overwrite the input csv file using a FILEDEF.

  
-SET &ENVIRONMENT = 'PROD';
-SET &LOCATION    = IF (&ENVIRONMENT EQ 'PROD') THEN '\\nasserver\prod\inbound\elasped_time.csv' ELSE '\\nasserver\dev\inbound\elasped_time.csv';

FILEDEF CSV_FILE DISK &LOCATION
-RUN

TABLE FILE CSV_FILE
PRINT
   FIELD1
   FIELD2
END

Current ACX

 SEGNAME=ELAPSED_TIME_CSV, DELIMITER=',', ENCLOSURE=", HEADER=NO,
CONNECTION=&&FL_CONNECTION, 
DIRECTORY=&&FL_DIRECTORY, NAME=&&FL_NAME, 
EXTENSION=&&FL_EXTENSION, DATA_ORIGIN=FILE, $
 

Currrent MAS:

 FILENAME=ELAPSED_TIME_CSV, SUFFIX=DFIX ,$
VARIABLE NAME=&&FL_DIRECTORY, DEFAULT='\\NAS5\Psoftdev\TCD\Inbound', $
VARIABLE NAME=&&FL_NAME,  DEFAULT='elapsed_time*', $
VARIABLE NAME=&&FL_EXTENSION, DEFAULT='csv', $
VARIABLE NAME=&&FL_CONNECTION,  $
  SEGMENT=ELAPSED_TIME_CSV, SEGTYPE=S0, $
    FIELDNAME=F1, ALIAS=F1, USAGE=A255V, ACTUAL=A255V,
      MISSING=ON, $
    FIELDNAME=F2, ALIAS=F2, USAGE=A255V, ACTUAL=A255V,
      MISSING=ON, $
    FIELDNAME=F3, ALIAS=F3, USAGE=A255V, 

[COLOR:RED]AND SO ON[/COLOR]

    FIELDNAME=F25, ALIAS=F25, USAGE=A255V, ACTUAL=A255V,
      MISSING=ON, $
DEFINE ALPHAF5/A10=SUBSTV(255,F5, 1, 10,ALPHAF5);$
DEFINE DATE1/A8YYMD=EDIT(ALPHAF5,'9999$99$99');$
DEFINE F5/YYMD=DATE1;$ 

How would I change Max's code above the give the report runner a dropdown menu to choose 'Production' or 'Developement'?

Does this code need to go in to the header of each report? OR can it go in the MAS?

Greg,
For Max's suggestion, your FEX could look like this. This example would look for MFDs called DEV_CAR, UAT_CAR and PRD_CAR, so unless those exist, you'll get an error when running.

-PROMPT &ENV.(<Development,DEV_>,<User Acceptance Test,UAT_>,<Production,PRD_>).Choose Reporting Environment:.;

-SET &CAR =  &ENV | 'CAR';

-TYPE &|ENV = &ENV
-TYPE &|CAR = &CAR

TABLE FILE &CAR
PRINT
*
END

There are other ways to solve this issue as well, but this is a good place to start.

- ABT

You are using the new feature of variables in the master file. In this case you will need a data adapter for production.
Set the value of &&FL_CONNECTION to the name of the data adapter for production. Set the value &&FL_DIRECTORY to the production folder.
You can place the code in a fex and INCLUDE it at the top of the report.

  
-PROMPT &ENV.(<Development,DEV>,<User Acceptance Test,UAT>,<Production,PRD>).Choose Reporting Environment:.;

-SET &&FL_CONNECTION = DECODE &ENV ('DEV' 'DEV_ADAPTER_NAME' 'UAT' 'UAT_ADAPTER_NAME' 'PRD' 'PRD_ADAPTER_NAME');
-SET &&FL_DIRECTORY = DECODE &ENV ('DEV' '\\NAS5\Psoftdev\TCD\Inbound' 'UAT' '\\NAS5\Psoftuat\TCD\Inbound' 'PRD' '\\NAS5\Psoftprod\TCD\Inbound');

TABLE FILE ELAPSED_TIME_CSV
PRINT *
END

This message has been edited. Last edited by: Mighty Max,