Hello everyone. I have researched the site for a solution to my problem and found Case: 20442045 to be somewhat helpful but can't get it to work with my report because I am placing fields 'over' other fields. Placement of my report fields is all out of wack. Here's a sample of what my report should look like.

ZONE: 11 12 TOTAL
JAN 2009 ORDER 4069 2973 7042
RECVD 4050 2961 7011
DIFF 19 12 31
%RECV 99% 99% 99%

1) I'm selecting criteria from my detail table and the output is:

SUM ORDER# RECVD# DIFF#
BY DELVMONTH
BY DELIVMO
BY ZONE
ON TABLE HOLD AS SUMMARY

2) I'm doing a define on my Summary table as follows:

DEFINE FILE SUMMARY
REC%/D5.1% = (RECVD#/ORDER#)*100;
END

3) And my final step is:
TABLE FILE SUMMARY
SUM ORDER#
OVER RECVD#
OVER DIFF#
OVER REC%
BY DELVMONTH NOPRINT
BY DELIVMO
ACROSS ZONE
HEADING
"<30>PAGE<+0> "<30>" "
" "
ON TABLE ROW-TOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,GRID=OFF,FONT='ARIAL',SIZE=6,COLOR='BLACK',BACKCOLOR='NONE',STYLE=NORMAL,$
END


Output looks great except for the percentage in the TOTAL column. I wasn't able to find a solution that works with 'over'. Thanks for your help! Timpy

This message has been edited. Last edited by: Kerry,

Web Focus Developer Studio Release 7.6.1 Output formats include Excel, PDF, HTML, XML.

Try the following code:

 
FILEDEF MAS DISK MYMASTER.MAS
FILEDEF DATA DISK MYDATA.FTM
FILEDEF MYMASTER DISK MYDATA.FTM
-RUN

-WRITE MAS FILENAME=MYMAS, SUFFIX=FIX
-WRITE MAS SEGNAME=MYMASTER
-WRITE MAS FIELDNAME=ORDER#   , FORMAT=I6, ACTUAL=A6, $
-WRITE MAS FIELDNAME=RECVD#   , FORMAT=I6, ACTUAL=A6, $
-WRITE MAS FIELDNAME=DELVMONTH, FORMAT=A6, ACTUAL=A6, $
-WRITE MAS FIELDNAME=DELIVMO  , FORMAT=A8, ACTUAL=A8, $
-WRITE MAS FIELDNAME=ZONE     , FORMAT=A6, ACTUAL=A6, $

-WRITE DATA   4069  4050012009JAN 2009    11
-WRITE DATA   2973  2873012009JAN 2009    12
-WRITE DATA   7042  6523012009JAN 2009    13

DEFINE FILE MYMASTER
DIFF#/I6 = ORDER# - RECVD#;
END

TABLE FILE MYMASTER
SUM ORDER# RECVD# DIFF#
BY DELVMONTH
BY DELIVMO
BY ZONE
ON TABLE HOLD AS SUMMARY
END

DEFINE FILE SUMMARY
TZONE/A6 = 'TOTAL';
END

TABLE FILE SUMMARY
SUM ORDER#
    RECVD#
    DIFF#
    COMPUTE REC%/D5.1 = (RECVD#/ORDER#)*100;
BY  DELVMONTH NOPRINT
BY  DELIVMO
BY  TZONE AS ZONE
ON  TABLE SET HOLDLIST PRINTONLY
ON  TABLE SET ASNAMES ON
ON  TABLE HOLD AS MYHOLD FORMAT ALPHA
END

FILEDEF MYHOLD DISK MYHOLD.FTM (APPEND

DEFINE FILE SUMMARY
REC%/D5.1% = (RECVD#/ORDER#)*100;
END

TABLE FILE SUMMARY
SUM ORDER#
    RECVD#
    DIFF#
    REC%
BY  DELVMONTH NOPRINT
BY  DELIVMO
BY  ZONE
ON  TABLE SET HOLDLIST PRINTONLY
ON  TABLE SET ASNAMES ON
ON  TABLE HOLD AS MYHOLD FORMAT ALPHA
END
-RUN

TABLE FILE MYHOLD
SUM  ORDER#
OVER RECVD#
OVER DIFF#
OVER REC%
BY   DELIVMO
ACROSS  ZONE
HEADING
"<30><80>PAGE<+0> "
"<30><80><90>"
" "
-*ON TABLE PCHOLD FORMAT PDF
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
UNITS=IN,
SQUEEZE=ON,
ORIENTATION=PORTRAIT,
$
TYPE=REPORT,GRID=OFF,FONT='ARIAL',SIZE=6,COLOR='BLACK',BACKCOLOR='NONE',STYLE=NORMAL,$
END
 

Please note that this will only work right if the field ZONE has the exact same format as the TZONE field.
If that's the case (as it is in the above code) it will give you the correct output, I think.

Hope this helps ...