Is there a way to view ALL reportcaster schedules that are out there for any user? I want to know when jobs are scheduled and by whom, not just my own.

This message has been edited. Last edited by: <Emily McAllister>,

You need to be an ReportCaster admin and change to Administration/Mode Manager !!! (from the menu options bar on top right)

You need to do this ALL the time because there is no such default setting for admin to be always in Manager Mode...

Thanks for the suggestion to change to Mode Manager. That does allow me to see into everyone's folder, but I'm hoping there is a way to get a list of what all the active schedules are without having to hunt and peck through each users folder.

You can query the DB directly since the repository is in a DB.

Cannot know what is your DB name, but the table's name is : BOTSCHED (and other starting with BOT% are also used by ReportCaster)

SELECT [JOBDESC]
FROM [YourDB].[dbo].[BOTSCHED]
  WHERE ACTIVE = 'Y'

You can also extract much more information about the schedules.

Thanks, I will give that a try.

We whipped up an *.fex to dump Report Caster Scheduled data. This may or may not be helpful for you.

-*Dump of report caster scheduler jobs


JOIN
BOTSCHED.BOTSCHED.PACKETID IN BOTSCHED TO UNIQUE BOTTASK.BOTTASK.PACKETID
IN BOTTASK TAG J0 AS J0
END
JOIN
BOTSCHED.BOTSCHED.SCHEDULEID IN BOTSCHED TO UNIQUE BOTDIST.BOTDIST.SCHEDULEID
IN BOTDIST TAG J1 AS J1
END
JOIN
LEFT_OUTER J1.BOTDIST.DISTLIST IN BOTSCHED TO UNIQUE BOTDEST.BOTDEST.ADDRBOOKID
IN botdest TAG J2 AS J2
END
JOIN
LEFT_OUTER J1.BOTDIST.DISTLIST IN BOTSCHED TO UNIQUE BOTADDR.BOTADDR.IBFSID
IN botaddr TAG J3 AS J3
END



DEFINE FILE BOTSCHED
METHOD/A10 = IF (METHOD_CODE EQ 'M') THEN 'Email' ELSE
             IF (METHOD_CODE EQ 'P') THEN 'Printer' ELSE 'Other';
LIST_T/A25 = IF (LISTTYPE EQ 'D')    THEN 'Distribution List' ELSE
             IF (LISTTYPE EQ 'S')    THEN 'Single Email Address(es)' ELSE 'Other';
PRETTY_TO/A255 = IF (LISTTYPE EQ 'D') THEN J3.DESCRIPTION || ' -- ' || DESTFN ELSE DISTLIST;
END

TABLE FILE BOTSCHED
PRINT
     BOTSCHED.BOTSCHED.LASTEXTIME/HMDYYI
	 LASTEXSTATUS
	 PRETTY_TO
     COMPUTE LIST_TYPE/A25 = IF SCHEDULEID EQ LAST SCHEDULEID THEN '' ELSE LIST_T;
BY  BOTSCHED.BOTSCHED.JOBDESC
BY  BOTSCHED.BOTSCHED.CASTER_USER
BY  BOTSCHED.BOTSCHED.ACTIVE
BY  J1.BOTDIST.METHOD
BY  J1.BOTDIST.MAILSUBJECT
BY  J0.BOTTASK.TASKNAME
-*WHERE ACTIVE EQ 'Y';
ON TABLE SET PAGE-NUM NOLEAD
ON TABLE SET ASNAMES ON
ON TABLE NOTOTAL
ON TABLE PCHOLD FORMAT HTML
ON TABLE SET HTMLEMBEDIMG ON
ON TABLE SET HTMLCSS ON
ON TABLE SET STYLE *
     INCLUDE = IBFS:/EDA/EDASERVE/_EDAHOME/ETC/endeflt.sty,
$
ENDSTYLE
END