Hello,

I am not able to figure out how to wrap columns in an Across table I have created and am looking for some pointers. Here is my code:

 TABLE FILE PREV_YEAR_NEW
SUM
	COLVAL AS ''
ACROSS COLID NOPRINT
ACROSS COLTXT AS ''
ACROSS DIMDATEKEYIDTRENDINGDATE NOPRINT
ACROSS TREND_DEC NOPRINT
ACROSS DATECALENDARKEY_YEAR_M AS ''
ACROSS DATECALENDARKEY_MONTH NOPRINT
ACROSS SUMID NOPRINT
ACROSS SUMTXT AS ''
BY HEALTHPLAN AS 'Health Plan'
BY CNT_MEMBER AS 'Current,Population'
TYPE=REPORT,
	COLUMN=HEALTHPLAN,
	WRAP=.85,
$
TYPE=REPORT,
	COLUMN=N2,
	WRAP=.7,
$
TYPE=REPORT,
	ACROSSCOLUMN=P1,
	WRAP=.8,
$
TYPE=REPORT,
	COLUMN=N0,
	WRAP=.25,
$
 

When I tried to build a report in the GUI with multiple across columns, the code said to use "N0" as the column name however that didn't work.

Could someone advise how to wrap the resulting across columns?

Thanks in advance!!

This message has been edited. Last edited by: Brandon Andrathy,

What's your output format?

N0 applies to all ACROSS fields. Does this work for you?

  
TABLE FILE WF_RETAIL
SUM 
     WF_RETAIL.WF_RETAIL_SALES.REVENUE_US
BY  WF_RETAIL.WF_RETAIL_PRODUCT.PRODUCT_CATEGORY
BY  WF_RETAIL.WF_RETAIL_PRODUCT.PRODUCT_SUBCATEG
ACROSS LOWEST WF_RETAIL.WF_RETAIL_VENDOR.VENDOR_NAME
ACROSS WF_RETAIL.WF_RETAIL_PRODUCT.MODEL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = warm,
$
TYPE=REPORT,
     COLUMN=N1,
     WRAP=0.750000,
$
TYPE=REPORT,
     COLUMN=N2,
     WRAP=0.500000,
$
TYPE=REPORT,
     COLUMN=N0,
     WRAP=0.250000,
$
ENDSTYLE
END

This message has been edited. Last edited by: BabakNYC,

Oh my bad, PDF

Hey Babak, that doesn't work unfortunately.

Here is my output.



I'd like to Wrap each "SUMTXT" column that says RAF Score which should either be Column = N8 or ACROSSCOLUMN = N8. Ultimately I want to just wrap each Across column in a pdf so that the column width is smaller. However, when I try Column = N1 or Column = N2, etc. That doesn't work.

SQUEEZE, not WRAP, for ADOBE/PDF - well-known caveat...

I tried this:

TYPE=REPORT,
COLUMN=N0,
SQUEEZE=0.250000,
$

However it didn't work. Something is telling me I am referencing the column wrongly?

I think you'll need SQUEEZE and WRAP like this:

  
TABLE FILE WF_RETAIL
SUM 
     WF_RETAIL.WF_RETAIL_SALES.REVENUE_US
BY  WF_RETAIL.WF_RETAIL_PRODUCT.PRODUCT_CATEGORY
BY  WF_RETAIL.WF_RETAIL_PRODUCT.PRODUCT_SUBCATEG
ACROSS LOWEST WF_RETAIL.WF_RETAIL_VENDOR.VENDOR_NAME
ACROSS WF_RETAIL.WF_RETAIL_PRODUCT.MODEL
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = warm,
$
TYPE=REPORT,
     COLUMN=N1,
     WRAP=0.750000,
$
TYPE=REPORT,
     COLUMN=N2,
     WRAP=0.750000,
$
TYPE=REPORT,
WRAP=0.30,
SQUEEZE=ON,
$ 
ENDSTYLE
END

That unfortunately doesn't work. Across columns are still the same width and aren't budging.

I figured it out.

This worked for me

TYPE=REPORT,
ACROSSCOLUMN=P1,
WRAP=.4,
$

I want to also point out that having a global

 TYPE=REPORT,
        SQUEEZE=ON,
        WRAP=.25
 

Also is a part of the solution for what I was trying to do. So stoked to get little things like this to work . Thanks for the assistance in brainstorming!