Hi I have a report that is set to have a page break on the first sort field. I would like to add a dynamic footer that displays only on certain pages. I've tried reviewing the documentation and searching posts but have had no luck. I tried to accomplish this with setting a parameter but of course it only passes the field name and not the value for each page.
Here is an example of where I tried the parameters with the car file:
-SET &ECHO = ALL;
-SET &COUNTRY = '<CAR.ORIGIN.COUNTRY';
-SET &FOOTER_C = IF '<CAR.ORIGIN.COUNTRY' EQ 'England' THEN '3. INSERT THIS NEW FOOTER - FOOTER C' ELSE '';
TABLE FILE CAR
SUM
CAR.BODY.SALES
BY CAR.ORIGIN.COUNTRY NOPRINT
BY CAR.COMP.CAR
BY CAR.CARREC.MODEL
ACROSS LOWEST CAR.BODY.SEATS
ON CAR.ORIGIN.COUNTRY SUBTOTAL AS '*TOTAL'
ON CAR.ORIGIN.COUNTRY PAGE-BREAK
HEADING
"&COUNTRY"
FOOTING
"1. Footer A"
"2. Footer B"
"&FOOTER_C"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,
$
ENDSTYLE
END
Are there any ideas on how to get a dynamic footer to show up on certain pages in a report that has a page break? Thanks! CaraThis message has been edited. Last edited by: cldiaz,
WebFOCUS 8204 Windows, All Outputs
June 25, 2019, 03:00 PM
BabakNYC
WebFOCUS doesn't know the value of the field before TABLE FILE. Consequently, you can't use -SET here. Maybe you can use something like this:
DEFINE FILE CAR
FOOTER1/A40= IF COUNTRY EQ 'ENGLAND' THEN '3. INSERT THIS NEW FOOTER - FOOTER C' ELSE '';
END
TABLE FILE CAR
SUM
CAR.BODY.SALES
BY CAR.ORIGIN.COUNTRY NOPRINT
BY CAR.COMP.CAR
BY CAR.CARREC.MODEL
ACROSS LOWEST CAR.BODY.SEATS
ON CAR.ORIGIN.COUNTRY SUBTOTAL AS '*TOTAL'
ON CAR.ORIGIN.COUNTRY PAGE-BREAK
HEADING
"<COUNTRY"
FOOTING
"1. Footer A"
"2. Footer B"
"<FOOTER1"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/warm.sty,
$
ENDSTYLE
END
WebFOCUS 8206, Unix, Windows
June 25, 2019, 03:08 PM
cldiaz
Thank you! Thank you! Thank you! Yes, that will work exactly how I need it!