I need to transpose some data.
I have data in this format that goes out to 280 columns:

P_W P W Week_num Cur_week 1 2 3 4
01-1 01 1 1 16 50 2 8 60
01-2 01 2 2 16 40 5 5 50
01-3 01 3 3 16 20 5 5 30
01-4 01 4 4 16 10 5 5 20
02-1 02 1 5 16 10 5 5 20

I need it in this format:
P_W 01-1 01-2 01-3 01-4 02-1
P 01 01 01 01 02
W 1 2 3 4 5
Cur_week 16 16 16 16 16
1 50 40 20 10 10
2 2 5 5 5 5
3 8 5 5 5 5
4 60 50 30 20 20

Thanks!

This message has been edited. Last edited by: Kerry,

Try OVER

FIELD1 OVER FIELD2

I think thier is a limit on the number of Over commands you can use.

Macgyver is always an option.

Todd,

Using Waz suggestion of MacGyver, see if this works for you:

  
-* File test_121611.fex
TABLE FILE CAR
PRINT
COMPUTE P_W/A4      = ' ';
COMPUTE P1/A2       = ' ';
COMPUTE W1/A1       = ' ';
COMPUTE Week_Num/A1 = ' ';
COMPUTE Cur_Week/A2 = ' ';
COMPUTE F1/A2       = ' ';
COMPUTE F2/A1       = ' ';
COMPUTE F3/A1       = ' ';
COMPUTE F4/A2       = ' ';
COMPUTE SP/A1       = 'X';
COMPUTE REC/I5      = 0;
BY COUNTRY NOPRINT
IF RECORDLIMIT EQ 1
ON TABLE HOLD AS TODDJ FORMAT ALPHA
END
-RUN

-WRITE TODDJ 01-1011116502860X    1
-WRITE TODDJ 01-2012216405550X    2
-WRITE TODDJ 01-3013316205530X    3
-WRITE TODDJ 01-4014416105520X    4
-WRITE TODDJ 02-1021516105520X    5
-CLOSE TODDJ
-*
TABLE FILE TODDJ
PRINT *
ON TABLE HOLD AS TODDJ2
END
-RUN

-SET &RECS   = &LINES;
-SET &OCCURS = 9;
-* build macgyver MFD
FILEDEF MCMAS DISK mcgyv.mas
-RUN
-WRITE MCMAS FILENAME=mcgyv, SUFFIX=FIX
-WRITE MCMAS   SEGMENT=ONE, SEGTYPE = S0,$
-WRITE MCMAS     FIELDNAME=SP,USAGE=A1,ACTUAL=A1,$
-WRITE MCMAS   SEGMENT=TWO, SEGTYPE=S0,PARENT=ONE,OCCURS=&OCCURS ,$
-WRITE MCMAS     FIELDNAME=CHAR1, USAGE=A1,ACTUAL=A1,$
-WRITE MCMAS     FIELDNAME=CTR, ALIAS=ORDER,USAGE=I4,ACTUAL=I4,$
-*
FILEDEF MCGYV DISK mcbyv.ftm
-RUN
-* Control=X: used as Join cross reference target field
-WRITE MCGYV XABCDEFGHI
-RUN

JOIN SP IN TODDJ TO SP IN MCGYV AS J1
-RUN
DEFINE FILE TODDJ
COL1/A8 = DECODE CTR(1 'P_W'
                     2 'P'
                     3 'W'
                     4 'Week_Num'
                     5 'Cur_Week'
                     6 '1'
                     7 '2'
                     8 '3'
                     9 '4'
                     ELSE ' ');
-REPEAT ENDDEFLP FOR CT FROM 2 TO &RECS
COL&CT /A4 =
     IF (CTR EQ 1) AND (REC EQ &CT ) THEN P_W
ELSE IF (CTR EQ 2) AND (REC EQ &CT ) THEN P1
ELSE IF (CTR EQ 3) AND (REC EQ &CT ) THEN W1
ELSE IF (CTR EQ 4) AND (REC EQ &CT ) THEN Week_Num
ELSE IF (CTR EQ 5) AND (REC EQ &CT ) THEN Cur_Week
ELSE IF (CTR EQ 6) AND (REC EQ &CT ) THEN F1
ELSE IF (CTR EQ 7) AND (REC EQ &CT ) THEN F2
ELSE IF (CTR EQ 8) AND (REC EQ &CT ) THEN F3
ELSE IF (CTR EQ 9) AND (REC EQ &CT ) THEN F4
ELSE ' ';
-ENDDEFLP
END

TABLE FILE TODDJ
SUM
MAX.COL1
-REPEAT ENDREPLP FOR RT FROM 2 TO &RECS
MAX.COL&RT
-ENDREPLP
BY CTR NOPRINT
END

ACROSS?

What do you mean by:

quote:

I have data in this format that goes out to 280 columns

280 fields in the MASTER?
And all not the same format?
And you want to show them down the page?