Focal Point Banner


As of December 1, 2020, Focal Point is retired and repurposed as a reference repository. We value the wealth of knowledge that's been shared here over the years. You'll continue to have access to this treasure trove of knowledge, for search purposes only.

Join the TIBCO Community
TIBCO Community is a collaborative space for users to share knowledge and support one another in making the best use of TIBCO products and services. There are several TIBCO WebFOCUS resources in the community.

  • From the Home page, select Predict: WebFOCUS to view articles, questions, and trending articles.
  • Select Products from the top navigation bar, scroll, and then select the TIBCO WebFOCUS product page to view product overview, articles, and discussions.
  • Request access to the private WebFOCUS User Group (login required) to network with fellow members.

Former myibi community members should have received an email on 8/3/22 to activate their user accounts to join the community. Check your Spam folder for the email. Please get in touch with us at community@tibco.com for further assistance. Reference the community FAQ to learn more about the community.


Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Underlining a Report Column Across the Entire Row

Read-Only Read-Only Topic
Go
Search
Notify
Tools
[SOLVED] Underlining a Report Column Across the Entire Row
 Login/Join
 
AMC2
Platinum Member
posted
I have an HTML report where I'm trying to underline a report column and data across the entire row of data. The report has two across fields but I want to underline an entire row for an amount field that I'm summing up for the across fields This styling code below only underlines the column title and the first data value for that field. I want the entire row underlined.

TYPE=REPORT, COLUMN=VBR_PD_ELG_AMT, STYLE=UNDERLINE, $

This message has been edited. Last edited by: FP Mod Chuck,


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
AMC2
Platinum Member
posted Hide Post
I am trying to do this in the code. If anyone has any suggestions, please let me know.


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
MartinY
Virtuoso
posted Hide Post
TYPE=DATA, COLUMN=VBR_PD_ELG_AMT(*), STYLE=UNDERLINE, $


Underline will be only under displayed value it will not create a kind of "break line"


WF versions : Prod 8.2.04M gen 33, Dev 8.2.04M gen 33, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2409 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Report This Post
AMC2
Platinum Member
posted Hide Post
MartinY - Thanks for your post. That only underlines the first data value for that field. I am summing this field ACROSS two other fields. I do need it to be like a "break line" to go under that field that is being displayed across the other two fields.


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
David Briars
Master
posted Hide Post
quote:
...I want the entire row underlined.

It sounds like you would want to add the following two items to your TABLE FILE command:
1. Flag to tell your StyleSheet when to underline.
2. StyleSheet command to set a border conditionally.

For example: 
SET ACROSSLINE = OFF
SET ACROSSTITLE = SIDE
SET PAGE = OFF
TABLE FILE CAR
-*
 SUM     RCOST                                                    NOPRINT
 COMPUTE TOTALRCOSTFLAG/A1 = IF RCOST GT 50000 THEN 'Y' ELSE 'N'; NOPRINT
 BY      COUNTRY
-*
 SUM     RCOST AND ROW-TOTAL
 BY      COUNTRY 
 ACROSS  CAR AS 'Car:'
-*
 ON TABLE SET STYLE *
  TYPE=REPORT, FONT=ARIAL,$
  TYPE=TITLE, STYLE=UNDERLINE,$
  TYPE=DATA, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=RED, TOPGAP=0, BOTTOMGAP=0, WHEN = TOTALRCOSTFLAG EQ 'Y', $
 ENDSTYLE
END





Pilot: WebFOCUS 8.2.06 Test: WebFOCUS 8.1.05M Prod: WebFOCUS 8.1.05M Server: Windows Server 2016/Tomcat Standalone Workstation: Windows 10/IE11+Edge Database: Oracle 12c, Netezza, & MS SQL Server 2019 Output: AHTML/XLSX/HTML/PDF/JSCHART Tools: WFDS, Repository Content, BI Portal Designer & ReportCaster
 
Posts: 822 | Registered: April 23, 2003Report This Post
AMC2
Platinum Member
posted Hide Post
David - Thanks for your post. I don't need to conditionally underline it. I want to underline it in every case. This is what I used from your styling code:



TYPE=DATA, COLUMN=VBR_PD_ELG_AMT, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=RED, TOPGAP=0, BOTTOMGAP=0, $


But this only underlines the first value for the field VBR_PD_ELG_AMT.

Also secondarily, how did you paste your whole output to the post?


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
David Briars
Master
posted Hide Post
In looking at the StyleSheet command you show, it looks like you would want to try removing the COLUMN attribute.

FocalPoint supports 'image URL's' in a post - third button from the right when composing.

I use Cloudinary to host my images.
 
Posts: 822 | Registered: April 23, 2003Report This Post
AMC2
Platinum Member
posted Hide Post
David - Without the COLUMN attribute, it underlines every field's value for the ACROSS.

With the COLUMN attribute it underlines just the first value of the VBR_PD_ELG_AMT column for the ACROSS.

I need the whole row for VBR_PD_ELG_AMT in the ACROSS
underlined all the time.


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
FP Mod Chuck
Virtuoso
posted Hide Post
AMC2

I am confused by this David's post clearly shows an underline of all the values and it works for me in my 8.2.06 environment. Please post all your code so we can see what is different in yours vs David's.


Thank you for using Focal Point!

Chuck Wolff - Focal Point Moderator
WebFOCUS 7x and 8x, Windows, Linux All output Formats
 
Posts: 2127 | Location: Customer Support | Registered: April 12, 2005Report This Post
MartinY
Virtuoso
posted Hide Post
Pay attention on the (*) beside the column's name :
TYPE=DATA,
 COLUMN=VBR_PD_ELG_AMT(*),
 BORDER-BOTTOM=LIGHT,
 BORDER-BOTTOM-COLOR=RED,
 TOPGAP=0,
 BOTTOMGAP=0,
$

Sample
SET ACROSSLINE = OFF
SET ACROSSTITLE = SIDE
SET PAGE = OFF
TABLE FILE CAR
SUM RETAIL_COST
    DEALER_COST
BY COUNTRY 
ACROSS  CAR AS 'Car:'
ON TABLE SET STYLE *
TYPE=REPORT, FONT=ARIAL,$
TYPE=TITLE, STYLE=UNDERLINE,$
TYPE=DATA, COLUMN=RETAIL_COST(*), BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=RED, TOPGAP=0, BOTTOMGAP=0, $
ENDSTYLE
END


WF versions : Prod 8.2.04M gen 33, Dev 8.2.04M gen 33, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2409 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Report This Post
David Briars
Master
posted Hide Post
If I understand your scenario correctly, you have two verb objects, within your BY/ACROSS matrix, and only one of the verb object values needs to be 'underlined'. 
SET ACROSSLINE = OFF
SET ACROSSTITLE = SIDE
SET PAGE = OFF
SET NODATA = 'N/A'
TABLE FILE CAR
-*
 SUM     RCOST   AS 'Retail Cost'
         DCOST   AS 'Dealer Cost'                                                   
 BY      COUNTRY AS 'Country'
 ACROSS  CAR AS 'Car:'
-*
 WHERE COUNTRY EQ 'FRANCE' OR 'ITALY' OR 'ENGLAND'
-*
 ON TABLE SET STYLE *
  TYPE=REPORT, FONT=ARIAL, SIZE=10,$
  TYPE=TITLE,  COLUMN=COUNTRY, STYLE=UNDERLINE,$
  TYPE=ACROSSVALUE, JUSTIFY = CENTER, $
  TYPE=DATA,   COLUMN=RCOST(*), BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=GREEN, TOPGAP=0, BOTTOMGAP=0,  $
 ENDSTYLE
END

 
Posts: 822 | Registered: April 23, 2003Report This Post
AMC2
Platinum Member
posted Hide Post
Thanks MartinY...the column name with the (*) beside below does underline all of the values in the row for the field. However, it does not extend the underline to the column title.

TYPE=DATA, COLUMN=VBR_PD_ELG_AMT(*), BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $

David - I have two verb objects with two ACROSS fields and no BY field.


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
David Briars
Master
posted Hide Post
quote:
...However, it does not extend the underline to the column title...

Then, to underline the column titles of one of the verb objects, you would do something similar... 1. Identify the section you want to style, 2. Style.

For example:
SET ACROSSLINE = OFF
SET ACROSSTITLE = SIDE
SET PAGE = OFF
SET NODATA = 'N/A'
TABLE FILE CAR
-*
 SUM    RCOST   AS 'Retail Cost'
        DCOST   AS 'Dealer Cost'
 BY     COUNTRY AS 'Country'
 ACROSS CAR     AS 'Car:'
-*
 WHERE  COUNTRY EQ 'ENGLAND' OR 'FRANCE' OR 'ITALY'
-*
 ON TABLE SET STYLE *
  DEFMACRO = CELLUNDERLINE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=RED, TOPGAP=0, BOTTOMGAP=0, $
  TYPE=REPORT, FONT=CALIBRI, SIZE=10,$
-* Styling for across cars.
  TYPE=ACROSSTITLE, JUSTIFY = RIGHT,  COLOR=GREY, $
  TYPE=ACROSSVALUE, JUSTIFY = CENTER, COLOR=GREY, STYLE=UNDERLINE, $
-* Styling for column titles.  
  TYPE=TITLE, COLUMN=COUNTRY,  COLOR=GREY,$
  TYPE=TITLE, COLUMN=RCOST(*), MACRO=CELLUNDERLINE, $
-* Styling for data section.
  TYPE=DATA,  COLUMN=COUNTRY,  COLOR=GREY,$  
  TYPE=DATA,  COLUMN=RCOST(*), MACRO=CELLUNDERLINE, $
 ENDSTYLE
END

This message has been edited. Last edited by: David Briars,
 
Posts: 822 | Registered: April 23, 2003Report This Post
AMC2
Platinum Member
posted Hide Post
Thanks Martiny and David for your replies. Had to address a couple of other items since our last posts. I can't get the title line under my 2nd ACROSS row either by SET TITLELINE ON or by trying to style it individually in styling section below....now that I added:

TYPE=DATA, COLUMN=VBR_PD_ELG_AMT(*), BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $
TYPE=TITLE, COLUMN=VBR_PD_ELG_AMT(*), BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $

Any other ideas? Here is the bulk of the code:

  
SET ACROSSLINE = OFF
SET ACROSSTITLE = SIDE

DEFINE FILE PMR_PROV_VAL_BASE_CLUSTER
PRCG_SCHD/A5 = IF VBR_PRCG_SCHD_NM EQ 'Select Provider Plus 5%'  THEN '5%'  ELSE
               IF VBR_PRCG_SCHD_NM EQ 'Select Provider Plus 10%' THEN '10%' ELSE
			   IF VBR_PRCG_SCHD_NM EQ 'Select Provider Plus 15%' THEN '15%' ELSE
			   IF VBR_PRCG_SCHD_NM EQ 'Select Provider Plus 20%' THEN '20%' ELSE
			   IF VBR_PRCG_SCHD_NM EQ 'Select Provider Plus 25%' THEN '25%' ELSE
			   IF VBR_PRCG_SCHD_NM EQ 'Select Provider Plus 30%' THEN '30%' ELSE '';

CLDR_DT/MDYY = DATECVT(ICURD_CLDR, 'I8YYMD', 'MDYY');
END

TABLE FILE PMR_PROV_VAL_BASE_CLUSTER
SUM VBR_GAIN_AMT/D12!d   AS 'Estimated' OVER
    VBR_PD_ELG_AMT/D12!d AS 'Potential' OVER
	COMPUTE MISOPP/D12!d = VBR_PD_ELG_AMT - VBR_GAIN_AMT; AS 'Missed Opportunity'
-*ACROSS ICURD_CLDR AS ''
ACROSS CLDR_DT AS ''
ACROSS PRCG_SCHD AS ''
WHERE VBR_PRCG_PCT_VAL NE 0;
WHERE SPEC_CD EQ 'AC' OR 'PD' OR 'OB';
WHERE PRIM_LCTN_SW EQ 'Y'
WHERE VBR_PRCG_SCHD_NM NE MISSING;
WHERE ICURD_CLDR NE MISSING;
WHERE PMR_PROV_VAL_BASE_CLUSTER.PROV_DMN.PROV_NPI EQ &NPI;
-*WHERE RECORDLIMIT EQ 10000;
-*-INCLUDE /WFC/Repository/PMR/common/fex/PMR_com_filter_include.fex
ON TABLE PCHOLD FORMAT HTML CLOSE
ON TABLE SET PAGE-NUM NOPAGE
ON TABLE SET AUTOFIT ON
ON TABLE SET TITLELINE ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
TYPE=REPORT,
	CSSURL=IBFS:/WFC/Repository/PMR/common/css/PMR_com_css_main_css.css,
$
TYPE=REPORT,
	 GRID=OFF ,
     FONT='OpenSans',
     SIZE=11,
	 STYLE=NORMAL,
	 SQUEEZE=ON,
	 JUSTIFY=CENTER,
$

TYPE=ACROSSVALUE, STYLE=BOLD, $

-*TYPE=ACROSSVALUE, STYLE=BOLD, BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0,$
-*TYPE=ACROSSTITLE, STYLE=BOLD, BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0,$

TYPE=DATA, COLUMN=VBR_PD_ELG_AMT(*), BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $
TYPE=TITLE, COLUMN=VBR_PD_ELG_AMT(*), BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $


ENDSTYLE
END
-RUN


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
MartinY
Virtuoso
posted Hide Post
Not clear what you want.
Please try to reproduce with a legacy file or draw a sample output

I may miss something, but I don't think that you can style individually the ACROSS in a report (Maybe with a datagrid graph)

-* REPORT
SET ACROSSLINE = OFF
SET ACROSSTITLE = SIDE
SET PAGE = OFF
TABLE FILE CAR
SUM RETAIL_COST
    DEALER_COST
BY COUNTRY 
ACROSS CAR   AS 'Car:'
ACROSS MODEL AS 'Model:'
ON TABLE SET STYLE *
TYPE=REPORT, FONT=ARIAL,$
TYPE=TITLE, STYLE=UNDERLINE,$
TYPE=DATA, COLUMN=RETAIL_COST(*), BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=RED, TOPGAP=0, BOTTOMGAP=0, $
TYPE=ACROSSVALUE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=RED, TOPGAP=0, BOTTOMGAP=0, $
ENDSTYLE
END


WF versions : Prod 8.2.04M gen 33, Dev 8.2.04M gen 33, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2409 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Report This Post
AMC2
Platinum Member
posted Hide Post
Ok another note...if I remove or comment out the these two styling lines I added below, then my SET TITLELINE ON will generate the line under the 2nd ACROSS line. However, then I don't have it generated under the VBR_PD_ELG_AMT line as a result. I need it under both.

TYPE=DATA, COLUMN=VBR_PD_ELG_AMT(*), BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $
TYPE=TITLE, COLUMN=VBR_PD_ELG_AMT(*), BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
David Briars
Master
posted Hide Post
quote:
...title line under my 2nd ACROSS row...

Yes, you can style each of your two ACROSS objects independently...
SET PAGE = OFF
TABLE FILE CAR
-*
 SUM    RCOST   AS 'Retail Cost'
        DCOST   AS 'Dealer Cost'
 ACROSS COUNTRY AS ''
 ACROSS CAR     AS ''
-*
 WHERE  COUNTRY EQ 'ENGLAND' OR 'FRANCE' OR 'ITALY'
-*
 ON TABLE SET STYLE *
  DEFMACRO = CELLUNDERLINE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=RED, TOPGAP=0, BOTTOMGAP=0, $
  TYPE=REPORT, FONT=CALIBRI, SIZE=10,$
-* Styling for across country's.
  TYPE=ACROSSVALUE, ACROSS=COUNTRY, JUSTIFY = CENTER, COLOR=BLUE, STYLE=UNDERLINE, SIZE=12, $
-* Styling for across cars.
  TYPE=ACROSSVALUE, ACROSS=CAR, JUSTIFY = CENTER, COLOR=PURPLE, STYLE=UNDERLINE, SIZE=11, $
-* Styling for column titles.
  TYPE=TITLE, COLUMN=RCOST(*), MACRO=CELLUNDERLINE, $
-* Styling for data section.
  TYPE=DATA,  COLUMN=RCOST(*), MACRO=CELLUNDERLINE, $
 ENDSTYLE
END

This message has been edited. Last edited by: David Briars,




Pilot: WebFOCUS 8.2.06 Test: WebFOCUS 8.1.05M Prod: WebFOCUS 8.1.05M Server: Windows Server 2016/Tomcat Standalone Workstation: Windows 10/IE11+Edge Database: Oracle 12c, Netezza, & MS SQL Server 2019 Output: AHTML/XLSX/HTML/PDF/JSCHART Tools: WFDS, Repository Content, BI Portal Designer & ReportCaster
 
Posts: 822 | Registered: April 23, 2003Report This Post
AMC2
Platinum Member
posted Hide Post
David - So that will work for me when I use:

TYPE=ACROSSVALUE, ACROSS=PRCG_SCHD, STYLE=UNDERLINE, $

However, I need the line all the way across that row of data. When I try to use it with BORDER-BOTTOM it generates nothing:

TYPE=ACROSSVALUE, ACROSS=PRCG_SCHD, BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0,$


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
David Briars
Master
posted Hide Post
quote:
...I need the line all the way across that row of data. When I try to use it with BORDER-BOTTOM it generates nothing:...

It looks like borders are supported for the ACROSS objects:
SET PAGE = OFF
TABLE FILE CAR
-*
 SUM    RCOST   AS 'Retail Cost'
        DCOST   AS 'Dealer Cost'
 ACROSS COUNTRY AS ''
 ACROSS CAR     AS ''
-*
 WHERE  COUNTRY EQ 'ENGLAND' OR 'FRANCE' OR 'ITALY'
-*
 ON TABLE PCHOLD FORMAT HTML
 ON TABLE SET STYLE *
  DEFMACRO = ACROSSCOUNTRYUNDERLINE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=BLUE, TOPGAP=.02, BOTTOMGAP=.02, $
  DEFMACRO = ACROSSCARUNDERLINE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=PURPLE, TOPGAP=.02, BOTTOMGAP=.02, $
  DEFMACRO = CELLUNDERLINE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=RED, TOPGAP=0, BOTTOMGAP=0, $
-* 
  TYPE=REPORT, FONT=CALIBRI, SIZE=10,$
-* Styling for across country's.
  TYPE=ACROSSVALUE, ACROSS=COUNTRY, JUSTIFY = CENTER, COLOR=BLUE, MACRO=ACROSSCOUNTRYUNDERLINE, SIZE=12, $
-* Styling for across cars.
  TYPE=ACROSSVALUE, ACROSS=CAR, JUSTIFY = CENTER, COLOR=PURPLE, MACRO=ACROSSCARUNDERLINE, SIZE=11, $
-* Styling for column titles.
  TYPE=TITLE, COLUMN=RCOST(*), MACRO=CELLUNDERLINE, $
-* Styling for data section.
  TYPE=DATA,  COLUMN=RCOST(*), MACRO=CELLUNDERLINE, $
 ENDSTYLE
END

 
Posts: 822 | Registered: April 23, 2003Report This Post
AMC2
Platinum Member
posted Hide Post
David, this below as you indicate did not work for me. It did not generate the line under my ACROSS line as it does for your example. Am I missing something?

DEFMACRO = ACROSSPRCG_SCHDUNDERLINE, BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $
TYPE=ACROSSVALUE, ACROSS=PRCG_SCHD, JUSTIFY=CENTER, MACRO=ACROSSPRCG_SCHDUNDERLINE, SIZE=11, $


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
AMC2
Platinum Member
posted Hide Post
David - Am I missing something there that you can tell? I replied to your last post.


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
AMC2
Platinum Member
posted Hide Post
David - If I take your CARS example and SUM the Retail Cost OVER Dealer Cost like what I'm trying to do with my data, I can't get it to generate the line under the CAR across field row and under one of the detail lines (Dealer Cost) being summed. It looks like there is this issue maybe while using the OVER. Any suggestions anyone on how to get both lines to generate while using the OVER command?

quote:

SET PAGE = OFF
TABLE FILE CAR
-*
SUM RCOST AS 'Retail Cost' OVER
DCOST AS 'Dealer Cost'
ACROSS COUNTRY AS ''
ACROSS CAR AS ''
-*
WHERE COUNTRY EQ 'ENGLAND' OR 'FRANCE' OR 'ITALY'
-*
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
DEFMACRO = ACROSSCOUNTRYUNDERLINE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=BLUE, TOPGAP=.02, BOTTOMGAP=.02, $
DEFMACRO = ACROSSCARUNDERLINE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=PURPLE, TOPGAP=.02, BOTTOMGAP=.02, $
DEFMACRO = CELLUNDERLINE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=RED, TOPGAP=0, BOTTOMGAP=0, $
-*
TYPE=REPORT, FONT=CALIBRI, SIZE=10,$
-* Styling for across country's.
-* TYPE=ACROSSVALUE, ACROSS=COUNTRY, JUSTIFY = CENTER, COLOR=BLUE, MACRO=ACROSSCOUNTRYUNDERLINE, SIZE=12, $
-* Styling for across cars.
TYPE=ACROSSVALUE, ACROSS=CAR, JUSTIFY = CENTER, COLOR=PURPLE, MACRO=ACROSSCARUNDERLINE, SIZE=11, $
-* Styling for column titles.
-* TYPE=TITLE, COLUMN=RCOST(*), MACRO=CELLUNDERLINE, $
-* Styling for data section.
-* TYPE=DATA, COLUMN=RCOST(*), MACRO=CELLUNDERLINE, $

TYPE=DATA, COLUMN=DCOST(*), BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $
TYPE=TITLE, COLUMN=DCOST(*), BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $
ENDSTYLE
END
END


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
MartinY
Virtuoso
posted Hide Post
Using OVER is just a "display" option for the measures (SUM/PRINT) fields.
But in fact, they remains on "the same row" for FOCUS. Reason why underlining the column applies on the "second" displayed row only.

With the below you have "underline" everywhere
SET PAGE = OFF
TABLE FILE CAR
SUM RCOST AS 'Retail Cost' OVER
    DCOST AS 'Dealer Cost'
ACROSS COUNTRY AS ''
ACROSS CAR AS ''
WHERE COUNTRY EQ 'ENGLAND' OR 'FRANCE' OR 'ITALY'
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
TYPE=REPORT, FONT=CALIBRI, SIZE=10, BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $
TYPE=ACROSSVALUE, ACROSS=CAR, JUSTIFY = CENTER, COLOR=PURPLE, SIZE=11, $
ENDSTYLE
END

And using below, you will finally probably get what you are looking for
SET PAGE = OFF
DEFINE FILE CAR
DUMMY /A1 = '';
END
TABLE FILE CAR
SUM RCOST AS 'Retail Cost' OVER
    DCOST AS 'Dealer Cost'
ACROSS COUNTRY AS ''
ACROSS CAR AS ''
ACROSS DUMMY AS ''
WHERE COUNTRY EQ 'ENGLAND' OR 'FRANCE' OR 'ITALY';
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
TYPE=REPORT, FONT=CALIBRI, SIZE=10, $
TYPE=DATA, BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $
TYPE=TITLE, BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $
TYPE=ACROSSVALUE, ACROSS=CAR,   JUSTIFY=CENTER, COLOR=PURPLE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=PURPLE, TOPGAP=.02, BOTTOMGAP=.02, SIZE=11, $
TYPE=ACROSSTITLE, ACROSS=DUMMY, JUSTIFY=CENTER, COLOR=PURPLE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=PURPLE, TOPGAP=.02, BOTTOMGAP=.02, SIZE=11, $
ENDSTYLE
END


WF versions : Prod 8.2.04M gen 33, Dev 8.2.04M gen 33, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2409 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Report This Post
AMC2
Platinum Member
posted Hide Post
MartinY - Good point about the OVER command. What you indicated here with the DUMMY field gets almost what I need. The line under the DUMMY field just does not extend all the way to the leftmost margin where the other lines begin.


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
MartinY
Virtuoso
posted Hide Post
You cannot expand the purple underline over RetailCost because "CAR / DUMMY" across fields do not go "over" that field.
By using OVER command, you trick the report display.

If you had tried adding some other borders ("underline") around these fields you will have realized that.
And also that each field has its own borders area and that displaying TOP border on RetailCost will not be aligned (on same row) than the purple bottom border of "CAR / DUMMY" such as below sample

SET PAGE = OFF
DEFINE FILE CAR
DUMMY /A1 = '';
END
TABLE FILE CAR
SUM RCOST AS 'Retail Cost' OVER
    DCOST AS 'Dealer Cost'
ACROSS COUNTRY AS ''
ACROSS CAR AS ''
ACROSS DUMMY AS ''
WHERE COUNTRY EQ 'ENGLAND' OR 'FRANCE' OR 'ITALY';
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
TYPE=REPORT, FONT=CALIBRI, SIZE=10, $
TYPE=DATA, BORDER-BOTTOM=LIGHT, TOPGAP=0, BOTTOMGAP=0, $
TYPE=TITLE, BORDER-BOTTOM=LIGHT, $
TYPE=ACROSSVALUE, ACROSS=CAR,   JUSTIFY=CENTER, COLOR=PURPLE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=PURPLE, SIZE=11, $
TYPE=ACROSSTITLE, ACROSS=DUMMY, JUSTIFY=CENTER, COLOR=PURPLE, BORDER-BOTTOM=LIGHT, BORDER-BOTTOM-COLOR=PURPLE, SIZE=11, $
TYPE=TITLE, COLUMN=RETAIL_COST, BORDER-TOP=LIGHT, BORDER-TOP-COLOR=PURPLE, $
ENDSTYLE
END

To have it on the same row, you need to use the REPORT borders, as per below. But they will end up all with the same color and you will also have a top border above the COUNTRY which you probably don't want.
You will notice that different color where it is a TOP or a BOTTOM border that take precedence.
SET PAGE = OFF
TABLE FILE CAR
SUM RCOST AS 'Retail Cost' OVER
    DCOST AS 'Dealer Cost'
ACROSS COUNTRY AS ''
ACROSS CAR AS ''
WHERE COUNTRY EQ 'ENGLAND' OR 'FRANCE' OR 'ITALY'
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
TYPE=REPORT, FONT=CALIBRI, SIZE=10, BORDER-BOTTOM=LIGHT, BORDER-TOP=LIGHT, BORDER-BOTTOM-COLOR=RED, TOPGAP=0, BOTTOMGAP=0, $
TYPE=ACROSSVALUE, ACROSS=CAR, JUSTIFY=CENTER, COLOR=PURPLE, SIZE=11, $
ENDSTYLE
END


WF versions : Prod 8.2.04M gen 33, Dev 8.2.04M gen 33, OS : Windows, DB : MSSQL, Outputs : HTML, Excel, PDF
In Focus since 2007
 
Posts: 2409 | Location: Montreal Area, Qc, CA | Registered: September 25, 2013Report This Post
AMC2
Platinum Member
posted Hide Post
Right, I don't want the top border above the COUNTRY field. It also puts a border under and above every line. I only need it under the Dealer Cost and under the CAR across lines for this CAR example.

I also can't use SET TITLELINE ON with the TYPE=DATA, COLUMN=DCOST, BORDER-BOTTOM=LIGHT, $ to get both of those lines. If I use both, it only generates the border line for the Dealer Cost.


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
Joanna Swiggett
Member
posted Hide Post
Will this work?

 
SET PAGE = OFF
TABLE FILE CAR
SUM RCOST AS 'Retail Cost' OVER
    DCOST AS 'Dealer Cost'
ACROSS COUNTRY AS ''
ACROSS CAR AS ''
WHERE COUNTRY EQ 'ENGLAND' OR 'FRANCE' OR 'ITALY';
ON TABLE SET HTMLCSS ON
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
TYPE=REPORT, FONT='CALIBRI', SIZE=10, $
-* style DCOST using bottom border
TYPE=DATA, COLUMN=DCOST, BORDER-BOTTOM=MEDIUM, $
TYPE=DATA, ACROSSCOLUMN=DCOST, BORDER-BOTTOM=MEDIUM, $
TYPE=TITLE, COLUMN=DCOST, BORDER-BOTTOM=MEDIUM, $
-* style RCOST using top border
TYPE=DATA, COLUMN=RCOST, BORDER-TOP=MEDIUM, $
TYPE=DATA, ACROSSCOLUMN=RCOST, BORDER-TOP=MEDIUM, $
TYPE=TITLE, COLUMN=RCOST, BORDER-TOP=MEDIUM, $
ENDSTYLE
END


WebFOCUS 8.2.01M
 
Posts: 12 | Location: Charlotte, NC | Registered: December 19, 2012Report This Post
AMC2
Platinum Member
posted Hide Post
Joanna - Beautiful...that worked! I didn't realize that about ACROSSCOLUMN. So using "ACROSSCOLUMN=" with "TYPE=DATA" and "TYPE=TITLE"...and coupled with the BORDER-BOTTOM and BORDER-TOP I get what I need.

Thank you!


WebFOCUS 8.2.06
SQL Server
HTML, PDF, Excel, etc
 
Posts: 168 | Registered: August 22, 2019Report This Post
  Powered by Social Strata  

Read-Only Read-Only Topic

Focal Point    Focal Point Forums  Hop To Forum Categories  WebFOCUS/FOCUS Forum on Focal Point     [SOLVED] Underlining a Report Column Across the Entire Row

Copyright © 1996-2020 Information Builders