Does anyone have an example of how the WebFOCUS provided sparkline chart can be embedded in a table or text?

The documentation says it can but doesn't provide an example.

Thanks in advance.

This message has been edited. Last edited by: FP Mod Chuck,

Hi Ben, and welcome to FP.

Example code using GGSALES sample data

EMBED BEGIN PCHOLD FORMAT HTML
EMBED COMPONENT AS SPARK
DEFINE FILE GGSALES
  YEAR/YY = DATE;
END
GRAPH FILE GGSALES
SUM DOLLARS AS ''
BY CATEGORY AS ''
BY PRODUCT AS ''
ACROSS DATE AS ''
WHERE YEAR EQ 1997
ON GRAPH PCHOLD AS SPARK FORMAT JSCHART
ON GRAPH SET LOOKGRAPH BAR
ON GRAPH SET HAXIS 200
ON GRAPH SET VAXIS 50
ON GRAPH SET GRMERGE ADVANCED
ON GRAPH SET GRMULTIGRAPH 2
ON GRAPH SET GRLEGEND 0
ON GRAPH SET GRXAXIS 1
ON GRAPH SET STYLE *
*GRAPH_JS
chartType: 'sparkline',
title: {visible: false},
xaxis: {
    majorGrid: {
                   visible: false
    }
},
yaxis: {
    majorGrid: {
                   visible: false
    }
},
border: {width: 0},
blaProperties:{ lineConnection: 'curved'},
END

EMBED MAIN
TABLE FILE GGSALES
SUM DOLLARS
COMPUTE SparkLine/A1=' ';
BY CATEGORY
BY PRODUCT
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET STYLE *
type=report, border=light, $
type=data, column=SparkLine, embed=spark, size=3, $
END
EMBED END
-RUN

T

Awesome! Works like a charm. Is this documented anywhere?

Hi Tony,
Very nice. One learns something every day!
As Ben asks: where is the documentation.

quote:

EMBED MAIN

Excellent Tony... Excellent (As expected)