Is it possible to put a single column at the right-most end of the output of a series of ACROSS columns?

I'm generating a number of WHERE clauses from a data-file and OR-ing them together using ACROSS and COMPUTE, but I'm kind of stuck getting a semi-colon ( at the end of each line...

My code is similar to:

DEFINE FILE CAR
 SELITEM/A8 = DECODE COUNTRY('FRANCE' 'MODEL' 'ITALY' 'SEATS' ELSE '');
 SELVALS/A15 = DECODE COUNTRY('FRANCE' 'EQ ''504 4 DOOR''' 'ITALY' 'EQ 4' ELSE '');
 WHERELINE/A26 = IF SELITEM EQ '' OR SELVALS EQ '' THEN '' ELSE '('|SELITEM||' '|SELVALS||')';
END
TABLE FILE CAR
 SUM
    COMPUTE  CONDITION/A32 = IF WHERELINE EQ '' THEN ''
                  ELSE IF (LAST COUNTRY EQ COUNTRY)
                  THEN '   OR ' | TRIM('T', WHERELINE, 26, ' ', 1, 'A26')
                  ELSE 'WHERE ' | TRIM('T', WHERELINE, 26, ' ', 1, 'A26'); AS ''

 BY COUNTRY NOPRINT
 ACROSS CAR NOPRINT
WHERE COUNTRY EQ 'FRANCE' OR 'ITALY' OR 'SPAIN';
END

The result of this query, saved as FORMAT ALPHA, is to be -INCLUDE'd as the WHERE clause in another TABLE FILE query.
For that purpose, obviously, each line should end with a ';'. How do I do that?

Wep,

You can add a COMPUTE'd field at the end like:

...
  BY COUNTRY NOPRINT
  ACROSS CAR NOPRINT
  COMPUTE SC/A1 = ';';
WHERE COUNTRY EQ 'FRANCE' OR 'ITALY' OR 'SPAIN';
END

-Fred

That field will repeat for each ACROSS value though. Without a way to detect that I'm at the last ACROSS value, that won't help.

Hmmm, as far as I know any COMPUTE field you add *after* the ACROSS clause will be appended at the end of the report right after the last ACROSS which seems to be what you wanted. Did you actually try FreSte's suggestion and it didn't work? If that's the case I'll have to revise my old assumptions

I don't think you need the across to do what you want. Try:

  DEFINE FILE CAR
 SELITEM/A8 = DECODE COUNTRY('FRANCE' 'MODEL' 'ITALY' 'SEATS' ELSE '');
 SELVALS/A15 = DECODE COUNTRY('FRANCE' 'EQ ''504 4 DOOR''' 'ITALY' 'EQ 4' ELSE '');
 WHERELINE/A26 = IF SELITEM EQ '' OR SELVALS EQ '' THEN '' ELSE '('|SELITEM||' '|SELVALS||')';
END
TABLE FILE CAR
 SUM 
   COMPUTE C_COUNTRY_CTR/I1 = CNT.CAR; NOPRINT
  BY COUNTRY NOPRINT
 SUM
   COMPUTE C_CAR_CTR/I5 = IF COUNTRY EQ LAST COUNTRY THEN LAST C_CAR_CTR + 1  ELSE 1; NOPRINT
    COMPUTE  CONDITION/A32 = IF WHERELINE EQ '' THEN ''
                  ELSE IF (LAST COUNTRY EQ COUNTRY)
                  THEN '   OR ' | TRIM('T', WHERELINE, 26, ' ', 1, 'A26')
                  ELSE 'WHERE ' | TRIM('T', WHERELINE, 26, ' ', 1, 'A26'); AS ''
   COMPUTE COMMA/A1 = IF C_CAR_CTR EQ C_COUNTRY_CTR THEN ';' ELSE ' '; AS ''
 BY COUNTRY NOPRINT
 BY CAR NOPRINT
WHERE COUNTRY EQ 'FRANCE' OR 'ITALY' OR 'SPAIN';
END

Output:

 
WHERE (MODEL EQ '504 4 DOOR') ; 
WHERE (SEATS EQ 4) 
OR (SEATS EQ 4) ; 

quote:

Originally posted by njsden:
Hmmm, as far as I know any COMPUTE field you add *after* the ACROSS clause will be appended at the end of the report right after the last ACROSS which seems to be what you wanted. Did you actually try FreSte's suggestion and it didn't work? If that's the case I'll have to revise my old assumptions

Doh! I hadn't noticed that the COMPUTE was after the ACROSS and didn't know it would behave differently at that spot.

Thanks for pointing that out.

Does it work for you?

DEFINE FILE CAR
SELITEM/A8 = DECODE COUNTRY('FRANCE' 'MODEL' 'ITALY' 'SEATS' ELSE '');
SELVALS/A15 = DECODE COUNTRY('FRANCE' 'EQ ''504 4 DOOR''' 'ITALY' 'EQ 4' ELSE '');
WHERELINE/A26 = IF SELITEM EQ '' OR SELVALS EQ '' THEN '' ELSE '('|SELITEM||' '|SELVALS||')';
SEMI_COLON/A1 = ';';
END
TABLE FILE CAR
SUM
COMPUTE CONDITION/A32 = IF WHERELINE EQ '' THEN ''
ELSE IF (LAST COUNTRY EQ COUNTRY)
THEN ' OR ' | TRIM('T', WHERELINE, 26, ' ', 1, 'A26')
ELSE 'WHERE ' | TRIM('T', WHERELINE, 26, ' ', 1, 'A26'); AS ''

BY COUNTRY NOPRINT
BY SEMI_COLON AS ''
ACROSS CAR NOPRINT
WHERE COUNTRY EQ 'FRANCE' OR 'ITALY' OR 'SPAIN';
ON TABLE SET NODATA ' '
ON TABLE SET STYLE *
TYPE=REPORT, COLUMN=SEMI_COLON, SEQUENCE=90,$
ENDSTYLE
END

As atturhari shows, you can use the SEQUENCE attribute in the style sheet to change the position of a column in a report.

This SEQUENCE attribute is OK for HTML-output, but for writing to HOLD-files, it doesn't work.
Wep needs these HOLD-files with WHERE-statements for including in other fexes.
I also use this kind of dynamice WHERE-statements; very powerfull

Its actually very easy. It depends on where you put the Compute. In this case put it after the ACROSS. The syntax is..
TABLE FILE CAR
SUM RETAIL_COST
BY COUNTRY
ACROSS BODYTYPE AND COMPUTE NEW= C1 + C3 ;
END

Note that the columns can be identified as C1,C2, etc