Hi,

How can I WRAP heading in PDF. See the following example.

TABLE FILE CAR
PRINT
CAR
DEALER_COST
RETAIL_COST
SALES
HEADING
"THIS IS A LONG TEXT WHICH HAS TO WRAPPED TO TWO OR MORE LINES. CURRENTLY IT IS NOT DISPLAYED PROPERLY DUE TO THE LENGTH OF THE TEXT"
""
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=HEADING,
SIZE=12,
STYLE=BOLD,
LINE=1,
WRAP=3,
$
ENDSTYLE
END

Thanks for your help!

This message has been edited. Last edited by: Kerry,

The obvious questions is, why not just two lines of heading? Or is the heading text passed to your report?

It is a heading text passed as a variable to my report. I tried WRAP/SQUEEZE etc, but none working with PDF. Not sure where I am going wrong.

This message has been edited. Last edited by: Cyril Joy,

An alternative is to split it yourself using PARAG to position a character to allow you to use the GETTOK function.

T

Cyril,

Create a field containing the &variable value and then use the field in your HEADING. Fields will respect the WRAP setting. Straight text in a HEADING will not.

I wrote an article that expalins many of the ways to deal with text and fields in HEADINGs, SUBHEADings, etc. You may find this useful. The information about the field values in a HEADING is further down in the article.

http://www.informationbuilders.com/support/developers/htmlpdf_part2.html

Cyril,

Here's your code with the necessary changes:

TABLE FILE CAR
PRINT
CAR
DEALER_COST
RETAIL_COST
SALES
COMPUTE HDRTEXT/A150='THIS IS A LONG TEXT WHICH HAS TO WRAPPED TO TWO OR MORE LINES. CURRENTLY IT IS NOT DISPLAYED PROPERLY DUE TO THE LENGTH OF THE TEXT'; NOPRINT
HEADING
"<HDRTEXT"
""
ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=HEADING,
SIZE=12,
STYLE=BOLD,
LINE=1,
WRAP=3,
$
ENDSTYLE
END

Great Idea! Appreciate it. Thanks for your help.

Mickey: Nice article. Cyril - that should definitely do it for you.
Ira

After playing with this a little, I found it interesting that wrapping a field within a text line works in HEADING, SUBHEAD, SUBFOOT, TABHEADING, AND TABFOOTING, but it does not work correctly (at least in PDF) in FOOTING. It seems to truncate the field after one line at the specified length - as if it doesn't know if there will be enough room for the additional lines of wrapped field value, so it doesn't bother to display them. Can you verify this when you get a minute, Mickey?

Darin,

You are correct. I am using WF713 and the FOOTING does not show anymore than one line of text. Have you reported this to IBI to see if it is fixed in later releases than what we are using? (me-WF713, you-WF716)

I found a WRAPping issue with fields in HEADINGs in WF713 that IBI says is fixed in WF716. Maybe further fixes are in WF76x.

FYI.. This issue still isn't fixed in 7.7.1. Which is what led me to this post...

quote:

Create a field containing the &variable value and then use the field in your HEADING. Fields will respect the WRAP setting. Straight text in a HEADING will not.

I wrote an article that expalins many of the ways to deal with text and fields in HEADINGs, SUBHEADings, etc. You may find this useful. The information about the field values in a HEADING is further down in the article.

http://www.informationbuilders...s/htmlpdf_part2.html

Thatz defenitely an useful article.. Thanks Mickey...

You are welcome. I am glad the two articles I wrote are still helping peple even after three years.

True all the way !!!

I read the articles but I am still having a problem getting an amper variable to center in a heading, it trails off the right side of the page and will not wrap. I have tried to assign the &var to a define field and use that in the heading and it doesn't work. Any other ideas??

quote:

http://www.informationbuilders...s/htmlpdf_part2.html

I have read this great article and tried the things that are in it. I still need help along these lines: I have a very long (A8000V) field that I want to wrap in PDF at the subfoot level. In the article the heading works great for wrpping - not so with the subfoot (or footing). It works in HTML format - but not in PDF. Can anyone PLEASE help me?
THANKS!!
Marilyn
version 7.6.11

I tried this on v7.7.03 and as you say, wrap with a long footing does not work. It works for tabheading, tabfooting, heading, subhead and subfoot, but not for footing.
I would open a case with IBI. You can use this reproducible code as an example:

-SET &FOOT_TEXT = 'At vero eos et accusamus et iusto odio dignissimos ducimus qui blanditiis praesentium voluptatum deleniti atque corrupti quos dolores et quas molestias excepturi sint occaecati cupiditate non provident, similique sunt in culpa qui officia deserunt mollitia animi, id est laborum et dolorum fuga. Et harum quidem rerum facilis est et expedita distinctio. Nam libero tempore, *** soluta nobis est eligendi optio cumque nihil impedit quo minus id quod maxime placeat facere possimus, omnis voluptas assumenda est, omnis dolor repellendus. Temporibus autem quibusdam et aut officiis debitis aut rerum necessitatibus saepe eveniet ut et voluptates repudiandae sint et molestiae non recusandae. Itaque earum rerum hic tenetur a sapiente delectus, ut aut reiciendis voluptatibus maiores alias consequatur aut perferendis doloribus asperiores repellat.';

TABLE FILE CAR
SUM
COMPUTE FOOT_TEXT/A1200 = '&FOOT_TEXT'; NOPRINT
SALES
BY COUNTRY
BY CAR
BY MODEL

ON COUNTRY SUBHEAD
"<FOOT_TEXT"
" "

ON COUNTRY SUBFOOT
" "
"<FOOT_TEXT"

HEADING
"<FOOT_TEXT"
" "

FOOTING
" "
"<FOOT_TEXT"

ON TABLE SUBHEAD
"<FOOT_TEXT"
" "

ON TABLE SUBFOOT
" "
"<FOOT_TEXT"

ON TABLE PCHOLD FORMAT PDF

ON TABLE SET STYLE *
TYPE=REPORT, ORIENTATION=LANDSCAPE, $
TYPE=REPORT, FONT=ARIAL, SIZE=10, $
TYPE=TABHEADING, SIZE=8, WRAP=10, COLOR=PURPLE, $
TYPE=TABFOOTING, SIZE=8, WRAP=10, COLOR=BROWN, $
TYPE=HEADING, SIZE=8, WRAP=10, COLOR=RED, $
TYPE=FOOTING, SIZE=8, WRAP=10, COLOR=BLUE, $
TYPE=SUBHEAD, SIZE=8, WRAP=10, COLOR=GREEN, $
TYPE=SUBFOOT, SIZE=8, WRAP=10, COLOR=ORANGE, $
END
-RUN

If it's acceptable to have the text on only the last page, use ON TABLE SUBFOOT to create a tabfooting.

This message has been edited. Last edited by: Francis Mariani,

Same result in v7.6.8 and v7.7.02. I suspect this has been there since the beginning and into the 21st century.

Don't we love consistency?

Aren't you just the lucky fellow, working on v5.3.4!

Yep, but not for long ... I think I'm gonna miss it