Something that I would like to share.

One of our customers wanted to display a bar graph. However the values to be displayed had high differences in amplitude, meaning some could be small - say, in the hundreds, and some could be quite large - say in the tens of millions.

When using a simple bar graph, the small values were squashed.

One of the ways to remedy this is to use a logarithmic scale. This option does not exist as one of the options of GRAPH FILE but there is a command which does it:

setY1LogScale(true);

.

Following is the example I concocted with the CAR file:

-* File LogGraph.fex
DEFINE FILE CAR
BSALES/D15=(SALES + 100) ** (1 + SEATS / 8);
END
GRAPH FILE CAR
PRINT BSALES
BY MODEL
ON GRAPH SET LOOKGRAPH HBAR
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH SET BARNUMB OFF
ON GRAPH SET 3D OFF
ON GRAPH SET VZERO ON
ON GRAPH SET GRID ON
ON GRAPH PCHOLD FORMAT PNG
ON GRAPH SET GRAPHSTYLE *
setMarkerDisplay(true);
setConnectLineMarkers(false);
setConnectScatterMarkers(false);
setO1LabelDisplay(true);
setO1AxisSide(0);
setO1MajorGridDisplay(true);
setO1MajorGridStyle(0);
setO1MinorGridDisplay(false);
setAxisAssignment(0,0);
setSeriesType(0,1);
setY1LabelDisplay(true);
-* Log Scale
setY1LogScale(true);
setY1AxisSide(0);
setY1MajorGridDisplay(true);
setY1MajorGridStyle(0);
-* Minor Grid to show Log scale
setY1MinorGridDisplay(true);
setTextFormatPreset(getY1Label(),15);
setTextFormatPattern(getY1Label(),"#.##");
-* Alternating Colors * 3
-REPEAT #COLORS FOR &I FROM 1 TO 120 STEP 3;
-SET &J=&I - 1;
-SET &K=&I + 1;
-SET &COL0=IF IMOD(&I,3,'I1') EQ 0 THEN 255 ELSE 127;
-SET &COL1=IF IMOD(&I,3,'I1') EQ 1 THEN 255 ELSE 127;
-SET &COL2=IF IMOD(&I,3,'I1') EQ 2 THEN 255 ELSE 127;
setFillColor(getSeries(&J), new Color(&COL0,&COL1,&COL2));
setFillColor(getSeries(&I), new Color(&COL1,&COL2,&COL0));
setFillColor(getSeries(&K), new Color(&COL2,&COL0,&COL1));
-#COLORS
setPieFeelerTextDisplay(1);
setPieLabelDisplay(0);
setTextFormatPreset(getPieSliceLabel(),1);
setRiserBorderMode(1);
setSeriesDefaultTransparentBorderColor(true);
setUseSeriesBorderDefaults(true);
setLegendDisplay(true);
setFontSizeAbsolute(getY1Title(),true);
setFontSizeAbsolute(getY1Label(),true);
setFontSizeAbsolute(getY2Title(),true);
setFontSizeAbsolute(getY2Label(),true);
setFontSizeAbsolute(getO1Title(),true);
setPlace(true);
ENDSTYLE
ON GRAPH SET STYLE *
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
$
ENDSTYLE
END

This message has been edited. Last edited by: Kathleen Butler,