Hi,
Please help me in formatting my report's subtotal which is generated through across columns.
Below is the code snippet:
SUM TOTAL_CNT/D20.2 AS ''
BY SERVICE AS 'Service'
BY PPC AS O/B'
BY TRADE AS 'Trade'
ACROSS TITLE_SEQUENCE_NBR NOPRINT
ACROSS TITLE_HEAD AS ''
ACROSS HEADER_SEQUENCE_NBR NOPRINT
ACROSS HEADING_TYPE AS ''
ACROSS SUBHEAD_TYPE AS ''
ON PORT_CD_CALL_NBR RECOMPUTE AS 'Total'
ON TABLE NOTOTAL

I want to apply conditional formatting on the subtotal; if subtotal on any given column is not equla to 100 then it should be in red.
I am using below style stmt which applies to all the ST values.
TYPE=SUBTOTAL, JUSTIFY=RIGHT, FONT=VERANDA, COLOR=NAVY BLUE,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $
But i want to put some conditions on subtoal.
What should be the style statement used for this?

I am using WF7.1.3 on Oracle database on WindowsXP platform.

I've not totally tested this, but try:

ACROSSCOLUMN=TOTAL_CNT,TYPE=SUBTOTAL,BY=PORT_CD_CALL_NBR,COLOR=RED,WHEN=TOTAL_CNT NE 100,$

You will need a BY on PORT_CD_CALL_NBR.

Hi Alan,
This solution is not working.
It applies the conditional formatting to entire ST row.
Any other alternative.
Thanks,
Shankar

Shankar

This seems to work....

TABLE FILE CAR
PRINT 
     CAR
     MODEL
     DEALER_COST
     RETAIL_COST
BY COUNTRY
     
ON COUNTRY SUBTOTAL AS '*TOTAL'
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     UNITS=IN,
     LEFTMARGIN=0.000000,
     RIGHTMARGIN=0.000000,
     TOPMARGIN=0.000000,
     BOTTOMMARGIN=0.000000,
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
     PAGECOLOR=RGB(172 192 233),
$
     DEFMACRO=COND0001,
     MACTYPE=RULE,
     WHEN=N4 LT 10000,
$
TYPE=REPORT,
     BORDER=LIGHT,
     BORDER-COLOR=RGB(72 86 115),
     FONT='TAHOMA',
     SIZE=9,
     COLOR='BLACK',
     BACKCOLOR='NONE',
     STYLE=NORMAL,
     RIGHTGAP=0.125000,
     TOPGAP=0.013889,
     BOTTOMGAP=0.027778,
$
TYPE=DATA,
     BORDER=LIGHT,
     BORDER-COLOR=RGB(72 86 115),
     SIZE=8,
     BACKCOLOR='WHITE',
$
TYPE=TITLE,
     BORDER-TOP=MEDIUM,
     BORDER-BOTTOM=MEDIUM,
     BORDER-LEFT=OFF,
     BORDER-RIGHT=OFF,
     BORDER-COLOR=RGB(72 86 115),
     BACKCOLOR=RGB(237 241 213),
     STYLE=BOLD,
$
TYPE=TITLE,
     ACROSSCOLUMN=N1,
     BACKCOLOR='SILVER',
$
TYPE=TABHEADING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=TABFOOTING,
     SIZE=12,
     STYLE=BOLD,
$
TYPE=HEADING,
     SIZE=12,
     COLOR=RGB(237 241 213),
     BACKCOLOR=RGB(70 96 149),
     STYLE=BOLD,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=10,
     JUSTIFY=LEFT,
     WIDTH=2.375,
$
TYPE=HEADING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=2,
     SIZE=10,
     JUSTIFY=LEFT,
     WIDTH=3.625,
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=10,
     JUSTIFY=LEFT,
     WIDTH=2.375,
$
TYPE=HEADING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=2,
     SIZE=10,
     JUSTIFY=LEFT,
     WIDTH=3.625,
$
TYPE=FOOTING,
     BORDER=LIGHT,
     SIZE=12,
     COLOR=RGB(237 241 213),
     BACKCOLOR=RGB(70 96 149),
     STYLE=BOLD,
$
TYPE=FOOTING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=10,
     JUSTIFY=LEFT,
     WIDTH=2.500,
$
TYPE=FOOTING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=2,
     SIZE=10,
     JUSTIFY=RIGHT,
     WIDTH=1.625,
$
TYPE=FOOTING,
     LINE=1,
     OBJECT=TEXT,
     ITEM=3,
     SIZE=10,
     JUSTIFY=RIGHT,
     WIDTH=1.875,
$
TYPE=FOOTING,
     LINE=2,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=3.750,
$
TYPE=FOOTING,
     LINE=3,
     OBJECT=TEXT,
     ITEM=1,
     SIZE=10,
     JUSTIFY=LEFT,
     WIDTH=3.750,
$
TYPE=SUBHEAD,
     SIZE=12,
     COLOR=RGB(255 255 153),
     BACKCOLOR=RGB(153 204 255),
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     BY=1,
     BORDER-TOP=MEDIUM,
     BORDER-TOP-COLOR=RGB(72 86 115),
     SIZE=11,
     COLOR=RGB(72 86 115),
     BACKCOLOR=RGB(172 192 233),
$
TYPE=SUBFOOT,
     SIZE=10,
     STYLE=BOLD,
$
TYPE=SUBTOTAL,
     BACKCOLOR='WHITE',
$
TYPE=SUBTOTAL,
     BY=1,
     BORDER-TOP=MEDIUM,
     SIZE=8,
     COLOR=RGB(72 86 115),
     STYLE=BOLD,
$
TYPE=SUBTOTAL,
     BY=1,
     COLUMN=N4,
     COLOR='RED',
     MACRO=COND0001,
$
TYPE=SUBTOTAL,
     BY=2,
     BORDER-TOP=LIGHT,
     BORDER-BOTTOM=MEDIUM,
     BORDER-TOP-COLOR=RGB(72 86 115),
     BORDER-BOTTOM-COLOR=RGB(72 86 115),
     SIZE=8,
     STYLE=BOLD,
$
TYPE=ACROSSVALUE,
     SIZE=9,
$
TYPE=ACROSSVALUE,
     ACROSS=1,
     BACKCOLOR=RGB(237 241 213),
     STYLE=BOLD,
     JUSTIFY=CENTER,
$
TYPE=ACROSSTITLE,
     STYLE=BOLD,
$
TYPE=ACROSSTITLE,
     ACROSS=1,
     BORDER=MEDIUM,
     BORDER-COLOR=RGB(72 86 115),
     STYLE=BOLD,
$
TYPE=GRANDTOTAL,
     BORDER-TOP=MEDIUM,
     BORDER-BOTTOM=MEDIUM,
     BORDER-LEFT=OFF,
     BORDER-RIGHT=OFF,
     BORDER-COLOR=RGB(72 86 115),
     SIZE=8,
     BACKCOLOR=RGB(237 241 213),
     STYLE=BOLD,
$
ENDSTYLE
END
  

Hi Frank,
This solution is not working with my report.
Also the code snippet provided by you doesnt have any ACROSS columns. I tried to tweak it in different ways to make it work with my report but it doesnt work.
Please have a look at my code snippet again:
===============================================
SUM TOTAL_CNT/D20.2 AS ''
BY SERVICE AS 'Service'
BY PPC AS O/B'
BY TRADE AS 'Trade'
ACROSS TITLE_SEQUENCE_NBR NOPRINT
ACROSS TITLE_HEAD AS ''
ACROSS HEADER_SEQUENCE_NBR NOPRINT
ACROSS HEADING_TYPE AS ''
ACROSS SUBHEAD_TYPE AS ''
ON PPC RECOMPUTE AS 'Total'
ON TABLE NOTOTAL
================================================
Basically my report is applying all the ACROSS columns (i.e. TITLE_SEQUENCE_NBR,TITLE_HEAD,HEADER_SEQUENCE_NBR,HEADING_TYPE&SUBHEAD_TYPE) to just one column that is TOTAL_CNT. It means TOTAL_CNT is summarized by all these BY and ACROSS fields. Here is a sample screen shot of my report. Please note that i want to color 99.00 as RED since it is not equal to 100.00.

Period4-2007
TEU DWT
Alloc% Alloc%
Service Leg O/B Trade Group
APX TKY1 GOVT
LTED 43.40
RFR 4.70
TPED 50.90
Total TKY1 99.00


I hope i am clear in explaining my problem.
Please suggest some solution based on this.

Regards,
Shankar

Shankar

I see what you want....
I will try, but for the next time when you post a question first try to make your example on the CAR or SALES databases, so we can test it...

Alan,
I really have no idea about CAR or SALES database.

These databases are used in the courses and are mentioned in the manuals whit samples.
I thought it all comes with the package

TABLE FILE CAR
SUM 
     DEALER_COST
     RETAIL_COST
     COMPUTE ZERO/D12.2S = IF COUNTRY EQ 'ENGLAND' THEN 0 ELSE SALES;
BY COUNTRY
BY CAR
ACROSS ACC
     
ON COUNTRY SUBTOTAL AS '*TOTAL'
DEFMACRO=COND0001,     MACTYPE=RULE,     WHEN=N3 LT 10000,$
TYPE=SUBTOTAL,     BY=1,     ACROSSCOLUMN=N1,     COLOR='RED',     MACRO=COND0001,$
  

this should work....

N1 is the first field you want to display

Alan,
Sorry, but I am unable to apply this solution to my report.

Could you please use the exact attributes as given in my code snippet.

Thanks,
Shankar

No, not without some clearer code and output examples.

I cannot actually see what you want here, other than the code I supplied, and using an example on a WF sample datafile, as Frank suggested, is most helpful.

Don't expect our code to just slot in, you have to do somethings yourself, it's the only way to learn.

Hi Shankar,
Hope this is what you needed.

SET NODATA=0
TABLE FILE CAR
SUM RETAIL_COST
BY CAR
BY COUNTRY
BY MODEL
ACROSS SALES
ACROSS LENGTH
ACROSS WIDTH
ACROSS HEIGHT
ON CAR RECOMPUTE AS 'TOTAL'
ON TABLE NOTOTAL
ON TABLE SET STYLE *
TYPE=SUBTOTAL,BY=CAR,ACROSSCOLUMN=RETAIL_COST,COLOR=RED,WHEN=RETAIL_COST GT 6000,$
ENDSTYLE
END
-EXIT

Just change your stylesheet to

TYPE=SUBTOTAL,BY=PPC,ACROSSCOLUMN=TOTAL_CNT,COLOR=RED,WHEN TOTAL_CNT NE 100,$

Hope this helps

quote:

TYPE=SUBTOTAL,BY=PPC,ACROSSCOLUMN=TOTAL_CNT,COLOR=RED,WHEN TOTAL_CNT NE 100,$

Kamesh

Which is the same (apart from BY fieldname which he has changed) as I gave to Shankar earlier:

quote:

ACROSSCOLUMN=TOTAL_CNT,TYPE=SUBTOTAL,BY=PORT_CD_CALL_NBR,COLOR=RED,WHEN=TOTAL_CNT NE 100,$

Alan,
Sorry I didn't see that earlier.

I believe when he put his code first time, he mentioned the Subtotal field wrongly. In his second version of code he mentioned the right BY and SubTotal field.

That's okay Kamesh. At least both of us think the same solution for him!

my solution is also the same, the only diff is that I use a macro, but there seems to be a bit of misunderstanding here....

quote:

and SubTotal field

Hi Alan/Kamesh,
Sorry for the delay in response. Actually i had to go out.
Thanks for your valuable suggestions, but i had already told you that this solution (i.e. TYPE=SUBTOTAL,BY=PPC,ACROSSCOLUMN=TOTAL_CNT,COLOR=RED,WHEN TOTAL_CNT NE 100,$) is not giving expected results.
It applies the formatting in all the ST values whether they are 100 or not. For example, if there are 5 subtotals displayed in the report. 4 of which has 100 and one is having 90, then it is filling RED color in all 5 values instead of coloring just the 90 value.
Below are some solutions which i have tried but to no avail:
TYPE=SUBTOTAL, BY=2, COLUMN=TOTAL_CNT, COLOR='RED', MACRO=COND0001, $
TYPE=SUBTOTAL, COLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, WHEN=TOTAL_CNT NE 100, JUSTIFY=RIGHT, FONT=VERANDA, COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $
TYPE=SUBTOTAL, COLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, WHEN=TOTAL_CNT NE 100.00, JUSTIFY=RIGHT, FONT=VERANDA, COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $
TYPE=SUBTOTAL, ACROSSCOLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, WHEN=TOTAL_CNT NE '100.00', JUSTIFY=RIGHT, FONT=VERANDA, COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $

None of them is giving me the result explained in the above example.

Also in the solution suggested by you, you are trying to refer ACROSSCOLUMN=TOTAL_CNT, but i think TOTAL_CNT is not at all ACROSSCOLUMN, it is ACROSSVALUE. ACROSSCOLUMNs are TITLE_SEQUENCE_NBR,TITLE_HEAD,HEADER_SEQUENCE_NBR etc...
Please correct me if i am wrong somewhere...

Thanks,
Shankar

quote:

Please have a look at my code snippet again:
===============================================
SUM TOTAL_CNT/D20.2 AS ''
BY SERVICE AS 'Service'
BY PPC AS O/B'
BY TRADE AS 'Trade'
ACROSS TITLE_SEQUENCE_NBR NOPRINT
ACROSS TITLE_HEAD AS ''
ACROSS HEADER_SEQUENCE_NBR NOPRINT
ACROSS HEADING_TYPE AS ''
ACROSS SUBHEAD_TYPE AS ''
ON PPC RECOMPUTE AS 'Total'
ON TABLE NOTOTAL
================================================
Basically my report is applying all the ACROSS columns (i.e. TITLE_SEQUENCE_NBR,TITLE_HEAD,HEADER_SEQUENCE_NBR,HEADING_TYPE&SUBHEAD_TYPE) to just one column that is TOTAL_CNT. It means TOTAL_CNT is summarized by all these BY and ACROSS fields. Here is a sample screen shot of my report. Please note that i want to color 99.00 as RED since it is not equal to 100.00.

Make up your mind which field you are applying the RECOMPUTE on.

ACROSSCOLUMN refers to columns within an across phrase. In your case here TOTAL_CNT.

IF PPC is the point at which you want to SUBTOTAL/RECOMPUTE then:

TYPE=SUBTOTAL, 
ACROSSCOLUMN=TOTAL_CNT, 
BY=PPC, 
WHEN=TOTAL_CNT NE 100.00, 
JUSTIFY=RIGHT, 
FONT=VERDANA, 
COLOR=RED,
BACKCOLOR=TURQUOISE,
STYLE=BOLD,
SIZE=8,$

will work unless you are omitting something important in your code 'snippet'.

quote:

Below are some solutions which i have tried but to no avail:
TYPE=SUBTOTAL, BY=2, COLUMN=TOTAL_CNT, COLOR='RED', MACRO=COND0001, $
TYPE=SUBTOTAL, COLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, WHEN=TOTAL_CNT NE 100, JUSTIFY=RIGHT, FONT=VERANDA, COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $
TYPE=SUBTOTAL, COLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, WHEN=TOTAL_CNT NE 100.00, JUSTIFY=RIGHT, FONT=VERANDA, COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $
TYPE=SUBTOTAL, ACROSSCOLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, WHEN=TOTAL_CNT NE '100.00', JUSTIFY=RIGHT, FONT=VERANDA, COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $

And none of them are correct if you are using PPC as your BY/SUBTOTAL.

quote:

using PPC

Hi Alan,
Sorry that i missed to tell you that PPC and PORT_CD_CALL_NBR are same thing. I had used PPC as an acronym(short form)for PORT_CD_CALL_NBR.
I tried this solution but it is still not working. It somehow applies the formatting for the entire subtotal row (i.e. all the values of ST), instead of conditionally applying it.
I would have loved to put a snapshot of the report but this editor will not allow me to do so.
Any other alternative...

Try and reproduce the problem on the car or sales files as Frank suggested.

This will then allow us to be working from the same baseline.

These files can be found in the ibi\apps\ibisamp directory.

I believe that the solution provided should work and cannot see why it shouldn't; unless something is missing from your explanation.

Alan,
found the ibisamp directory. There are a lot of files with extensions .fex,.mas,.foc...
But i really have no clue about how can i use these to generate some report.
I generate reports using some HTML page which calls a .fex file and passes the user given inputs to the .fex file which in turn connects to Oracle database,uses these user inputs to generate some dynamic queries and then finally generates the report.
In my type of report generation, i've never used .mas or .foc files.
Dont know how can i use the sample files?How can i call them?how to connect to some DB for these sample files?
Thanks a lot for your support,but i can use only my code snippets to explain you my problems.

You've helped so many times in the past with my code only, but this time probably i am not able to explain the issue at hand... :-(
dont know how to move forward...

Here is the exact code and style statments which i am using to generate report. Hope you'll figure out the problem with this...

SUM TOTAL_CNT/D20.2S AS ''
BY SERVICE_CD AS 'Service'
BY PORT_CD_CALL_NBR AS 'Leg O/B'
BY TRADE_LANE_CD AS 'Trade Group'
ACROSS TITLE_SEQUENCE_NBR NOPRINT
ACROSS TITLE_HEAD AS ''
ACROSS HEADER_SEQUENCE_NBR NOPRINT
ACROSS HEADING_TYPE AS ''
ACROSS SUBHEAD_TYPE AS ''
ON PORT_CD_CALL_NBR RECOMPUTE AS 'Total'
ON TABLE NOTOTAL

ON TABLE SET STYLE *
TYPE=REPORT, SIZE=8, GRID=ON, BORDER=OFF,BACKCOLOR=WHITE, $
TYPE=TITLE,GRID=ON, JUSTIFY=CENTER,FONT=VERANDA,COLOR=WHITE,BACKCOLOR=NAVY BLUE, STYLE=BOLD, SIZE=8, $
TYPE=DATA, JUSTIFY=RIGHT, FONT=VERANDA,COLOR=BLUE,SIZE=8, $
TYPE=TABHEADING, JUSTIFY=CENTER, SIZE=10, COLOR=NAVY BLUE , BACKCOLOR=WHITE, STYLE=BOLD, $
TYPE=SUBHEAD, JUSTIFY=CENTER, SIZE=8,STYLE=BOLD, COLOR=NAVY BLUE, BACKCOLOR=WHITE, $
TYPE=HEADING, JUSTIFY=LEFT,COLOR=NAVY BLUE,BACKCOLOR=WHITE, SIZE=8,GRID=OFF,$
TYPE=FOOTING, SIZE=8, STYLE=BOLD,GRID=OFF,$
TYPE=DATA, COLUMN=SERVICE_CD,FONT=VERANDA,COLOR=NAVY BLUE,STYLE=BOLD,SIZE=8, $
TYPE=DATA, COLUMN=PORT_CD_CALL_NBR,FONT=VERANDA,COLOR=NAVY BLUE,STYLE=BOLD,SIZE=8, $
TYPE=DATA, COLUMN=TRADE_LANE_CD,FONT=VERANDA,COLOR=NAVY BLUE,STYLE=BOLD,SIZE=8, $
TYPE=DATA, COLUMN=YEAR_NBR,FONT=VERANDA,COLOR=NAVY BLUE,STYLE=BOLD,SIZE=8, $
TYPE=DATA, ACROSSCOLUMN=HEADING_TYPE, JUSTIFY=CENTER, FONT=VERANDA, COLOR=WHITE,BACKCOLOR=NAVY BLUE,STYLE=BOLD,SIZE=8, $
TYPE=DATA, COLUMN=HEADING_TYPE, JUSTIFY=CENTER, FONT=VERANDA, COLOR=WHITE,BACKCOLOR=NAVY BLUE,STYLE=BOLD,SIZE=8, $
TYPE=SUBTOTAL, JUSTIFY=RIGHT, FONT=VERANDA, COLOR=NAVY BLUE,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $
TYPE=SUBTOTAL, ACROSSCOLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, WHEN=TOTAL_CNT NE 100.00, JUSTIFY=RIGHT, FONT=VERANDA, COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $
TYPE=ACROSSTITLE,GRID=ON, JUSTIFY=CENTER,FONT=VERANDA,COLOR=WHITE,BACKCOLOR=NAVY BLUE, SIZE=8, STYLE=BOLD, $
TYPE=ACROSSVALUE, GRID=ON, JUSTIFY=CENTER,FONT=VERANDA,COLOR=WHITE,BACKCOLOR=NAVY BLUE, SIZE=8, STYLE=BOLD, $
ENDSTYLE
END
-EXIT

Shankar

Now you have found the sample files, I would suggest to copy my smaple script on the CAR database.
Create fex in the sammple directory and use my script to see if it meets your requierments.

BTW
I see you use the font VERANDA...I think it is misspelled and should be VERDANA...

Okay,

Everything is fine.

However, I suspect that your calculation for TOTAL_CNT is the problem.

In your WHEN, you ask for TOTAL_CNT NE 100.00. For numerics, if your field contains 100.0000001, which it may well do after a calculation, it will pass the WHEN and display as RED. This is a problem with any computer calculations, particularly with anything other than a + or - involved.

Alter your style line to be 2 lines:

TYPE=SUBTOTAL, ACROSSCOLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, 
WHEN=TOTAL_CNT LT 100, JUSTIFY=RIGHT, FONT=VERDANA, 
COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $
TYPE=SUBTOTAL, ACROSSCOLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, 
WHEN=TOTAL_CNT GT 100.005, JUSTIFY=RIGHT, FONT=VERDANA, 
COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $

Betcha it will work now.

And as Frank says, change VERANDA.

quote:

TYPE=SUBTOTAL, ACROSSCOLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, WHEN=TOTAL_CNT LT 100, JUSTIFY=RIGHT, FONT=VERDANA, COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $
TYPE=SUBTOTAL, ACROSSCOLUMN=TOTAL_CNT, BY=PORT_CD_CALL_NBR, WHEN=TOTAL_CNT GT 100.005, JUSTIFY=RIGHT, FONT=VERDANA, COLOR=RED,BACKCOLOR=TURQUOISE,STYLE=BOLD,SIZE=8, $

Alan,
It is still not working...
but i think we've a clue here, there is something wrong with "100" or "100.005". WF is not able to recognize them.
we need to find out something which can be recognized by WF.

You need to try different values.

And what do you mean WF doesn't recognise them?

How is this manifesting itself?

Remember that the figure could be 99.99995, so maybe LE 99.99.

Alan,
Thanks a ton!!!
Finally its working.
You've made my day.
You've always helped me out whenever i was in a deep trouble.
Thanks for your continuous support and patience!
Looking forward to learn more and more stuffs about webfocus from u...

Frank was suggesting something about creating CAR database and using sample files of WF. Can u plz throw a little more light on that. As i've never used it before, kindly explain me in a layman's language about the setup and other stuffs like how to start using these samples...

Thanks and Regards,
Shankar

HI Shankar,

Try the Tutorials from the Getting started manual. Thats how I Got to learn the basics.