All,
I have a graph will drill downs, that I would very much like to FTP via report caster.
I have used:
ON GRAPH PCHOLD FORMAT HTML
to send as HTML, but this does not work.
If I run the graph, save it as *.mht directly where I want it, the drill downs are in tact.
Is this possible to do, or am I beating my head against a wall?
If so, is there a way to easily convert a graph into an active report?
Thanks,
Kathryn

This message has been edited. Last edited by: Kerry,

I don't think your drilldown problems are due to your output format.
See if the hyperlinks for the drilldowns are pointing to your webfocus reporting server.
If they are not then FOCEXURL needs to be properly set.
Read this post Report Caster Drilldowns using MRE Development.
I had an issue with drilldowns in Report Caster a while back and susannah helped me.
Also, this article by Susan Trommer Drilling Down to a Managed Reporting Procedure From a ReportCaster Distributed Report was very useful.

There are also additional coding and configuration issues with using graphics in your ReportCaster output. I would recommend going back to your ReportCaster documentation and review both the topics about graphics and drilldowns.

Thanks guys,
However, once I put the SET FOCEXURL in, I got a java error. I then put in the SET GRAPHSERVURL, and now I am getting a restricted site. Not sure what is going on. Spoke with the infrastucture guy, and it should not be doing that.
Thanks,
Kathryn

I think you are getting a java error because the way a graph report is ftped through Report Caster.
The path of the codepase property for the APPLET path is relative and not absolute.

<APPLET id="graph" name=graph codebase=/ibi_html/javaassist archive=IBINewTDGChartApplet.jar code=ibi.applet.graph.IBINewTDGChartApplet.class width=760 height=400>

Instead of 

<APPLET id="graph" name=graph codebase=http://servername:serverport/ibi_html/javaassist archive=IBINewTDGChartApplet.jar code=ibi.applet.graph.IBINewTDGChartApplet.class width=760 height=400>

I don't use Report Caster Graphs so I have never ran into this issue.
To resolve the issue I basically edited the APPLET tag of the generated report.

  
-SET &ECHO = ALL;

-* WebFocus environment variables
-SET &SERVER_NAME = 'server_name';
-SET &SERVER_PORT = '9080';
-SET &MRE_DOMAIN  = 'q8fj1wne';
-SET &SNAME_LEN   = &SERVER_NAME.LENGTH;
-SET &SPORT_LEN   = &SERVER_PORT.LENGTH;

-* Tweaking needed for MRE drilldowns
-SET &FOCEXURL='http://' | &SERVER_NAME | ':' | &SERVER_PORT;
-SET &FOCEXURL=&FOCEXURL | '/ibi_apps/WFServlet?IBIF_webapp=/ibi_apps' | '&';
-SET &FOCEXURL=&FOCEXURL | 'IBIC_server=EDASERVE' | '&';
-SET &FOCEXURL=&FOCEXURL | 'IBIWF_msgviewer=OFF' | '&';
-SET &FOCEXURL=&FOCEXURL | 'IBIMR_drill=X,' | &MRE_DOMAIN | '/' | &MRE_DOMAIN | '.htm' | '&';
SET FOCEXURL='&FOCEXURL'

-* Will cause the fold file HGRAPH to be named HGRAPH.FTM
APP FI HGRAPH DISK HGRAPH.FTM
-RUN

-* Run the report and hold it as HGRAPH format HTML
GRAPH FILE CAR
SUM SALES
ACROSS COUNTRY
ON GRAPH SET LOOKGRAPH VBAR
ON GRAPH SET GRAPHEDIT SERVER
ON GRAPH SET BARNUMB OFF
ON GRAPH SET 3D OFF
ON GRAPH SET VZERO ON
ON GRAPH SET GRID ON
ON GRAPH HOLD AS HGRAPH FORMAT HTML
ON GRAPH SET GRAPHSTYLE *
setMarkerDisplay(true);
setConnectLineMarkers(false);
setConnectScatterMarkers(false);
setO1LabelDisplay(true);
setO1AxisSide(0);
setO1MajorGridDisplay(true);
setO1MajorGridStyle(0);
setO1MinorGridDisplay(false);
setAxisAssignment(0,0);
setSeriesType(0,1);
setY1LabelDisplay(true);
setY1AxisSide(0);
setY1MajorGridDisplay(true);
setY1MajorGridStyle(0);
setY1MinorGridDisplay(false);
setTextFormatPreset(getY1Label(),-1);
setTextFormatPattern(getY1Label(),"#.##");
setPieFeelerTextDisplay(1);
setPieLabelDisplay(0);
setTextFormatPreset(getPieSliceLabel(),1);
setRiserBorderMode(1);
setSeriesDefaultTransparentBorderColor(true);
setUseSeriesBorderDefaults(true);
setLegendDisplay(true);
setFontSizeAbsolute(getY1Title(),true);
setFontSizeAbsolute(getY1Label(),true);
setFontSizeAbsolute(getY2Title(),true);
setFontSizeAbsolute(getY2Label(),true);
setFontSizeAbsolute(getO1Title(),true);
setPlace(true);
ENDSTYLE
ON GRAPH SET STYLE *
     SQUEEZE=ON,
     ORIENTATION=PORTRAIT,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
$
TYPE=DATA,
     ACROSSCOLUMN=N1,
     FOCEXEC=app/graph_drill.fex(COUNTRY=A1),
$
ENDSTYLE
END
-RUN

-* Create the master file that will use HGRAPH.FTM which is the html code for our report
APP FI MAS_FILE DISK HGRAPH.MAS
-RUN
-WRITE MAS_FILE FILE=HGRAPH, SUFFIX=FIX, $
-WRITE MAS_FILE SEGNAME=SEG1, SEGTYPE=S0, $
-WRITE MAS_FILE FIELD=CODE,  ALIAS=CODE,  USAGE=A250,    ACTUAL=A250, $

-* Alter the APPLET tag so instead of having the relative path /ibi_html/javassist
-* it has the full path http://WFServerName:WFServerPo.../ibi_html/javaassist
DEFINE FILE HGRAPH
CODE/A250 = IF CODE LIKE '<APPLET%' THEN STRREP (250, CODE, 31, ' codebase=/ibi_html/javaassist ', 53, ' codebase=http://server_name:9080/ibi_html/javaassist ', 250, 'A250') ELSE CODE;
END

-* Print the new version of the report and hold as ALPHA so there are no html tags added to the report
TABLE FILE HGRAPH
PRINT
     CODE
ON TABLE HOLD AS HOLD1 FORMAT ALPHA
END

-* Display the report using -HTMLFORM and IBI bang variable
-HTMLFORM BEGIN
!IBI.FIL.HOLD1;
-HTMLFORM END

Look at the source code of the report after it is ftped.
All urls should point to your webfocus reporting server.

Someone probably has a better technique.
So please post if you have one.

Thanks Max,
I will take a look at this.