I need to create a Compound report.
There will be 5 queries.
The output of the first 3 queries will need to go onto Sheet 1 in the Excel Spreadsheet.
The output of the last 2 queries will need to go onto Sheet 2 in the Excel Spreadsheet.
I can create the Compound report in InfoAssist with all 5 queries using the same selection criteria.
However, when I run the Compound report, each query goes to a separate Sheet in Excel so I end up with 5 Sheets in my Excel Spreadsheets.
How do I tell InfoAssist when to insert a New Sheet (page break)?

Thanks

Eric J. Songy

This message has been edited. Last edited by: Tamra,

Eric,

Unfortunately you are not able to do this using the new Compound Report (Composer tool or InfoAssist)

quote:

There are several requirements and restrictions when using these output formats with coordinated compound reports:
In active report and active Flash output formats:

• Multiple reports and charts combined into one document.
  
• You must have at least one report object.
  
• LINE, IMAGE, and TEXT objects are not supported in the document.
  
• Chart objects are static images, which cannot be altered using active report and active Flash menu options.

Excel:

• Combines multiple reports as different sheets in a workbook.
  
• LINE, IMAGE, and TEXT objects are not supported in the document.

PowerPoint:

• Combines multiple reports, charts in a single slide.
  
• You may embed the output into pre-existing PowerPoint templates.
  
• LINE, IMAGE and TEXT objects are supported.

You will have to do this with the old compound syntax which means coding without a GUI

StuBouyer

Can I insert commands via the Text Editor that would allow 2 or 3 queries on a single sheet with a page break (sheet break) inserted and then 2 or 3 queries on a second sheet?

I have seen references to NOBREAK and I have tried to test that but have not been successful in getting it to work yet. Every query generates a separate sheet in the Excel Workbook.

Thanks

Eric J. Songy

Try creating a new report in the Text Editor and pasting in this code. it created 5 reports over two excel pages.

I assume you have the CAR file available.

TABLE FILE CAR
PRINT SEATS
BY COUNTRY
HEADING
"REPORT 1"
"Page 1"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD AS MYEXCEL FORMAT XLSX OPEN NOBREAK
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ENDSTYLE
END

TABLE FILE CAR 
SUM SALES
BY COUNTRY
HEADING
"REPORT 2"
"Page 1"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD AS MYEXCEL FORMAT XLSX 
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ENDSTYLE
END

TABLE FILE CAR 
SUM DEALER_COST
BY COUNTRY
HEADING
"REPORT 1"
"Page 2"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD AS MYEXCEL FORMAT XLSX  NOBREAK
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ENDSTYLE
END

TABLE FILE CAR 
SUM RETAIL_COST
BY COUNTRY
HEADING
"REPORT 2"
"Page 2"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD AS MYEXCEL FORMAT XLSX  NOBREAK
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ENDSTYLE
END

TABLE FILE CAR
PRINT SEATS SALES DEALER_COST RETAIL_COST
BY COUNTRY
BY CAR
BY MODEL
HEADING
"REPORT 3"
"Page 2"
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE NOTOTAL
ON TABLE PCHOLD AS MYEXCEL FORMAT XLSX  CLOSE
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ENDSTYLE
END

Thanks Stu

I got this working.
Appreciate the help.

Eric J. Songy

how can I save different reports in deticated worksheets within xlsx files?

 INCLUDE = endeflt,
$
SUMMARY='data',
TITLETEXT='data',
$
TYPE=DATA,
     IN-RANGES='T_data',
$
TYPE=TITLE,
     IN-RANGES='T_data',
$
ENDSTYLE
END 

this is working for the first report, but not for the second, obviously with different tab-name.

any ideas?

Have you tried to insert the following line of code (TITLETEXT = 'tab name') as below? You won't need "IN-RANGE = 'T-data'" line.

TABLE FILE CAR
PRINT MODEL
BY COUNTRY
ON TABLE SET STYLE *
TYPE=REPORT,
SIZE=9,
TITLETEXT='Detail',
GRID=ON,
BORDER=OFF,
BACKCOLOR=WHITE,
$
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K OPEN
END
TABLE FILE CAR
COUNT MODEL
BY COUNTRY
ON TABLE SET STYLE *
TYPE=REPORT,
SIZE=9,
TITLETEXT='Summary',
GRID=ON,
BORDER=OFF,
BACKCOLOR=WHITE,
$
ENDSTYLE
ON TABLE PCHOLD FORMAT EXL2K CLOSE
END