I have a FOCUS DB that contains an HYYMDS field.

I'd like to use MODIFY to insert rows into this DB. I'm having trouble formatting the input data for this field.

-SET &ST_DATE = EDIT(&YYMD,'9999/99/99');
-SET &ST_TIME = EDIT(HHMMSS('A8'),'99$99$99');

-SET &EN_DATE = EDIT(&YYMD,'9999/99/99');
-SET &EN_TIME = EDIT(HHMMSS('A8'),'99$99$99');

MODIFY FILE FOCDB1
FREEFORM ST_DTTM/17
FREEFORM EN_DTTM/17

DATA
ST_DTTM=&ST_DATE &ST_TIME,
EN_DTTM=&EN_DATE &EN_TIME,$
END

With this code, I get this error:

(FOC210) THE DATA VALUE HAS A FORMAT ERROR: 2011/05/11 142011

Any ideas?

Thanks,

This message has been edited. Last edited by: Francis Mariani,

I would prefer not to do it this way, but I can make it work by creating an intermediary HOLD file:

-SET &ST_DATE = &YYMD;
-SET &ST_TIME = EDIT(HHMMSS('A8'),'99$99$99');

-SET &EN_DATE = &YYMD;
-SET &EN_TIME = EDIT(HHMMSS('A8'),'99$99$99');

SET HOLDFORMAT=ALPHA
SET ASNAMES=ON
SET HOLDLIST=PRINTONLY

TABLE FILE CAR
PRINT COUNTRY NOPRINT
COMPUTE ST_DTTM1/A14   = '&ST_DATE' | '&ST_TIME'; NOPRINT
COMPUTE ST_DTTM/HYYMDS = HINPUT(14, ST_DTTM1, 8, 'HYYMDS');
COMPUTE EN_DTTM1/A14   = '&EN_DATE' | '&EN_TIME'; NOPRINT
COMPUTE EN_DTTM/HYYMDS = HINPUT(14, EN_DTTM1, 8, 'HYYMDS');
WHERE RECORDLIMIT EQ 1
ON TABLE HOLD AS H001
END
-RUN

MODIFY FILE FOCDB1
FIXFORM FROM H001
DATA ON H001
END
-RUN

The time needs to have ':' in for correct format.

APP FI MASTER DISK DB1.MAS
-RUN
-WRITE MASTER FILENAME=DB1, SUFFIX=FOC     , $
-WRITE MASTER   SEGMENT=SEG, SEGTYPE=S1, $
-WRITE MASTER     FIELDNAME=KEY, USAGE=A1, $
-WRITE MASTER     FIELDNAME=DATE, USAGE=HYYMDS, $

CREATE FILE DB1

-SET &ST_DATE = EDIT(&YYMD,'9999/99/99');
-SET &ST_TIME = EDIT(HHMMSS('A8'),'99$:99$:99'); 

-SET &EN_DATE = EDIT(&YYMD,'9999/99/99');
-SET &EN_TIME = EDIT(HHMMSS('A8'),'99$:99$:99'); 

MODIFY FILE DB1
FREEFORM KEY DATE
DATA
A,&ST_DATE &ST_TIME,$
B,&EN_DATE &EN_TIME,$
END
-RUN
TABLE FILE DB1
PRINT *
END

Alan,

Than works perfectly!

Thanks very much.

Thats interesting Alan, I was not aware that you could get a Datetime field populated directly from the FREEFORM.

My code was similar to Francis'.