Given the following code How can I style the words retail and Dealer DIFFERENTLY IN THE TOTALS SECTION :

 
TABLE FILE CAR
SUM
RETAIL_COST OVER AS 'RETAIL'
DEALER_COST AS 'DEALER'

BY MODEL

ACROSS BODYTYPE

ON TABLE ROW-TOTAL
ON TABLE COLUMN-TOTAL
END
 

Something like this?

TABLE FILE CAR
 SUM
  RETAIL_COST AS 'RETAIL' OVER
  DEALER_COST AS 'DEALER'
 BY MODEL
 ACROSS BODYTYPE
 ON TABLE ROW-TOTAL
 ON TABLE COLUMN-TOTAL
 ON TABLE SET STYLE *
  TYPE=TITLE, COLUMN=RETAIL_COST, COLOR=RED, $
  TYPE=TITLE, COLUMN=DEALER_COST, COLOR=BLUE, $
  TYPE=DATA, COLUMN=ROWTOTAL(1), COLOR=RED, $
  TYPE=DATA, COLUMN=ROWTOTAL(2), COLOR=BLUE, $
 ENDSTYLE
END

EDIT: added styling for row totals.

This message has been edited. Last edited by: Dan Satchell,

Thank you dan but not the quite what I was looking for. add the following line and tell me how to fill in the unshaded area will be self explanitory.

TYPE = GRANDTOTAL,BACKCOLOR= ORANGE,$

Thanks

Looks like a bug to me. TYPE=GRANDTOTAL should include all text and values in the grand total rows. Below is a work-around. You could do the same with a single, multi-verb request, but then you would have the multi-line totals problem. You could probably also accomplish this with a FOOTING/TABFOOT/SUBFOOT, but that requires extra work.

SET HOLDLIST = PRINTONLY
-*
TABLEF FILE CAR
 SUM
  RETAIL_COST/D7
  DEALER_COST/D7
 ON TABLE SAVE AS TOTALS
END
-RUN
-READ TOTALS &TOT_RCOST.7. &TOT_DCOST.7.
-*
TABLE FILE CAR
 SUM
  RETAIL_COST AS 'RETAIL' OVER
  DEALER_COST AS 'DEALER'
 BY MODEL
 ACROSS BODYTYPE
 ON TABLE ROW-TOTAL
 ON TABLE COLUMN-TOTAL
 ON TABLE SET STYLE *
  TYPE=TITLE, COLUMN=RETAIL_COST, BACKCOLOR=ORANGE, WHEN=ROWTOTAL(RETAIL_COST) EQ &TOT_RCOST, $
  TYPE=TITLE, COLUMN=DEALER_COST, BACKCOLOR=ORANGE, WHEN=ROWTOTAL(DEALER_COST) EQ &TOT_DCOST, $
  TYPE=GRANDTOTAL, BACKCOLOR=ORANGE, $
 ENDSTYLE
END

This message has been edited. Last edited by: Dan Satchell,

Duane - I just added couple more styles to Dan's previous code.

SET HOLDLIST = PRINTONLY
-*
TABLEF FILE CAR
SUM
RETAIL_COST/D7
DEALER_COST/D7
ON TABLE SAVE AS TOTALS
END
-RUN
-READ TOTALS &TOT_RCOST.7. &TOT_DCOST.7.
-*
TABLE FILE CAR
SUM
RETAIL_COST AS 'RETAIL' OVER
DEALER_COST AS 'DEALER'
BY MODEL
ACROSS BODYTYPE
ON TABLE ROW-TOTAL
ON TABLE COLUMN-TOTAL
ON TABLE SET STYLE *
TYPE=TITLE, COLUMN=RETAIL_COST, BACKCOLOR=ORANGE, STYLE=BOLD, WHEN=ROWTOTAL(RETAIL_COST) EQ &TOT_RCOST, $
TYPE=TITLE, COLUMN=DEALER_COST, BACKCOLOR=ORANGE, STYLE=BOLD, WHEN=ROWTOTAL(DEALER_COST) EQ &TOT_DCOST, $
TYPE=GRANDTOTAL, BACKCOLOR=ORANGE, $
TYPE=TITLE, COLUMN=RETAIL_COST, COLOR=RED, $
TYPE=TITLE, COLUMN=DEALER_COST, COLOR=BLUE, $
TYPE=DATA, COLUMN=ROWTOTAL(1), COLOR=RED, $
TYPE=DATA, COLUMN=ROWTOTAL(2), COLOR=BLUE, $
TYPE=GRANDTOTAL,
COLUMN=N12,
BACKCOLOR=RGB(204 153 255),
STYLE=BOLD,
$
TYPE=GRANDTOTAL,
COLUMN=N13,
BACKCOLOR=RGB(0 204 255),
STYLE=BOLD,
$
TYPE=GRANDTOTAL,
ACROSSCOLUMN=N1,
FONT='ARIAL',
COLOR='BLACK',
BACKCOLOR=RGB(204 153 255),
STYLE=BOLD,
$
TYPE=GRANDTOTAL,
ACROSSCOLUMN=N2,
FONT='ARIAL',
COLOR='BLACK',
BACKCOLOR=RGB(0 204 255),
STYLE=BOLD,
$
ENDSTYLE
END