Is it possible in a procedure to get the directory path of the procedure file and display it in a report? If so can someone provide an example?

Thanks

You can use the WHENCE command to get the full path but it does not populate a DM variable with the result. It only displays it so you cannot grab it to put it in something else such as a HEADING.

Hmm, well that is no good.

We are trying to create a process of documenting our reports and one of the things we want to do is display the location of the procedure say in the "FOOTER". However we are wanting to just add a procedure that will tell us this instead of editing all of our procedures with the location, which over time could change and possibly not get edited to the new location.

So you haven't even tried using something like WHENCE &FOCFEXNAME FOCEXEC then?

Don't try it from Dev Studio as the value for &FOCFEXNAME is always ADHOC from DS.

T

Tony is right, we put in every fex the &FOCFEXNAME and if you run it from the editor that will give "ADHOC" But when you run it via the Dashboard or from the browser it does give the internal fexname.

Please excuse my ignorance, but the only training I have are the manuals and other FOCAL point users. I'm not complaining, I retain more with hands on training.

Is there documentation somewhere on this?

Glenda

Glenda,

A the top right of this page is a link for searching the Technical Documentation Library.
Click it and then choose WebFOCUS Reporting and your release on the left hand side. On the search item enter "whence". Only one document is shown but it is very informational.

T

quote:

FOCFEXNAME

Tony A and FrankDutch,

I have never used this magical parm, it does not exist when I've run my fexes. What I do have in my self-service fexes is &FOCFOCEXEC which has an underscore in the first character and which probably won't work with WHENCE. And I'd love to have someone explain to me how to use the WHENCE command to get the result into a Dialogue Manager variable, which is what the original question was about.

If this is for MRE, the domain and folder are in DM variables.

This message has been edited. Last edited by: Francis Mariani,

There has to be a way to do what you want. Perhaps something can be added to WF Admin Console > Configuration > Custom Settings, but I don't know...

Here is a completely ridiculous way, and this will only work for programs that are in a folder in App Root, not for programs that are in a folder that has been added via APP MAP, APP PREPENDPATH or APP APPENDPATH. The program loops through each App, one by one, looking for the program - when it finds it, it gets out of the loop:

-SET &ECHO=ALL;

-DEFAULT &PROGRAM1 = 'NCRR004';

-SET &PROGRAM1 = LOCASE(&PROGRAM1.LENGTH, &PROGRAM1, 'A&PROGRAM1.LENGTH');

-SET &DIRSEP = IF &FOCMODE EQ 'UNIX' THEN '/' ELSE '\';

APP LIST HOLD
-RUN

?FF FOCAPPL
-RUN

-READ FOCAPPL NOCLOSE &ADATE.A10. &ATIME.A8. &APPNAME.A45.

-REPEAT END_LOOP1 WHILE &IORETURN EQ 0;

APP QUERY '&APPNAME' HOLD
-RUN

?FF FOCAPPQ
-RUN

DEFINE FILE FOCAPPQ
FILENAME1/A70 = LOCASE(70, FILENAME, 'A70');
END
-RUN

TABLE FILE FOCAPPQ
PRINT *
WHERE FILENAME1 EQ '&PROGRAM1...fex';
ON TABLE HOLD
END
-RUN

-IF &LINES GT 0 GOTO EXIT_LOOP1;

-READ FOCAPPL NOCLOSE &ADATE.A10. &ATIME.A8. &APPNAME.A45.

-END_LOOP1
-EXIT_LOOP1

-SET &PROGRAM_LOC = &APPROOT || &DIRSEP || &APPNAME || &DIRSEP || &PROGRAM1 || '.fex';

-TYPE PROGRAM LOCATION: &PROGRAM_LOC

Francis,

Ridiculous though this seems, it is also the only way I could think of to do this. I do something similar, for a different reason. It would be nice if there could be a &FOCFEXPATH type variable for self service apps.

Take a look at Master File Descriptions

The answer is in there!

Here's how to use what we've learnt:

-SET &ECHO=ALL;

-DEFAULT &PROGRAM1 = 'NCRR004';

-SET &PROGRAM1 = LOCASE(&PROGRAM1.LENGTH, &PROGRAM1, 'A&PROGRAM1.LENGTH');

SQL FMI SET SYSFILES FOCEXEC
-RUN

DEFINE FILE SYSFILES
FILENAME1/A64 = LOCASE(64, FILENAME, 'A64');
END
-RUN

TABLE FILE SYSFILES
PRINT
PHNAME
WHERE FILENAME1 EQ '&PROGRAM1';
ON TABLE HOLD AS H001 FORMAT ALPHA
END
-RUN

-READ H001 &PHNAME.A80.

-TYPE PROGRAM LOCATION: &PHNAME

Damn good news!

Of course Francis, thank you. RTFM, works all the time!

Alan

how about this amper value?

"&focfexurl"

"&fochtmlurl"

I never used them, but it might be something you can use..

Not really Frank,

Maybe I am just awkward, but I have 3 main application directories:
all_trak
sky_trak
del_trak

sky_trak and del_trak contain similar programs, called in the same way, but with subtle differences. For example, each contains a POD program, with the same layout, different CSS files and accessing different data sources. With over 1500 programs, an error can happen!

all_trak is always in the path, when a user logs on I prepend either sky_trak or del_trak into the path. I know from WF_USER which they have, but I don't know, without looking, if the program they run is from all_trak or sky_trak/del_trak.

The url does not hold this info, as the path is searched.