Hi,
I want to change the automatic format of the sum in VBRSTK1 graph.
I want only 2 decimales.
I searched in the wf77graph.pdf documentation but did not find.
Any idea ?

  
-SET &A  = EDIT(&YYMD,'9999') ;
-SET &A_1 = &A - 1;
GRAPH FILE CAR
SUM DEALER_COST/D11 AS 'Dons'
    RETAIL_COST/D11 AS 'Partenariats'
    SALES/D11 AS 'Legs'
BY COUNTRY NOPRINT
BY SEATS AS ' '
WHERE COUNTRY EQ 'FRANCE' OR 'JAPAN' OR 'ENGLAND'
FOOTING
" "
"                            Collecte totale"

ON GRAPH PCHOLD FORMAT PNG
ON GRAPH SET HTMLENCODE ON
ON GRAPH SET GRAPHDEFAULT OFF
ON GRAPH SET VZERO OFF
ON GRAPH SET HAXIS 800
ON GRAPH SET VAXIS 600
ON GRAPH SET UNITS PIXELS
ON GRAPH SET LOOKGRAPH VBRSTK1
ON GRAPH SET GRMERGE ADVANCED
ON GRAPH SET GRMULTIGRAPH 0
ON GRAPH SET GRLEGEND 0
ON GRAPH SET GRXAXIS 2
ON GRAPH SET GRAPHSTYLE *
setReportParsingErrors(false);
setSelectionEnableMove(false);
setTransparentBorderColor(getSeries(0),true);
setTransparentBorderColor(getSeries(1),true);
setTransparentBorderColor(getSeries(2),true);
setDepthRadius(5);
setTransparentBorderColor(getChartBackground(),true);
setPlace(true);
-* Présentation valeurs graduations
setTextFormatPreset(getY1Label(),10);
-* Collecte privée - couleur bleu foncé
setFillColor(getSeries(0),new Color(0,0,218));
-* Collecte partenariats - fuschia
setFillColor(getSeries(1),new Color(255,51,204));
-* Collecte legs - vert anis
setFillColor(getSeries(2),new Color(204,255,51));

setDisplay(getO1Label(),false);
setTextString(getAnnotation(0),"&A_1");
setDisplay(getAnnotation(0),true);
setRect(getAnnotation(0),new Rectangle(-12000.0,-14060.0,8000.0,1939.0));
setTextString(getAnnotation(1),"&A");
setDisplay(getAnnotation(1),true);
setRect(getAnnotation(1),new Rectangle(-4266.0,-14157.0,8000.0,2036.0));
setTextString(getAnnotation(2),"Objectifs");
setDisplay(getAnnotation(2),true);
setRect(getAnnotation(2),new Rectangle(4000.0,-14060.0,8000.0,1939.0));
setLegendTextAutosize(false);
setTextFormatPreset(getDataTextStackedTotalOnTop(), 16);
setTextFormatPattern(getDataTextStackedTotalOnTop(),"$### ### ###.##");
-*setDataTextFormat(16);
-*setTextFormatPattern(getDataTextStackedTotalOnTop(),"###,###,###,###.##");

setDisplay(getDataTextStackedTotalOnTop(), true);

ENDSTYLE
ON GRAPH SET STYLE *
TYPE=FOOTING,LINE=2,OBJECT=TEXT,ITEM=1,FONT='VERDANA',COLOR=RGB(255 140 0),STYLE=BOLD,$
ENDSTYLE

END

This message has been edited. Last edited by: Cati - France,

Hi,
After lots of tries, I found the solution. Instead of DataTextStackedTotalonTop, I use this :

setRect(getAnnotation(2),new Rectangle(4000.0,-14060.0,8000.0,1939.0));
setLegendTextAutosize(false);

setFontName(getDataText(),"Courier New");
setFontSizeAbsolute(getDataText(), true);
setFontSizeInPoints(getDataText(), 10);
setPlaceResize(getDataText(), 0);
setFillColor(getDataText(),new Color(0,0,0));
setStackedDataValueSum(true);
setTextFormatPreset(getDataText(),-1);
setTextFormatPattern(getDataText(),"###,###,###");
setDisplay(getDataText(),true);
setDisplay(getDataText(0), false);
setDisplay(getDataText(1), false);

Catherine