I am having trouble with the positioning of the image. Fields are overlaying image. I have tried different X & Y positions but nothing seams to work. What am I doing wrong???
My Code
TABLE FILE EMPLOYEE
BY LAST_NAME NOPRINT
BY FIRST_NAME NOPRINT

ON FIRST_NAME PAGE-BREAK
ON TABLE SUBHEAD
""
HEADING
""""ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SET STYLE *
UNITS=IN,
PAGESIZE='Letter',
LEFTMARGIN=0.250000,
TOPMARGIN=0.500000,
SQUEEZE=ON,
ORIENTATION=LANDSCAPE,
$
PAGEMATRIX=(3 5),
ELEMENT=(4.000000 1.000000),
GUTTER=(0.180556 0.000000),
MATRIXORDER=VERTICAL,
$
LABELPROMPT=OFF,
$
TYPE=REPORT,
GRID=OFF,
FONT='ARIAL',
SIZE=9,
$
TYPE=TABHEADING,
IMAGE=app/ppmoh.gif,
POSITION=(+0.000000 +0.000000),
$
TYPE=HEADING,
LINE=1,
BACKCOLOR='SILVER',
STYLE=BOLD,
$
TYPE=SUBHEAD,
BACKCOLOR='GRAY',
STYLE=BOLD,
$
ENDSTYLE
END

This message has been edited. Last edited by: Kerry,

Developers Studio 7.6.5

When you post code, you should put it inside of

[code]

[/code]

markers - that way none of it disappears.

What is it you are trying to do with that image? Is it supposed to appear on each of the labels? If so it should be in the TYPE=HEADING, not TYPE=TABHEADING. Also, FOCUS does not reserve a spot for the image to appear. You have to do that yourself by inserting blank lines or spot markers to move your fields out of the way of the image. Otherwise it just appears in the exact location you specify without regard to whether or not any other components (heading, fields, etc.) appear there as well.

What is the issue? You say you are having a problem but you do not specify what the issue is.

Yes Mickey, problem was specified (fields are overlaying the image or vice versa).
The following example uses the same logic as above, only now with an image I do have:

TABLE FILE EMPLOYEE
BY LAST_NAME NOPRINT
BY FIRST_NAME NOPRINT
ON FIRST_NAME PAGE-BREAK
HEADING
"</5"
"<FIRST_NAME <LAST_NAME"
"<ADDRESS_LN1"
"<ADDRESS_LN2"
"<ADDRESS_LN3"
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
     UNITS=IN,
     PAGESIZE='Letter',
     LEFTMARGIN=0.250000,
     TOPMARGIN=0.500000,
     SQUEEZE=ON,
     ORIENTATION=LANDSCAPE,
     PAGEMATRIX=(3 5),
     ELEMENT=(3.700000 2.000000),
     GUTTER=(0.180556 0.000000),
     MATRIXORDER=VERTICAL,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=HEADING,
     IMAGE=smplogo1.gif,
     POSITION=(+0.0000 +0.0000),
$
TYPE=HEADING,
     LINE=7,
     BACKCOLOR='SILVER',
     STYLE=BOLD,
$
ENDSTYLE
END

Main differences here:
1. You have to allocate space for the image by adding heading lines, as per Darin.
2. You also have to provide more vertical space for the matrix cells.
And with this code you get a nice matrix of data that has no more overlaps.
Of course, you'll have to play around a bit with the values for your own situation.

Something like this:

TYPE=HEADING, IMAGE=MYIMAGE.GIF, POSITION(0.0 0.1),$

will give you this (the image in the upper left corner).

Play around with the values for POSTION and the placement of you heading text (I used HEADING CENTER).

See you at Summit

I only want to the image to appear at the top of the page, not for every record. I tried several of the suggestion and my data is still overlaying the image.

TABLE FILE EMPLOYEE
-*TYPE=HEADING,LINE=2,STYLE=BOLD,BACKCOLOR='SILVER', $
BY LAST_NAME NOPRINT
BY FIRST_NAME NOPRINT
     
ON FIRST_NAME PAGE-BREAK
ON TABLE SUBHEAD
""
HEADING
"<FIRST_NAME <LAST_NAME"
"<ADDRESS_LN1"
"<ADDRESS_LN2"
"<ADDRESS_LN3"
ON TABLE SET PAGE-NUM OFF 
ON TABLE NOTOTAL
ON TABLE SET STYLE *
     UNITS=IN,
     PAGESIZE='Letter',
     LEFTMARGIN=0.250000,
     TOPMARGIN=0.500000,
     SQUEEZE=ON,
     ORIENTATION=LANDSCAPE,
$
     PAGEMATRIX=(3 5),
      ELEMENT=(4.000000 1.000000),
      GUTTER=(0.180556 0.000000),
      MATRIXORDER=VERTICAL,
 $
     LABELPROMPT=OFF,
 $
TYPE=REPORT,
     GRID=OFF,
     FONT='ARIAL',
     SIZE=9,
$
TYPE=TABHEADING,
     IMAGE=app/ppmoh.gif,
     POSITION=(+0.000000 +0.000000),
$
TYPE=HEADING,
     LINE=1,
     BACKCOLOR='SILVER',
     STYLE=BOLD,
$
TYPE=SUBHEAD,
     BACKCOLOR='GRAY',
     STYLE=BOLD,
$
ENDSTYLE
ON TABLE PCHOLD FORMAT PDF
END

I need pdf output for this

This message has been edited. Last edited by: baxj89,

The code that you last posted puts an image once on the top left corner of the page, with the first employee's data printing over the image.

You can have the text of your report starting lower by increasing the number of blank lines in the report heading:

ON TABLE SUBHEAD
" "
" "
" "
" "
" "

This message has been edited. Last edited by: Francis Mariani,

quote:

" "
" "
" "
" "
" "

That takes care of the first column but column 2 and 3 still overlay the image.

Do you have an image that goes right across the page?

Set the top margin for the actual data. Position the image above the top margin by using negative positioning:

-* baxj89001.fex
TABLE FILE EMPLOYEE
BY LAST_NAME NOPRINT
BY FIRST_NAME NOPRINT

ON FIRST_NAME PAGE-BREAK
ON TABLE SUBHEAD
""

HEADING
"<FIRST_NAME <LAST_NAME"
"<ADDRESS_LN1"
"<ADDRESS_LN2"
"<ADDRESS_LN3"

ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SET STYLE *
UNITS=IN, PAGESIZE='Letter', LEFTMARGIN=0.250000, TOPMARGIN=1.250000, SQUEEZE=ON, ORIENTATION=LANDSCAPE, $

PAGEMATRIX=(3 5), ELEMENT=(4.0 1.0), GUTTER=(0.180556 0.0), MATRIXORDER=VERTICAL, $
LABELPROMPT=OFF, $

TYPE=REPORT, GRID=OFF, FONT='ARIAL', SIZE=9, $
TYPE=TABHEADING, IMAGE=ias_logo.jpg, POSITION=(+0.0 -1.0), $
TYPE=TABHEADING, FONT='ARIAL', SIZE=1, $
TYPE=HEADING, LINE=1, BACKCOLOR='SILVER', STYLE=BOLD, $
TYPE=SUBHEAD, BACKCOLOR='GRAY', STYLE=BOLD, $
ENDSTYLE

ON TABLE PCHOLD FORMAT PDF
END
-RUN

Ideally I'd like to remove the report heading (ON TABLE SUBHEAD) because the first employee in the matrix is positioned one line below the others in the first matrix row, but removing the report heading removes the image as well. One solution would be to make the font size of the report heading (TABHEADING) very small - font size 1.

This message has been edited. Last edited by: Francis Mariani,

I applied the suggestions you made and it works great. If you would not mind I have a couple more questions. Is it possible to repeat the image on each page? & Is it possible to put a title between the image and the data? or if you could point me to the documentation on my questions.

Unfortunately, I don't think there's any documentation about applying images in a Matrix (Labels) type report, you could play around or open a case with IBI Tech Support.

There's the new PDF Composer tool in DevStudio that *may* help, but I'd be surprised it works with Matrix type reports.

Here you go, using a counter (3 x 5 = 15), HEADING instead of TABHEADING and WHEN:

-* baxj89002.fex

-SET &ECHO=ALL;

TABLE FILE EMPDATA
PRINT
COMPUTE COUNTER/D5 = IF COUNTER EQ 15 THEN 1 ELSE COUNTER + 1; NOPRINT

BY LASTNAME NOPRINT
BY FIRSTNAME NOPRINT

ON FIRSTNAME PAGE-BREAK

HEADING
"<FIRSTNAME <LASTNAME"
"<TITLE"
"<DIV"
"<DEPT"

ON TABLE SET PAGE-NUM OFF
ON TABLE NOTOTAL
ON TABLE SET STYLE *
UNITS=IN, PAGESIZE='Letter', LEFTMARGIN=0.250000, TOPMARGIN=1.250000, SQUEEZE=ON, ORIENTATION=LANDSCAPE, $

PAGEMATRIX=(3 5), ELEMENT=(4.0 1.0), GUTTER=(0.180556 0.0), MATRIXORDER=VERTICAL, $
LABELPROMPT=OFF, $

TYPE=REPORT, GRID=OFF, FONT='ARIAL', SIZE=9, $
TYPE=HEADING, IMAGE=ias_logo.jpg, POSITION=(+0.0 -1.0), WHEN=COUNTER EQ 1, $
TYPE=HEADING, LINE=1, BACKCOLOR='SILVER', STYLE=BOLD, $
TYPE=SUBHEAD, BACKCOLOR='GRAY', STYLE=BOLD, $
ENDSTYLE

ON TABLE PCHOLD FORMAT PDF
END
-RUN

You don't mention the release that you are on (of did I miss that?). I'm surprised no-one has picked that up!

Look up the document composer syntax as that will give you the total control that you strive for.

T (At Summit 09 )

Tony, will the Document Composer syntax handle the PAGEMATRIX syntax? Multiple "pages" generated by PAGE-BREAK on the same physical page?

quote:

Originally posted by Tony A:
You don't mention the release that you are on (of did I miss that?). I'm surprised no-one has picked that up!

Look up the document composer syntax as that will give you the total control that you strive for.

T (At Summit 09 )

I updated my profile. Is it ok know?

Yes

quote:

will the Document Composer syntax handle the PAGEMATRIX syntax

No, but the composer is so much more than that, you can set overflow page options, boxes, lines, text, pictures. The only requirement is that each page section has to contain a report output section. Soooooooo simple it's unbelievable. I now use it in preference to the old compound syntax and admittedly I don't generally use PAGEMATRIX but I do find composer suits all of our end user requirements.

T at Nashville

p.s. I am glad to see that someones holding the fort - shame you couldn't make it - hope everything is OK.

quote:

unbelievable

that it works flawlessly!

We're fine here while you're having fun in the sun...

Forecast today is 50% chance of rain and thunderstorms I'm off back to Texas tomorrow where there's some sun!!

T

quote:

document composer syntax

How do you access the document composer. I am not seeing it in the drop down box create in??????

It's called "Composer (Layout)" in the Dev Studio New Procedure dialog box.

Tony suggests writing code that is normally generated by the Composer tool, but it certainly is a good idea to try doing it with the GUI - this is new to v7.6.

COMPOUND LAYOUT PCHOLD FORMAT PDF
...
SECTION=section1, LAYOUT=ON, METADATA='0.5^0.5^0.5^0.5', MERGE=OFF, ORIENTATION=PORTRAIT, PAGESIZE=Letter, $
COMPONENT='report1', TEXT='report1', TOC-LEVEL=2,...
...
SET COMPONENT='report1'
...
SET COMPONENT='report2'
...
COMPOUND END

I have version 7.6.5 and I am not seeing it in the drop down menu. Is it something extra you have to pay for????

In 7.6.5, it is still called the PDF Layout Painter. You must access it as a 'new' program to see it in the dropdown or use the posts above as reference as code it by hand.

Is there any examples or documentation on the pdf layout painter on how to use the GUI?? I found very little in the help index fo dev studio.

The documentation is in the "Creating Reports with Graphical Tools" manual. This is how I learned to use the tool, by doing the examples.