Hi!!

I wanna do the following and I do a lot of tries but it has been impossible:

Example:

I have the next code:
…
TABLE FILE SQLOUT
NAME
COMPUTE PAG/P20CS = PAGE; NOPRINT
COMPUTE VIS1/A7 = IF (IMOD(PAG,2,'I2') NE 0) THEN ' ' ELSE 'NOPRINT'; NOPRINT
COMPUTE VIS2/A7 = IF (IMOD(PAG,2,'I2') EQ 0) THEN ' ' ELSE 'NOPRINT'; NOPRINT
IMP1 AS ‘Value1’
IMP2 AS ‘Value2’
ON TABLE PCHOLD FORMAT PDF
…
…
END

What I want to do is to print NAME in both pages, IMP1 in odd pages and IMP2 in even pages. That is:

Page 1:
NAME IMP1
Xxxxx 25
Aaaaaa 56

Page 2:
NAME IMP2
Xxxxx 57
Aaaaaa 89

PAGE gives me the page number.
The field VIS1 or VIS2 gives me the information whether I need to print or not. But if I put IMP1 AS ‘Value1’ VIS1, logically VIS1 appears like another field because it isn’t a variable.

I have also tried to define the variable VIS1 in the DEFINE but the field PAGE takes always the first value, that is, the value 1 and I don’t want that because PAGE has different values. Like that:

DEFINE SQLOUT
PAG/P20CS = PAGE; NOPRINT
-SET &VIS1 = IF (IMOD(PAG,2,'I2') NE 0) THEN ' ' ELSE 'NOPRINT';
END

Any ideas?

Thank you!!!

This message has been edited. Last edited by: Kerry,

I'm not sure what you are trying to do. Is this example even close?

TABLE FILE CAR
PRINT SALES
COMPUTE PAG/P2CS = TABPAGENO; 
COMPUTE VIS/A7 = IF (IMOD(PAG,2,'I2') NE 0) THEN 'IMP1 ' ELSE 'IMP2'; BY COUNTRY PAGE-BREAK
BY CAR 
BY MODEL
BY BODYTYPE
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET STYLE *
ORIENTATION=LANDSCAPE,$
ENDSTYLE
END

Your approach is wrong, you cannot conditionally suppress a column with NOPRINT
Because NOPRINT can not be dynamic.

Make your data and heading dynamic and display your headings in a subhead

 
TABLE FILE CAR
PRINT 
     MODEL AS ''
     COMPUTE PAG/P2CS = TABPAGENO; NOPRINT
     COMPUTE VIS_DATA/A50 = IF ( IMOD(PAG, 2, 'I2') NE 0 ) THEN MODEL ELSE BODYTYPE;
 AS ''
     COMPUTE VIS_HEAD/A50 = IF ( IMOD(PAG, 2, 'I2') NE 0 ) THEN 'MODEL' ELSE 'BODYTYPE'; NOPRINT
 AS ''
BY CAR AS ''
     
ON CAR SUBHEAD
"CAR <+0> MODEL <VIS_HEAD"
ON CAR PAGE-BREAK
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
     UNITS=IN,
     SQUEEZE=ON,
     ORIENTATION=LANDSCAPE,
$
TYPE=REPORT,
     GRID=OFF,
     FONT='TIMES NEW ROMAN',
     SIZE=10,
$
TYPE=SUBHEAD,
     BY=1,
     LINE=1,
     OBJECT=TEXT,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=1.08,
$
TYPE=SUBHEAD,
     BY=1,
     LINE=1,
     OBJECT=TEXT,
     ITEM=2,
     JUSTIFY=LEFT,
     WIDTH=2.10,
$
TYPE=SUBHEAD,
     BY=1,
     LINE=1,
     OBJECT=FIELD,
     ITEM=1,
     JUSTIFY=LEFT,
     WIDTH=3.625,
$
ENDSTYLE
END

 

I beleive you could do this with a coordinated compound report.

You would have two reports fitting the two layout requirements and turn coordination (MERGE) on

Thank you JG!!!

I have done as you said and it works perfectly!!

Have i misunderstood? as i can make noprint dynamic..

 
-SET &CHOICE = 'N';
-SET &NOP = IF &CHOICE EQ 'Y' THEN 'NOPRINT' ELSE '';

TABLE FILE CAR 
PRINT CAR MODEL BODYTYPE 
BY COUNTRY '&NOP'
END
 

test by changing the value &CHOICE to 'Y' or 'N' and compare results...

ah i see DM is done before the TABLE Request so yes i see what you mean. The &Var can't be set until the table data has been processed...

That is correct. Anything with the '-' (all Dialogue Manager commands) is executed in the order encountered and before any FOCUS code is run. That is the reason that you can't mix the two (i.e. -SET a variable equal to a field value.)