This is my code:

TABLE FILE EXPENSES
SUM
TOTALAMOUNT/D15.2M/C AS 'Total'
MAX.BUDGET/C AS 'Budget'
MAX.VARIANCE/C AS 'Variance'
BY REGION AS 'Region'
ACROSS EXPDATE_MMYY AS ' ' ROW-TOTAL
WHERE EXPENSEDATE GE '20071101';
WHERE REGION NE ' ';
ON TABLE COLUMN-TOTAL
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS = IN, PAGESIZE = LEGAL, ORIENTATION = LANDSCAPE, GRID = OFF, SQUEEZE = ON,
LEFTMARGIN = 0.5, TOPMARGIN = 0.25, RIGHTMARGIN = 0.025, BOTTOMMARGIN = 0.025, LEFTGAP = 0.055, RIGHTGAP = 0.055, $
TYPE = REPORT, FONT = 'Arial', SIZE = 9, $
TYPE = HEADING, SIZE = 9, STYLE = BOLD, $
TYPE = TITLE, SIZE = 9, STYLE = BOLD, $
TYPE = SUBFOOT, SIZE = 9, STYLE = BOLD, $
TYPE = FOOTING, SIZE = 7, $
TYPE = DATA, SIZE = 8, JUSTIFY = LEFT, COLUMN = REGION, BACKCOLOR = ( RGB(243 244 248) RGB(255 255 255) ), $
TYPE = DATA, SIZE = 8, JUSTIFY = RIGHT, BACKCOLOR = ( RGB(243 244 248) RGB(255 255 255) ), $
TYPE = ACROSS, FONT = 'ARIAL', SIZE = 9, STYLE = BOLD, JUSTIFY = CENTER, $
TYPE = GRANDTOTAL, FONT = 'ARIAL', SIZE = 8, STYLE = BOLD, $
ENDSTYLE
END

I want to know how do I bold the data in the row-total columns.

I think this does it...BUT NO TIME TO TEST.
TYPE=DATA,COLUMN=ROWTOTAL(*),STYLE=BOLD,$

Check this link...


https://forums.informationbuilders.com/eve/forums/a/tpc/...901048331#3901048331

Sean

this should work for you.

TYPE=TITLE,
COLUMN=ROWTOTAL(1),
STYLE=BOLD,
$

TYPE=ACROSSVALUE,
COLUMN=ROWTOTAL(1),
STYLE=BOLD,
$

Hmmmmm...neither one of these works.

The code above just bolds the title of the row-total. I need the data in the report bold as well that appears under the across.

sorry forgot this

TYPE=DATA,
COLUMN=ROWTOTAL(1),
STYLE=BOLD,
$

Thank you...that worked.