SOLVED - AS400 Configuration problem ??

July 24, 2009, 01:15 PM

Cati - France

Hello,

I have two AS400 with the 7.6.7 release installed.
When I run the fex above on the AS400 number 1, It gives me the correct result with all the borders as defined.
When I run the same fex on the AS400 number 2, all the borders are missing.
If somebody has any idea of what is not correct in the AS400 number 2.......
Merci beaucoup (Thanks a lot).
Catherine

  
SET PRINTPLUS = ON
SET LINES = 99999

-SET &DATEEDT = EDIT(&DMYY,'99/99/9999');
SQL DB2 PREPARE SQLOUT FOR
SELECT A.ADNIV2, C.ENLNOM AS NOMFD,
COUNT(*) AS NBFICHES,
COUNT(CASE WHEN ADCSUP <> ' ' THEN 1 END) AS NBSUPP,
COUNT(CASE WHEN (PA02 = 'O' AND ADCSUP <> ' ') THEN 1 END) AS NBCOLSUPP,
SUM(CASE WHEN (D.PA04 <> ' ' AND ADCSUP = ' ') THEN INT(TRIM(D.PA04))
         ELSE 0 END) AS NBDONATEURS,
COUNT(CASE WHEN (PA02 = 'O' AND ADCSUP = ' ' ) THEN 1 END) AS NBCOLLECTEURS,
COUNT(CASE WHEN (PA17 = '4J' AND ADCSUP = ' ') THEN 1 END) AS NBENFANTS,
COUNT(CASE WHEN (PA17 LIKE 'SM%' AND ADCSUP = ' ') THEN 1 END) AS NBMEDECINS
FROM   COTSSPDB2/ADRESP A, COTSSPDB2/VUE_ENTITE C,
       COTSSPDB2/CODADP D
WHERE  A.ADNIV2 = C.ENTITE
  AND  A.ADIDEN = D.COIDEN
GROUP BY A.ADNIV2, C.ENLNOM;
END
TABLE FILE SQLOUT
PRINT *
ON TABLE HOLD AS TMP_PAR1 FORMAT ALPHA
END
DEFINE FILE TMP_PAR1
FD/A10= '&|#160;' | ADNIV2;
END
TABLE FILE TMP_PAR1
PRINT
     NOMFD AS 'Nom,'
     NBFICHES/D7S AS 'Nb,Fiches'
     NBSUPP/D7S AS 'Nb,Sup'
     NBDONATEURS/D7S AS 'Nb,Donat'
     NBCOLLECTEURS/D6S AS 'Nb,Collec'
     NBCOLSUPP/D5S AS 'Nb Col,Sup'
     NBENFANTS/D5S AS 'Nb,Enf'
     NBMEDECINS/D5S AS 'Nb,Méd'
BY FD AS 'FD,'

ON TABLE SET PAGE-NUM OFF
ON TABLE COLUMN-TOTAL AS 'TOTAL'
ON TABLE HOLD AS STATPAR1 FORMAT HTMTABLE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     PAGESIZE='A3',
     LEFTMARGIN=0.250000,
     RIGHTMARGIN=0.250000,
     TOPMARGIN=0.250000,
     BOTTOMMARGIN=0.000000,
     SQUEEZE=ON,
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,FONT='TAHOMA',SIZE=10,COLOR='BLACK',BACKCOLOR='NONE',STYLE=BOLD,$
TYPE=DATA,BORDER-TOP=LIGHT,BORDER-BOTTOM=LIGHT,BORDER-LEFT=LIGHT,BORDER-RIGHT=LIGHT,BORDER-TOP-STYLE=RIDGE,
     BORDER-BOTTOM-STYLE=RIDGE,BORDER-LEFT-STYLE=RIDGE,BORDER-RIGHT-STYLE=RIDGE,BORDER-TOP-COLOR=RGB(0 112 121),
	 BORDER-BOTTOM-COLOR=RGB(0 112 121),BORDER-LEFT-COLOR=RGB(0 112 121),
     BORDER-RIGHT-COLOR=RGB(0 112 121),SIZE=8,BACKCOLOR=('WHITE' ),$
TYPE=TITLE,BORDER-TOP=LIGHT,BORDER-BOTTOM=LIGHT,BORDER-LEFT=LIGHT,BORDER-RIGHT=LIGHT,BORDER-TOP-STYLE=RIDGE,
     BORDER-BOTTOM-STYLE=RIDGE,BORDER-LEFT-STYLE=RIDGE,BORDER-RIGHT-STYLE=RIDGE,BORDER-TOP-COLOR=RGB(0 112 121),
     BORDER-BOTTOM-COLOR=RGB(0 112 121),BORDER-LEFT-COLOR=RGB(0 112 121),BORDER-RIGHT-COLOR=RGB(0 112 121),
     SIZE=9,COLOR='WHITE',BACKCOLOR=RGB(0 183 206),STYLE=BOLD,$
TYPE=DATA,COLUMN=N1,JUSTIFY=LEFT,$
TYPE=TITLE,COLUMN=N3,SIZE=8,$
TYPE=TITLE,COLUMN=N4,SIZE=8,$
TYPE=TITLE,COLUMN=N5,SIZE=8,JUSTIFY=CENTER,$
TYPE=TITLE,COLUMN=N6,SIZE=8,JUSTIFY=CENTER,$
TYPE=TITLE,COLUMN=N7,SIZE=8,JUSTIFY=CENTER,$
TYPE=TITLE,COLUMN=N8,SIZE=8,JUSTIFY=CENTER,$
TYPE=TITLE,COLUMN=N9,SIZE=8,JUSTIFY=CENTER,$
TYPE=TITLE,COLUMN=N10,SIZE=8,JUSTIFY=CENTER,$
TYPE=TITLE,COLUMN=N11,SIZE=8,JUSTIFY=CENTER,$
TYPE=GRANDTOTAL,SIZE=9,COLOR=RGB(0 112 121),BACKCOLOR='WHITE',STYLE=BOLD,BORDER-TOP=LIGHT,
     BORDER-BOTTOM=LIGHT,BORDER-LEFT=LIGHT,BORDER-RIGHT=LIGHT,BORDER-TOP-STYLE=RIDGE,BORDER-BOTTOM-STYLE=RIDGE,
     BORDER-LEFT-STYLE=RIDGE,BORDER-RIGHT-STYLE=RIDGE,BORDER-TOP-COLOR=RGB(0 112 121),BORDER-BOTTOM-COLOR=RGB(0 112 121),
     BORDER-LEFT-COLOR=RGB(0 112 121),BORDER-RIGHT-COLOR=RGB(0 112 121),$
ENDSTYLE
END

SET HTMLFORMTYPE=XLS
-HTMLFORM BEGIN
<html>
<STYLE>
.coti {font-family:verdana;font-weight:bold;font-size:14px;background-color:#00B7CE}
</STYLE>
  <TABLE border="0">
    <tr>
      <td colspan="15" align="center" class="coti">Secours Populaire Français
      </td>
    </tr>
    <tr>
      <td colspan="15" align="center" class="coti">Statistiques paramètres au : !IBI.AMP.DATEEDT;
      </td>
    </tr>
    <tr><td colspan="15"></tr>
    !IBI.FIL.STATPAR1;
  </table>
</Html>
-HTMLFORM END

This message has been edited. Last edited by: Cati - France,

July 30, 2009, 11:17 AM

Kerry

Hi Catherine,

Is it possible that the settings are different? Did you issue a '? SET' ?
Maybe a setting like GRID is changed?
Just a thought.

Cheers,

Kerry

July 31, 2009, 02:35 AM

Cati - France

HI Kerry,

Thanks for your answer.
I did what you suggested, all the parameters are exactly the same on both AS400 when I do ? SET.
I don't know where to search in the configuration files to resolve this problem.
If you have another idea, you're welcome !

Merci (Thank you).
Catherine

July 31, 2009, 12:37 PM

Cati - France

In case of someone get the same problem :

The french IBI support found the source of the problem.
There is a system value named QLOCALE which had the following value on our system N° 2 : /QSYS.LIB/FR_FR.LOCALE
The user's profile have a parameter named LOCALE and the default value of this parameter is *SAME.
We just put this parameter to *NONE for the user's profile and It works.

Explanation : when the excel file is generated, in the style, the border is defined with 1,00pt instead of 1.00pt (the point was replaced by a comma in french OS/400)

Catherine