DEFINE FILE IBISAMP/CAR
  C1/I5 WITH CAR   = C1 + 1;
  C2/I5 WITH SEATS = C2 + 1;
  C3/I5 WITH CAR   = C3 + 1;
  C4/I5 WITH CAR   = 0;
END

TABLE FILE IBISAMP/CAR
SUM
    C1
    C2
    C3
    C4
   BY COUNTRY
 ON TABLE HOLD FORMAT ALPHA
END
-RUN
TABLE FILE HOLD
SUM
    MAX.C1
    MAX.C2    
    MAX.C3    
    MAX.C4
  ON TABLE HOLD AS MAXVALUE FORMAT ALPHA
END
-RUN
-READFILE MAXVALUE
-SET &SHOW_C1 = IF &C1 NE 0 THEN 'C1' ELSE '';
-SET &SHOW_C2 = IF &C2 NE 0 THEN 'C2' ELSE '';
-SET &SHOW_C3 = IF &C3 NE 0 THEN 'C3' ELSE '';
-SET &SHOW_C4 = IF &C4 NE 0 THEN 'C4' ELSE '';
TABLE FILE HOLD
SUM
   &SHOW_C1.EVAL
   &SHOW_C2.EVAL
   &SHOW_C3.EVAL
   &SHOW_C4.EVAL
  BY COUNTRY
 ON TABLE PCHOLD FORMAT HTMTABLE
END
-EXIT

  
-SET &ECHO=ALL;
-* File rakesh01.fex
DEFINE FILE CAR
  V1/I5 WITH CAR   = V1 + 1;
  V2/I5 WITH SEATS = V2 + 1;
  V3/I5 WITH CAR   = 0;
  V4/I5 WITH MODEL   = V4 + 1;
END

TABLE FILE CAR
SUM 
MAX.V1 NOPRINT
MAX.V2 NOPRINT
MAX.V3 NOPRINT
MAX.V4 NOPRINT
SUM
    V1
    V2
    V3
    V4
   BY COUNTRY
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
 INCLUDE=ENDEFLT,
$
-REPEAT #ZERO FOR &I FROM 1 TO 4;
TYPE=DATA, COLUMN=V&I, SIZE=1, WHEN=MAX.V&I EQ 0, 
$
TYPE=TITLE,COLUMN=V&I, SIZE=1, WHEN=MAX.V&I EQ 0, 
$
-#ZERO 
ENDSTYLE
END

  
-SET &ECHO=ALL;
-* File rakesh01.fex
DEFINE FILE CAR
RUN0/DMYY='19/04/2014';
NUM/I3 WITH COUNTRY = NUM + 1;
RUN1/DMYY=RUN0 + NUM;
RUN2/DMYY=RUN0 + NUM*2;
RUN4/DMYY=RUN0 + NUM*7;
RUN3/DMYY=0;
END
TABLE FILE CAR
SUM
    RUN1
    RUN2
    RUN3
    RUN4
   BY COUNTRY
ON TABLE SAVE AS RAK FORMAT ALPHA
END
-RUN
EX -LINES 7 EDAPUT MASTER,RAK,C,MEM
FILENAME=RAK, SUFFIX=FIX
 SEGNAME=RAK, SEGTYPE=S0
  FIELDNAME=COUNTRY, COUNTRY, A10, A10, $
 SEGNAME=RUN, SEGTYPE=S0, PARENT=RAK, OCCURS=VARIABLE
  FIELDNAME=RUN, RUN, DMYY, A8, $
  FIELDNAME=CNTR, ORDER, I2, I4,$
-RUN
DEFINE FILE RAK
RNUM/A5='RUN' | EDIT(CNTR);
END
-RUN
SET ACROSSTITLE = SIDE
TABLE FILE RAK
SUM RUN
BY COUNTRY
ACROSS RNUM AS ''
IF RUN NE '31/12/1900';
ON TABLE SET HTMLCSS ON
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET STYLE *
 INCLUDE=ENDEFLT,
$
ENDSTYLE
END

-* fpRakesh1.fex

-SET &ECHO=ALL;

SET ASNAMES=ON
SET HOLDLIST=PRINTONLY
SET HOLDFORMAT=ALPHA
SET NODATA=NULL
-RUN

FILEDEF FPRAKESH1 DISK fprakesh1.txt
-RUN

-WRITE FPRAKESH1  1 20110919 20120109 20120407 .        .        .        .
-WRITE FPRAKESH1  2 20110919 20120123 20120709 .        .        .        .
-WRITE FPRAKESH1  3 20110926 20120130 20121224 .        .        .        .
-WRITE FPRAKESH1  4 20111003 20120305 20120716 .        .        .        .
-WRITE FPRAKESH1  5 20111017 20120326 20130107 .        .        .        .
-WRITE FPRAKESH1  6 20111010 20120312 20120723 .        .        .        .
-WRITE FPRAKESH1  7 20111024 20120423 20130128 .        .        .        .
-WRITE FPRAKESH1  8 20111031 20120521 20121231 .        .        .        .
-WRITE FPRAKESH1  9 20111107 20120528 .        .        .        .        .
-WRITE FPRAKESH1 10 20111114 20120604 .        .        .        .        .
-WRITE FPRAKESH1 11 20111121 20120611 .        .        .        .        .
-WRITE FPRAKESH1 12 20111205 20120618 .        .        .        .        .
-WRITE FPRAKESH1 13 20120102 20120625 .        .        .        .        .
-WRITE FPRAKESH1 14 20120116 20120702 .        .        .        .        .
-WRITE FPRAKESH1 15 20120220 20120813 .        .        .        .        .
-WRITE FPRAKESH1 16 20120213 20121224 .        .        .        .        .

FILEDEF MASTER DISK fprakesh1.mas
-RUN

-WRITE MASTER FILENAME=FPRAKESH1, SUFFIX=FIX, $
-WRITE MASTER SEGNAME=FPRAKESH1, $
-WRITE MASTER FIELDNAME=ID, FORMAT=I2, ACTUAL=A2, MISSING=ON, $
-WRITE MASTER FIELDNAME=FILLER1, FORMAT=A1, ACTUAL=A1, $
-WRITE MASTER FIELDNAME=RUN1, FORMAT=YYMD, ACTUAL=A8YYMD, MISSING=ON, $
-WRITE MASTER FIELDNAME=FILLER2, FORMAT=A1, ACTUAL=A1, $
-WRITE MASTER FIELDNAME=RUN2, FORMAT=YYMD, ACTUAL=A8YYMD, MISSING=ON, $
-WRITE MASTER FIELDNAME=FILLER3, FORMAT=A1, ACTUAL=A1, $
-WRITE MASTER FIELDNAME=RUN3, FORMAT=YYMD, ACTUAL=A8YYMD, MISSING=ON, $
-WRITE MASTER FIELDNAME=FILLER4, FORMAT=A1, ACTUAL=A1, $
-WRITE MASTER FIELDNAME=RUN4, FORMAT=YYMD, ACTUAL=A8YYMD, MISSING=ON, $
-WRITE MASTER FIELDNAME=FILLER5, FORMAT=A1, ACTUAL=A1, $
-WRITE MASTER FIELDNAME=RUN5, FORMAT=YYMD, ACTUAL=A8YYMD, MISSING=ON, $
-WRITE MASTER FIELDNAME=FILLER6, FORMAT=A1, ACTUAL=A1, $
-WRITE MASTER FIELDNAME=RUN6, FORMAT=YYMD, ACTUAL=A8YYMD, MISSING=ON, $
-WRITE MASTER FIELDNAME=FILLER7, FORMAT=A1, ACTUAL=A1, $
-WRITE MASTER FIELDNAME=RUN7, FORMAT=YYMD, ACTUAL=A8YYMD, MISSING=ON, $
-RUN

TABLE FILE FPRAKESH1
SUM
MIN.RUN1
MIN.RUN2
MIN.RUN3
MIN.RUN4
MIN.RUN5
MIN.RUN6
MIN.RUN7

ON TABLE HOLD AS HRAKESH1
END
-RUN

-READ HRAKESH1 &RUN1.A8. &RUN2.A8. &RUN3.A8. &RUN4.A8. &RUN5.A8. &RUN6.A8. &RUN7.A8.

-? &RUN

-SET &COLRUN1 = IF &RUN1 EQ '.' THEN '' ELSE 'RUN1';
-SET &COLRUN2 = IF &RUN2 EQ '.' THEN '' ELSE 'RUN2';
-SET &COLRUN3 = IF &RUN3 EQ '.' THEN '' ELSE 'RUN3';
-SET &COLRUN4 = IF &RUN4 EQ '.' THEN '' ELSE 'RUN4';
-SET &COLRUN5 = IF &RUN5 EQ '.' THEN '' ELSE 'RUN5';
-SET &COLRUN6 = IF &RUN6 EQ '.' THEN '' ELSE 'RUN6';
-SET &COLRUN7 = IF &RUN7 EQ '.' THEN '' ELSE 'RUN7';

TABLE FILE FPRAKESH1
PRINT
&COLRUN1
&COLRUN2
&COLRUN3
&COLRUN4
&COLRUN5
&COLRUN6
&COLRUN7
BY ID
END
-RUN

Francis

Give me code, or give me retirement. In FOCUS since 1991

Production: WF 7.7.05M, Dev Studio, BID, MRE, WebSphere, DB2 / Test: WF 8.1.05M, App Studio, BI Portal, Report Caster, jQuery, HighCharts, Apache Tomcat, MS SQL Server

quote:

Originally posted by Rakesh Boddu:
Hi Jack,

Can you post some example elaborating your explanation.

DEFINE FILE xxx
  date1count/I6=IF RUN1 IS MISSING THEN 0 ELSE 1;
  date2count/I6=IF RUN2 IS MISSING THEN 0 ELSE 1;
  date3count/I6=IF RUN3 IS MISSING THEN 0 ELSE 1;
  . . .
END

TABLE FILE xxx
SUM COMPUTE
  date1print/A8=IF SUM.date1count EQ 0 THEN 'NOPRINT' ELSE ' ';
  date2print/A8=IF SUM.date2count EQ 0 THEN 'NOPRINT' ELSE ' ';
  date3print/A8=IF SUM.date3count EQ 0 THEN 'NOPRINT' ELSE ' ';
  . . .
ON TABLE HOLD AS 'CONTROL'
END
-RUN
-READFILE CONTROL
-? &date
TABLE FILE xxx
SUM
  RUN1 &date1print
  RUN2 &date2print
  RUN2 &date3print
    etc.
BY ID
. . .
END

 RUN1 AS 'HEADING,FOR DATE 1&date1print'