Visual Basic for Applications has a function that I can use to define a string of blank spaces: Spc(232)

Does WebFOCUS?

This message has been edited. Last edited by: Kerry,

yeah.
DEFINE FILE CAR
SPACES/A30=' ';
END

This is only giving me one space character.

Is there a "SET" command that needs to be included to preserve the space padding?

SET ASNAMES = ON

DEFINE FILE MCPD_TBLZREFFORMNAMES
HEADER1/A23 WITH FORMNAME = 'HDRMC01' | DATECVT(&YYMD, 'I8YYMD', 'A8YYMD') | EDIT(HHMMSS('A8'),'99$:99$:99');
SPACES/A232='';
END

TABLE FILE MCPD_TBLZREFFORMNAMES
PRINT
HEADER1 AS ''
SPACES AS ''

WHERE RECORDLIMIT EQ 1

ON TABLE PCHOLD FORMAT TAB
END

I've created spaces in the past this way.

 SP/A1 = HEXBYT(160, 'A1');
SP02/A2 = SP|SP;
SP05/A05 = SP|SP|SP|SP|SP;
SP10/A10 = SP05|SP05; 

My concern is that I need to space pad a row from 23 characters to 255 characters, so I'm trying to avoid concactinating so many times so that I get the needed 232 space characters.

I also come from some VB development (ASP/VBScript) and let me save you some trouble. stop trying to make Focus into VB. I've frustrated myself to no end trying to replicate some of the design patterns I used to use. I finally had to drink the Kool Aid and do it the WF way. :-)

That said, I recently had to do this same thing (for creating a fixed length record in a data feed), see below.

DEFINE FILE CAR
	PADDED_COUNTRY_TMP/A60  = '                                                  ' || COUNTRY;
	PADDED_COUNTRY_TMP/A60  = RJUST(60,PADDED_COUNTRY_TMP,PADDED_COUNTRY_TMP);
	PADDED_COUNTRY/A50      = SUBSTR(60, PADDED_COUNTRY_TMP, 11, 60, 50, 'A50');
END

TABLE FILE CAR
PRINT
	PADDED_COUNTRY
	ON TABLE PCHOLD FORMAT ALPHA
END

So the premise is to create a 50 character Country field (original is 30). to do this, I use 30 spaces and append the country field. from there, I right justify it and using a substring, get just the rightmost 50 characters. From a VB background, that's just cumbersome (the SUBSTR function alone is combersome)).

Saving it as an alpha should prompt you to save it on your PC and you can use TextPad or something to count the spaces (the web view will not preserve).

I'm not saying the above is the most efficient way to do it, it's just the mindset I've see in my shop and am trying to fit in...

HTH,
- ABT

The output format would make a difference. HTML won't preserve spaces, PDF will, TAB won't. I would try Prarie's or ABT's suggestion.

WebFOCUS Documentation:

 
Reference: FORMAT TAB
Description: 
     Creates an output file in tab-delimited format. The TAB format includes a built-in safety   
feature, which allows embedded quotes within character fields. 

A a second double quote (") is inserted adjacent to the existing one. 

For example, if you input Joe "Smitty" Smith, the output is Joe ""Smitty"" Smith. 
The TAB format also includes the following features: 

    All trailing blanks are stripped from alpha [An] fields. 
    All leading blanks are stripped from numeric [/Dx.y, /Fx.y, /Px.y, and /In] fields. 
    There is a 32K record length limit in the output file. 

A Master File is created when the HOLD command is used to create the output file. 
The Master File behaves exactly as in FORMAT ALPHA, except for the inclusion of double quotes. 

Note: To create a variable-length comma- or tab-delimited HOLD file that differentiates 
between a missing value and a blank string or zero value, 
use the SET NULL=ON command. 

For more information, see the Developing Reporting Applications manual.

Use: For importing data to Windows-based applications such as MS Access and Excel.

Supported with the command: HOLD; SAVE; PCHOLD

Available in: WebFOCUS; Developer Studio; FOCUS. 

SET ASNAMES = ON

DEFINE FILE CAR
SP/A1    = HEXBYT(160, 'A1');
SP02/A2  = SP|SP;
SP05/A05 = SP|SP|SP|SP|SP;
SP10/A10 = SP05|SP05; 
SP20/A20 = SP10|SP10;
XSP1/A230= SP20|SP20|SP20|SP20|SP20|SP20|SP20|SP20|SP20|SP20|SP20|SP05|SP|SP|SP;
HEADER1/A255 WITH COUNTRY = 
'"'| 'HDRMC01' | DATECVT(&YYMD, 'I8YYMD', 'A8YYMD') | EDIT(HHMMSS('A8'),'99$:99$:99') | XSP1 | '"';
END

TABLE FILE CAR
PRINT
HEADER1 AS ''
BY COUNTRY NOPRINT
WHERE RECORDLIMIT EQ 1

ON TABLE PCHOLD FORMAT ALPHA
END
-EXIT

hth

This message has been edited. Last edited by: Tom Flynn,

Thank you. This is working

... or use WF to do the heavy lifting -

-DEFAULT &SPCLEN = 200
-DEFAULT &SPCS   = ''
-REPEAT SPCLOOP &SPCLEN TIMES;
-SET &SPCS = &SPCS | HEXBYT(160, 'A1');
-SPCLOOP
-RUN
DEFINE FILE CAR
  PAD_COUNTRY/A255 = '&SPCS' | COUNTRY;
END
TABLE FILE CAR
PRINT PAD_COUNTRY
   BY COUNTRY
END

Also note that it is better to use chr$(160) (as per Prarie) rather than chr$(32) for the space character, so don't use a conflicting character set.

T

Could the same process be used to add blank spaces to the right side of a field to pad the field?

Best bet for that is the LJUST function. From the manual:

The LJUST function left-justifies a character string within a field. All leading spaces become trailing spaces.

Syntax: How to Left-Justify a Character String
LJUST(length, string, outfield)

FIELD_ID0/A4= CMB_FIELD_ID;
FIELD_ID1/A34= FIELD_ID0 | '                              '; (THIS IS 30 SPACES)

Both defines give me just the 4 character value from CMB_FIELD_ID with no trailing spaces.

CWM,

Yes, just change the define around. But you should also be able to just code without space filling -

DEFINE FILE CAR
  PAD_COUNTRY/A255 = COUNTRY | '&SPCS';
  SPC_COUNTRY/A255 = COUNTRY;
END
TABLE FILE CAR
PRINT SPC_COUNTRY
   BY COUNTRY
ON TABLE SAVE AS TEST FORMAT ALPHA
END

SPC_COUNTRY gives me a 255 character wide string, left justified with trailing spaces.

T

How about using

DEFINE FILE CAR
SPACES/A220 = SUBSTR(10,COUNTRY,-1,1,220,'A220');
NEW_COUNTRY/A230 = COUNTRY | SPACES;
END

TABLE FILE CAR
PRINT
NEW_COUNTRY
SPACES
ON TABLE PCHOLD FORMAT ALPHA
END