Hello,

I am trying to print labels (3.5 height by 5 wide) on the letter pagesize (normal 8.5 by 11),
one after the other vertically.

Our labels are continous form (roughly, will print 3 on a page), overall this comes to 10.5 in height, the width isn't an issue. Leaving
me with .5 gap.

The problem I'm having is that the labels look fine for the first page but they keep gaining 1/16 of an inch on printing, so by the time it
gets to page two I am way off.

I've tried using pagematrix, element, matrixorder and gutter but no luck.

Any suggestions?

Thanks
Craig

Hi Craig,

Here's an example using the CAR file. What does this look like for you?

-**********************************************************************
SET PAGE-NUM=NOPAGE
-*
TABLE FILE CAR
PRINT
COMPUTE CNTR/I6 = CNTR + 1;
BY COUNTRY
BY CAR
BY MODEL
WHERE RECORDLIMIT EQ 8
ON TABLE HOLD AS HLD_LBLS
END
-*
DEFINE FILE HLD_LBLS
CNT/I6 = 1;
T_LINE1/A50 = '**************************************************';
T_LINE2/A50 = '* *';
T_LINE3/A50 = '* CNT: ' | EDIT(CNTR) | ' *';
T_LINE4/A50 = '* COU: ' | COUNTRY | ' *';
T_LINE5/A50 = '* CAR: ' | CAR | ' *';
T_LINE6/A50 = '* MOD: ' | MODEL | ' *';
T_LINE7/A50 = '* *';
T_LINE8/A50 = '**************************************************';
END
TABLE FILE HLD_LBLS
SUM CNT NOPRINT
SUM T_LINE1 AS ''
OVER T_LINE2 AS ''
OVER T_LINE2 AS ''
OVER T_LINE2 AS ''
OVER T_LINE2 AS ''
OVER T_LINE2 AS ''
OVER T_LINE2 AS ''
OVER T_LINE3 AS ''
OVER T_LINE4 AS ''
OVER T_LINE5 AS ''
OVER T_LINE6 AS ''
OVER T_LINE7 AS ''
OVER T_LINE7 AS ''
OVER T_LINE7 AS ''
OVER T_LINE7 AS ''
OVER T_LINE7 AS ''
OVER T_LINE7 AS ''
OVER T_LINE8 AS ''
BY CNTR NOPRINT
ON CNTR PAGE-BREAK
ON TABLE PAGE-BREAK AND SUBHEAD
" "
"FORUM898_LABELS"
"&DATE"
"# OF LABELS: "THIS IS A TEST"
"ONE...TWO...THREE"
ON TABLE SET ONLINE-FMT PDF
ON TABLE SET STYLE *
TYPE=REPORT,
UNITS=IN,
PAGESIZE='Letter',
LEFTMARGIN=0.152778,
RIGHTMARGIN=0.000000,
TOPMARGIN=0.000000,
BOTTOMMARGIN=0.000000,
ORIENTATION=PORTRAIT,
PAGEMATRIX=(1 3),
ELEMENT=(5.000000 3.500000),
GUTTER=(0.000000 0.300000),
MATRIXORDER=VERTICAL,
$
ENDSTYLE
END
-*********************************************************************

Let me know if this helps.

Jim

WF DevStu 5.2.6/WF Srv 5.2.4/Win NT 5.2

Hi Jim,

Thanks for the information.
It's still doing the same thing.

Thanks
Craig

Hi Craig,

Here's another example without using pdf format.

-***************************************************************
-*
SET LINES=999999
SET PAGE-NUM=NOPAGE
SET PAPER=999999
SET NODATA=' '
-*
TABLE FILE CAR
PRINT
COMPUTE CNTR/I6 = CNTR + 1;
BY COUNTRY
BY CAR
BY MODEL
WHERE RECORDLIMIT EQ 8
ON TABLE HOLD AS HLD_LBLS
END
-*
DEFINE FILE HLD_LBLS
CNT/I6 = 1;
T_LINE1/A50 = '**************************************************';
T_LINE2/A50 = '* *';
T_LINE3/A50 = '* CNT: ' | EDIT(CNTR) | ' *';
T_LINE4/A50 = '* COU: ' | COUNTRY | ' *';
T_LINE5/A50 = '* CAR: ' | CAR | ' *';
T_LINE6/A50 = '* MOD: ' | MODEL | ' *';
T_LINE7/A50 = '* *';
T_LINE8/A50 = '**************************************************';
END
-*
TABLE FILE HLD_LBLS
SUM CNT NOPRINT
SUM T_LINE1 AS ''
OVER T_LINE2 AS ''
OVER T_LINE2 AS ''
OVER T_LINE2 AS ''
OVER T_LINE2 AS ''
OVER T_LINE2 AS ''
OVER T_LINE2 AS ''
OVER T_LINE3 AS ''
OVER T_LINE4 AS ''
OVER T_LINE5 AS ''
OVER T_LINE6 AS ''
OVER T_LINE7 AS ''
OVER T_LINE7 AS ''
OVER T_LINE7 AS ''
OVER T_LINE7 AS ''
OVER T_LINE7 AS ''
OVER T_LINE7 AS ''
OVER T_LINE8 AS ''
BY CNTR SKIP-LINE NOPRINT
ON TABLE SAVE AS FORUM898 FORMAT WP
END
-****************************************************************

This creates a file named forum898.wp which is just a continuous
stream of labels. I'm not sure if this will help....but if so..great

Jim

I'm also having an issue with labels trying to figure out what to have set and not to just do an Avery 5260 type 3 by 10. One option on page will give me 12 instead of 10, when I do get 10 they are off allignment. I've tried fixed font, variable font, you name it. Haven't reached the magic combination.

Anyone out there have any experience developing same. I'm Trying to replace the way we currently generate them to print through our mainframe print application to distribute a pdf that can just be printed on label stoc,.

Hi Leah,

Here's an example that worked for me. It prints five lines
at 30 charachters per line.

I'll have to admit...I've had my battles over the years with labels
and I still do.

-*****************************************************************
SET PAGE-NUM=NOPAGE
-*
TABLE FILE CAR
PRINT
COMPUTE CNTR/I6 = CNTR + 1;
BY COUNTRY
BY CAR
BY MODEL
ON TABLE HOLD AS HLD_LBLS
END
-*
DEFINE FILE HLD_LBLS
CNT/I6 = 1;
T_LINE1/A30 = '******************************';
T_LINE2/A30 = 'CNT: ' | EDIT(CNTR) | ' COU: ' | COUNTRY;
T_LINE3/A30 = 'CAR: ' | CAR;
T_LINE4/A30 = 'MOD: ' | MODEL;
T_LINE5/A30 = '******************************';
END
-*
TABLE FILE HLD_LBLS
SUM CNT NOPRINT
SUM T_LINE1 AS ''
OVER T_LINE2 AS ''
OVER T_LINE3 AS ''
OVER T_LINE4 AS ''
OVER T_LINE5 AS ''
BY CNTR NOPRINT
ON CNTR PAGE-BREAK
ON TABLE PAGE-BREAK AND SUBHEAD
" "
"FORUM899_LABELS"
"&DATE"
"# OF LABELS: "TESTING 1, 2, 3 "
ON TABLE SET ONLINE-FMT PDF
-*ON TABLE HOLD AS FORUM899 FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT,
UNITS=IN,
PAGESIZE=LETTER,
LEFTMARGIN=0.235,
TOPMARGIN=0.320,
PAGEMATRIX=(3 10),
ELEMENT=(2.630 1.05),
GUTTER=(0.200 0),
SIZE=10,
MATRIXORDER=HORIZONTAL,
$
ENDSTYLE
END
-********************************************************************

Let me know if this helped.

Jim

WF DevStu 5.2.6/WF Srv 5.2.4/Win NT 5.2

Thanks Jim, I'll try your way and see. Such a pain sometimes. Have a great weekend.

Hi Jim,

I tried all of your examples.
No luck, still doing the same thing.

Thanks for your help.
Craig

It has been a long time since I have had to do labels. I believe this worked for the Avery 3 wide and 11 down.

 TABLE FILE FCLBLA
 PRINT NAME ADDRESS ADDRESS2
    BY ZIP
    ON TABLE HOLD AS FCLBLB
 END
-*
 DEFINE FILE FCLBLA CLEAR
 END
-*
 JOIN BLANK WITH ZIP IN FCLBLB TO BLANK IN MACGYVER
-*
 DEFINE FILE FCLBLB
   BLANK/A1 WITH ZIP=' ';
   LBLCNT/I8 WITH COUNTER=LBLCNT+1;
   LBLROW/I8 WITH COUNTER=(LBLCNT/18)+1;
   NEWROW/I8 WITH COUNTER=LBLCNT-(LBLROW*18)+1;
   LBLPG/I6 WITH COUNTER=IMOD((LBLROW-1),11,'I6')+1;
   LBLLN/A40=IF COUNTER EQ 4 OR 5 OR 6 OR THEN BLANK
        ELSE IF COUNTER EQ 1 THEN NAME
        ELSE IF COUNTER EQ 2 THEN ADDRESS ELSE ADDRESS2;
   PAGELN/I6=(LBLPG-1)*6+COUNTER;
   COLNO/I2=IF (COUNTER NE 1 AND COUNTER NE 7) THEN COLNO
       ELSE IF COLNO EQ 3 THEN 1 ELSE COLNO+1;
   LBLN1/A40=IF COLNO EQ 1 THEN LBLLN ELSE ' ';
   LBLN2/A40=IF COLNO EQ 2 THEN LBLLN ELSE ' ';
   LBLN3/A40=IF COLNO EQ 3 THEN LBLLN ELSE ' ';
 END
 TABLE FILE FCLBLB
   SUM MAX.LBLN1
       MAX.LBLN2
       MAX.LBLN3
    BY LBLROW    NOPRINT
    BY LBLPG     NOPRINT
    BY COUNTER   NOPRINT
    BY PAGELN    NOPRINT
    IF COUNTER LE 6
    IF PAGELN  LT 64
    ON TABLE SAVE AS LABELS
 END
-RUN

In file FCLBLA, the NAME, ADDRESS and ADDRESS2 are all 40 characters. Zip is 5 characters. The ZIP to be printed is in ADDRESS2, this ZIP is just for sorting.

Now the labels are in a flat file that I imported into Word and printed on standard Laser labels. I think the trick is to print all the lines on the page of labels. This prints 64 lines per page. Here's the deal. Since the laser printer cannot print on the first and last line of a page (built in margin), on the physical page, the printing starts on line 2 and prints down to line 65 (64 lines).

To Jim, I just realized yours was one up. Thanks Jgelona, I will try your options.

Anybody have any suggestions for printing
on a customize form size of 8 wide x 10.5
height?

With 3 labels per page of 8 x 3.5 with
printable portion of 5 x 3.5.

Thanks
Craig

Craig,

The closest you'll get to that page size is to specify PAGESIZE=EXECUTIVE in your stylesheet. The actual size is 7 x 10.5 but as its the length you want to hit (mostly) it might be worth a shot?

The only other alternative is to contact IB and request an NFR to allow customisable page sizing.

Good luck

T

Hi Tony,

Thanks I changed the setting to Legal and the
paper size on the printer to 8 1/2 by 14.

This worked for me.

Thanks everyone for your help.
Craig

I want to let everyone know that my label problem (3 by 10 Avery 560) turned out to be that Adobe Acrobat printing was shrinking the form. I changed the adobe print to 'none' on the fit to page options and the label printed fine. Sorry a little late in posting.

Have a great weekend everyone.