Hello,

I am working on a compound PDF report with a very specific layout. The current page that I am working on, has static text to begin with (spanning 2 columns and 3 rows) followed by data from master file.

I am using WHERE RECORDLIMIT EQ 1 statement in the TABLE command because I don't want the static text repeating more than once. I have a few DEFINE statements which define the texts to be printed and then I use them in the TABLE command with the above mentioned WHERE clause to satisfy the requirements.

DEFINE FILE DISCLOSURE_BOX_1
BLANK/A25 WITH COC_DTE = ' ';
TEXT85/A200 WITH COC_DTE = 'These are the most common domestically issued card types and processing methods. They do not represent all the possible fees and variations that are charged to merchants';
TEXT86/A50 WITH COC_DTE = 'Processing method';
TEXT87/A50 WITH COC_DTE = 'Payment Card Type';
TEXT88/A50 WITH COC_DTE = 'Card/Device Present';
TEXT89/A100 WITH COC_DTE = 'Means that the card/device was electronically read (contact or contactless interface or mag-stripe).';
TEXT90/A40 WITH COC_DTE = 'Card/Device Not-Present';
TEXT91/A150 WITH COC_DTE = 'Means that the card/device was not electronically read, e.g. mail/telephone order, online, recurring payment, manually key-entered).';
...........
..........
END

TABLE FILE DISCLOSURE_BOX_1
PRINT
TEXT85 IN 2 AS ''
TEXT86 IN 40 AS '' OVER
BLANK AS '' OVER
TEXT87 IN 2 AS ''
TEXT88 IN 40 AS ''
TEXT90 IN 58 AS '' OVER
TEXT89 IN 40 AS ''
TEXT91 IN 60 AS '' OVER
FEE_DSC AS ''
........ 
.........
WHERE RECORDLIMIT EQ 1
WHERE MID EQ '34656576'
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT PDF CLOSE
ON TABLE SET STYLESHEET *
TYPE=HEADING, STYLE=BOLD, FONT=VERBANA, SIZE=12,$
-*TYPE=REPORT, GRID=FILL,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=ITALIC, COLUMN=TEXT85, JUSTIFY=CENTER, WRAP=3.5,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=BOLD, COLUMN=TEXT86, JUSTIFY=CENTER, WRAP=3.5,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=BOLD, COLUMN=TEXT87, JUSTIFY=CENTER, WRAP=2.0,$
........
........
ENDSTYLE
END

After all the texts are printed I am trying to print the column FEE_DSC below the text, but it displays only 1 row because of the WHERE RECORDLIMIT clause.. How do I work around this? I can't get rid of the WHERE clause...

Thanks in advance!

This message has been edited. Last edited by: Nova27,

First Nova27, a good practice is to reproduce your issue with, per example the CAR file.
This way we can use your code to find a solution instead of trying to understand what you did.
Sometime, reproducing the issue makes you find the solution yourself.

Next I will suggest to put all that text in HEADER or SUBHEADER then print your FEE_DSC as usual.
This way no need for the WHERE RECORDLIMIT EQ 1

This message has been edited. Last edited by: MartinY,

I can't use Heading or Subheading since I need it in certain place and order - here's my issue with CAR example:

DEFINE FILE CAR
BLANK/A25 WITH MODEL = '';
TEXT85/A200 WITH MODEL = 'These are the most common domestically issued card types and processing methods. They do not represent all the possible fees and variations that are charged to merchants';
TEXT86/A50 WITH MODEL = 'Processing method';
TEXT87/A50 WITH MODEL = 'Payment Card Type';
TEXT88/A50 WITH MODEL = 'Card/Device Present';
TEXT89/A100 WITH MODEL = 'Means that the card/device was electronically read (contact or contactless interface or mag-stripe).';
TEXT90/A40 WITH MODEL = 'Card/Device Not-Present';
TEXT91/A150 WITH MODEL = 'Means that the card/device was not electronically read, e.g. mail/telephone order, online, recurring payment, manually key-entered).';
END

TABLE FILE CAR
PRINT
TEXT85 IN 2 AS ''
TEXT86 IN 40 AS '' OVER
BLANK AS '' OVER
TEXT87 IN 2 AS ''
TEXT88 IN 40 AS ''
TEXT90 IN 58 AS '' OVER
TEXT89 IN 40 AS ''
TEXT91 IN 60 AS '' OVER
CAR AS ''
COMPUTE TOTALCOST/I10 = DEALER_COST+RETAIL_COST; IN 40 AS ''
COMPUTE LEN_WID/I10 = LENGTH+WIDTH; IN 60 AS ''
WHERE RECORDLIMIT EQ 1
WHERE COUNTRY EQ 'ENGLAND'
HEADING
"My Report heading"
" "
ON TABLE SET PAGE NOPAGE
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLESHEET *
TYPE=HEADING, STYLE=BOLD, FONT=VERBANA, SIZE=12,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=ITALIC, COLUMN=TEXT85, JUSTIFY=CENTER, WRAP=3.5,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=BOLD, COLUMN=TEXT86, JUSTIFY=CENTER, WRAP=3.5,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=BOLD, COLUMN=TEXT87, JUSTIFY=CENTER, WRAP=2.0,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=BOLD, COLUMN=TEXT88, JUSTIFY=CENTER, WRAP=1.5,$
TYPE=REPORT, FONT=VERBANA, SIZE=8, STYLE=ITALIC, COLUMN=TEXT89, WRAP=1.8,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=BOLD, COLUMN=TEXT90, JUSTIFY=CENTER, WRAP=2.0,$
TYPE=REPORT, FONT=VERBANA, SIZE=8, STYLE=ITALIC, COLUMN=TEXT91, WRAP=2.0,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, COLUMN=CAR, BORDER-TOP=OFF, BORDER=LIGHT, WRAP=3.7,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, COLUMN=TOTALCOST, BORDER-TOP=OFF, BORDER=LIGHT, WRAP=1.75,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, COLUMN=LEN_WID, BORDER-TOP=OFF, BORDER=LIGHT, WRAP=1.95,$

TYPE=REPORT, NAME='BOX030', OBJECT=BOX, POSITION=(0.25 0.8),
DIMENSION=(8.10 9.5),
BORDER-COLOR=BLACK, BORDER=MEDIUM,$
TYPE=REPORT, NAME='BOX031', OBJECT=BOX, POSITION=(0.25 0.8),
DIMENSION=(4.2 0.8),
BORDER-COLOR=BLACK, BORDER=MEDIUM,
BACKCOLOR=WHITE,$
TYPE=REPORT, NAME='BOX032', OBJECT=BOX, POSITION=(4.15 0.8),
DIMENSION=(4.2 0.8),
BORDER-COLOR=BLACK, BORDER=MEDIUM,
BACKCOLOR=WHITE,$
TYPE=REPORT, NAME='BOX033', OBJECT=BOX, POSITION=(0.25 1.6),
DIMENSION=(4.5 1.0),
BORDER-COLOR=BLACK, BORDER=MEDIUM,
BACKCOLOR=WHITE,$
TYPE=REPORT, NAME='BOX034', OBJECT=BOX, POSITION=(4.15 1.6),
DIMENSION=(2.15 1.0),
BORDER-COLOR=BLACK, BORDER=MEDIUM,
BACKCOLOR=WHITE,$
TYPE=REPORT, NAME='BOX035', OBJECT=BOX, POSITION=(6.1 1.6),
DIMENSION=(2.25 1.0),
BORDER-COLOR=BLACK, BORDER=MEDIUM,
BACKCOLOR=WHITE,$
ENDSTYLE
END

In this example, only Jaguar appears, although you would expect all the cars in ENGLAND to appear one after the other with their respective calculations...

How do I get all the cars to appear maintaining the specified format?

Thanks!

Sure you can use HEADER.
You need to use the Grid Alignment feature.
This gives you that ability to place things where you want, the width you want with different number of item per line if you which.

It's not polished, but it's a start...

TABLE FILE CAR
-*WHERE RECORDLIMIT EQ 1
PRINT 
     CAR.COMP.CAR AS ''
     COMPUTE TOTALCOST/I10 = DEALER_COST + RETAIL_COST; AS ''
     COMPUTE LEN_WID/I10 = LENGTH + WIDTH; AS ''
ON TABLE SUBHEAD
"These are blah blah blah<+0>Processing Method"
"Payment Type<+0>Card Present<+0>Card Not-Present"
WHERE COUNTRY EQ 'ENGLAND';
ON TABLE SET PAGE-NUM NOLEAD 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
TYPE=TABHEADING,
     HEADALIGN=BODY,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=2,
     COLSPAN=2,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=2,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=3,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
ENDSTYLE
END

Created via GUI; add header and right click within header and choose alignment grid. Be sure to "Align with Data". From that point it's fairly self explanatory.

Hope that helps get started anyway.

Thank you for your responses..

I can't use Grid Alignment in GUI because this is just 1 of the pages from my 7 page PDF report.. I have developed the entire fex using text editor since it has different layouts on each page... which is why I was looking for a way to achieve this through text editor...

Thanks!

Nova, you can do all this with text editor.

Here is the trick :
1- Start a brand new report with GUI.
2- Perform formatting as you which.
3- Save and close report.
4- Open report in text editor.
5- Replicate generated code into YOUR fex.

Even if you don't have the same HEADER/FOOTER from one page to the other, you can use the Grid Alignment. You format each page individualy.

quote:

You format each page individualy.

Started typing before Martin's answer came in...

You should still be able to use it. You can setup each of your 7 pages as it's own table file with distinct layouts and just compound them together in your FEX. Perhaps I'm missing something, but I would think you could get it to work.

Here's another rough one with 2 pages with different header setup...

  
DEFINE FILE CAR
BLANK/A25 WITH MODEL = '';
TEXT85/A200 WITH MODEL = 'These are the most common domestically issued card types and processing methods. They do not represent all the possible fees and variations that are charged to merchants';
TEXT86/A50 WITH MODEL = 'Processing method';
TEXT87/A50 WITH MODEL = 'Payment Card Type';
TEXT88/A50 WITH MODEL = 'Card/Device Present';
TEXT89/A100 WITH MODEL = 'Means that the card/device was electronically read (contact or contactless interface or mag-stripe).';
TEXT90/A40 WITH MODEL = 'Card/Device Not-Present';
TEXT91/A150 WITH MODEL = 'Means that the card/device was not electronically read, e.g. mail/telephone order, online, recurring payment, manually key-entered).';
END

TABLE FILE CAR
-*WHERE RECORDLIMIT EQ 1
PRINT
     CAR.COMP.CAR AS ''
     COMPUTE TOTALCOST/I10 = DEALER_COST + RETAIL_COST; AS ''
     COMPUTE LEN_WID/I10 = LENGTH + WIDTH; AS ''
ON TABLE SUBHEAD
"These are blah blah blah<+0>Processing Method"
"Payment Type<+0>Card Present<+0>Card Not-Present"
WHERE COUNTRY EQ 'ENGLAND';
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF OPEN
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
TYPE=TABHEADING,
     HEADALIGN=BODY,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=2,
     COLSPAN=2,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=2,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=3,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
TYPE=REPORT,
     COLUMN=N3,
     SQUEEZE=1.444444,
$
TYPE=REPORT,
     COLUMN=N1,
     SQUEEZE=2.347222,
$
TYPE=REPORT,
     COLUMN=N2,
     SQUEEZE=1.208333,
$
ENDSTYLE
END
TABLE FILE CAR
-*WHERE RECORDLIMIT EQ 1
PRINT
     CAR.COMP.CAR AS ''
     CAR.CARREC.MODEL AS ''
     COMPUTE TOTALCOST/I10 = DEALER_COST + RETAIL_COST; AS ''
     COMPUTE LEN_WID/I10 = LENGTH + WIDTH; AS ''
ON TABLE SUBHEAD
"This is new layout #2"
"Header<+0>Header<+0>A<+0>B"
WHERE COUNTRY EQ 'ENGLAND';
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF CLOSE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
TYPE=TABHEADING,
     HEADALIGN=BODY,
$
TYPE=TABHEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     COLSPAN=4,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=2,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=3,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
TYPE=TABHEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=4,
     COLSPAN=1,
     JUSTIFY=LEFT,
$
ENDSTYLE
END
 
 

If I try to separate both the TABLE commands (one for the header & other for the detail report) it does not print the detail table right below the header, but prints it on a new page.. So the header appears on 1 page and the detail table on the next...

I am not sure if this happens because I am using SET COMPOUND command to combine all the PDF pages (all 7) or maybe I am missing something..

I would like for the detail table to print exactly below the header part...

Ignore my previous response.. I am trying something...

Nova27, have you looked into the NOBREAK option of COMPOUND? Perhaps it will help to keep the heading and detail on the same page...

SET COMPOUND= {OPEN|CLOSE} [NOBREAK]

Thanks Francis.. I completely forgot NOBREAK option.. It totally works

Although, now, I am having trouble displaying cell borders for the detail part of my report page.. I could print cell borders for all the rows and columns involved, but the data isn't aligned within the cell borders.. 2 rows of data appear above the tabular border format...

I used the following statement to get all cell borders:

TABLE FILE CAR
PRINT
COUNTRY AS ''
CAR IN 40 AS ''
SEATS IN 60 AS ''
WHERE COUNTRY EQ 'ENGLAND'
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF CLOSE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLESHEET *
TYPE=REPORT, FONT=VERBANA, SIZE=9, COLUMN=COUNTRY, BORDER=LIGHT, WRAP=4.0,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, COLUMN=CAR, BORDER=LIGHT, WRAP=3.0,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, COLUMN=SEATS, BORDER=LIGHT, WRAP=2.0,$
ENDSTYLE
END

I am not sure if I did something wrong here...

This is the 1st part of my report page:

DEFINE FILE DISCLOSURE_BOX_1
BLANK/A25 WITH COC_DTE = ' ';
TEXT85/A200 WITH COC_DTE = 'These are the most common domestically issued card types and processing methods. They do not represent all the possible fees and variations that are charged to merchants';
TEXT86/A50 WITH COC_DTE = 'Processing method';
TEXT87/A50 WITH COC_DTE = 'Payment Card Type';
TEXT88/A50 WITH COC_DTE = 'Card/Device Present';
TEXT89/A100 WITH COC_DTE = 'Means that the card/device was electronically read (contact or contactless interface or mag-stripe).';
TEXT90/A40 WITH COC_DTE = 'Card/Device Not-Present';
TEXT91/A150 WITH COC_DTE = 'Means that the card/device was not electronically read, e.g. mail/telephone order, online, recurring payment, manually key-entered).';
END


TABLE FILE DISCLOSURE_BOX_1
PRINT
TEXT85 IN 2 AS ''
TEXT86 IN 40 AS '' OVER
BLANK AS '' OVER
BLANK AS '' OVER
TEXT87 IN 2 AS ''
TEXT88 IN 40 AS ''
TEXT90 IN 58 AS '' OVER
TEXT89 IN 40 AS ''
TEXT91 IN 60 AS ''
WHERE RECORDLIMIT EQ 1
HEADING CENTER
"Fee Disclosure Box Template"
" "
" "
" "
-*ON TABLE SET PAGE NOPAGE
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF NOBREAK
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLESHEET *
TYPE=HEADING, STYLE=BOLD, FONT=VERBANA, SIZE=12,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=ITALIC, COLUMN=TEXT85, JUSTIFY=CENTER, WRAP=3.5,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=BOLD, COLUMN=TEXT86, JUSTIFY=CENTER, WRAP=3.5,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=BOLD, COLUMN=TEXT87, JUSTIFY=CENTER, WRAP=2.0,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=BOLD, COLUMN=TEXT88, JUSTIFY=CENTER, WRAP=1.5,$
TYPE=REPORT, FONT=VERBANA, SIZE=8, STYLE=ITALIC, COLUMN=TEXT89, WRAP=1.8,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, STYLE=BOLD, COLUMN=TEXT90, JUSTIFY=CENTER, WRAP=2.0,$
TYPE=REPORT, FONT=VERBANA, SIZE=8, STYLE=ITALIC, COLUMN=TEXT91, WRAP=2.0,$

TYPE=REPORT, NAME='BOX030', OBJECT=BOX, POSITION=(0.25 0.8),
DIMENSION=(8.10 1.7),
BORDER-COLOR=BLACK, BORDER=MEDIUM,$
TYPE=REPORT, NAME='BOX031', OBJECT=BOX, POSITION=(0.25 0.8),
DIMENSION=(4.2 0.8),
BORDER-COLOR=BLACK, BORDER=MEDIUM,
BACKCOLOR=WHITE,$
TYPE=REPORT, NAME='BOX032', OBJECT=BOX, POSITION=(4.15 0.8),
DIMENSION=(4.2 0.8),
BORDER-COLOR=BLACK, BORDER=MEDIUM,
BACKCOLOR=WHITE,$
TYPE=REPORT, NAME='BOX033', OBJECT=BOX, POSITION=(0.25 1.6),
DIMENSION=(4.5 1.0),
BORDER-COLOR=BLACK, BORDER=MEDIUM,
BACKCOLOR=WHITE,$
TYPE=REPORT, NAME='BOX034', OBJECT=BOX, POSITION=(4.15 1.6),
DIMENSION=(2.15 1.0),
BORDER-COLOR=BLACK, BORDER=MEDIUM,
BACKCOLOR=WHITE,$
TYPE=REPORT, NAME='BOX035', OBJECT=BOX, POSITION=(6.1 1.6),
DIMENSION=(2.25 1.0),
BORDER-COLOR=BLACK, BORDER=MEDIUM,
BACKCOLOR=WHITE,$
ENDSTYLE
END

quote:

Originally posted by Nova27:
Thanks Francis.. I completely forgot NOBREAK option.. It totally works

Although, now, I am having trouble displaying cell borders for the detail part of my report page.. I could print cell borders for all the rows and columns involved, but the data isn't aligned within the cell borders.. 2 rows of data appear above the tabular border format...

I used the following statement to get all cell borders:

TABLE FILE CAR
PRINT
COUNTRY AS ''
CAR IN 40 AS ''
SEATS IN 60 AS ''
WHERE COUNTRY EQ 'ENGLAND'
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF CLOSE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLESHEET *
TYPE=REPORT, FONT=VERBANA, SIZE=9, COLUMN=COUNTRY, BORDER=LIGHT, WRAP=4.0,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, COLUMN=CAR, BORDER=LIGHT, WRAP=3.0,$
TYPE=REPORT, FONT=VERBANA, SIZE=9, COLUMN=SEATS, BORDER=LIGHT, WRAP=2.0,$
ENDSTYLE
END

I am not sure if I did something wrong here...

Never mind, I figured this one out... Somehow I was using wrong combinations of GRID=ON and BORDER..
Removing all BORDER=LIGHT and introducing the statement TYPE=DATA, GRID=ON, $ solved my problem...

Thanks for your help everyone

Turning BORDER on adds blank lines at the top and also causes other issues. SET PAGE-NUM=NOLEAD or SET PAGE_NUM=NOPAGE may or may not correct the issue.

Thanks for the tip Francis.. appreciate your help and advise..