[SOLVED] (FOC258) FIELDNAME OR COMPUTATIONAL ELEMENT NOT RECOGNIZED
Hi everyone!
I get this error that I don't undertand. The code worked in the previous version of the report but now gives this error: (FOC258) FIELDNAME OR COMPUTATIONAL ELEMENT NOT RECOGNIZED: &DIVID
Previous Version:
-SET &DIVID='FOC_NONE';
...
TABLE FILE BIFSTAP
PRINT
BAL
STACDE
UOMTYP
PERCDE
WHERE UNINUM EQ &UNINUM
WHERE (PERCDE EQ &PERCDE) OR (PERCDE EQ &PRVPERCDE)
WHERE (STACDE EQ &STACDE_MSFSWE AND (UOMTYP EQ '&XSW' OR UOMTYP EQ '&TON'))
WHERE VERKEY = 'STB' OR VERKEY = 'SBU'
WHERE DIVID EQ &DIVID
ON TABLE HOLD AS HOLD_DATA_SET_GLSTATR2 FORMAT FOCUS
END
New version:
-SET &DIVID='FOC_NONE';
...
-SET &WHERE_DIV = IF &UNINUM EQ 114 THEN 'DIVNUM = 5'
- ELSE IF &UNINUM EQ 37 THEN 'DIVNUM = 6'
- ELSE 'DIVID EQ &DIVID';
TABLE FILE BIFSTAP
PRINT
BAL
STACDE
UOMTYP
PERCDE
WHERE UNINUM EQ &UNINUM
WHERE (PERCDE EQ &PERCDE) OR (PERCDE EQ &PRVPERCDE)
WHERE (STACDE EQ &STACDE_MSFSWE AND (UOMTYP EQ '&XSW' OR UOMTYP EQ '&TON'))
WHERE VERKEY = 'STB' OR VERKEY = 'SBU'
-*WHERE DIVID EQ &DIVID
WHERE &WHERE_DIV;
ON TABLE HOLD AS HOLD_DATA_SET_GLSTATR2 FORMAT FOCUS
END
Can anybody explain to me what's happening here?This message has been edited. Last edited by: Kerry,
__________________________ Dev: WebFOCUS 7.6.8 OS: Windows XP Output: *ALL
March 16, 2012, 11:14 AM
Danny-SRL
Methinks:
-SET &DIVID='FOC_NONE';
...
-SET &WHERE_DIV = IF &UNINUM EQ 114 THEN 'DIVNUM EQ 5'
- ELSE IF &UNINUM EQ 37 THEN 'DIVNUM EQ 6'
- ELSE 'DIVID EQ &DIVID.EVAL';
TABLE FILE BIFSTAP
PRINT
BAL
STACDE
UOMTYP
PERCDE
WHERE UNINUM EQ &UNINUM
WHERE (PERCDE EQ &PERCDE) OR (PERCDE EQ &PRVPERCDE)
WHERE (STACDE EQ &STACDE_MSFSWE AND (UOMTYP EQ '&XSW' OR UOMTYP EQ '&TON'))
WHERE VERKEY EQ 'STB' OR VERKEY EQ 'SBU'
-*WHERE DIVID EQ &DIVID
WHERE &WHERE_DIV;
ON TABLE HOLD AS HOLD_DATA_SET_GLSTATR2 FORMAT FOCUS
END
You have to use the .EVAL function in the -SET command, otherwise the &variable will not be replaced by its value. Also, do not use the = sign but the EQ operation in a WHERE statement. I know that WF is forgiving but this might not always by the case...
Daniel In Focus since 1982 wf 8.202M/Win10/IIS/SSA - WrapApp Front End for WF
March 16, 2012, 11:24 AM
Fanfanprovok
Thanks for the quick reply!
And the best of it all, it worked!!
__________________________ Dev: WebFOCUS 7.6.8 OS: Windows XP Output: *ALL