I have a .fex that pulls the period of the year as of the system date. I would then like to take the period and derive -SET & variables from it. I am unsure how to do pass the period value to the -SET command.

TABLE FILE FTVFSPD
BY  FTVFSPD_FSPD_CODE
WHERE ( FTVFSPD.FTVFSPD.FTVFSPD_COAS_CODE EQ '1' ) AND ( FTVFSPD.FTVFSPD.FTVFSPD_PRD_START_DATE LE &YYMD ) AND ( FTVFSPD.FTVFSPD.FTVFSPD_PRD_END_DATE GE &YYMD );
ON TABLE HOLD
END  


-SET &PERIOD=FTVFSPD_FSPD_CODE IN FILE HOLD; (This doesn't work)

Is there a way to get this to work?

This message has been edited. Last edited by: Trudy,

Look into the -READ and -READFILE commands.

You need to pull out the values via these command statements before you can use the values you are looking to utilize in -SETs. The -READFILE command will automagically place the values in your request into DM variables for you.

I would also suggest using HOLD AS {your hold file name} FORMAT ALPHA

And read from that file.

Using HOLD is unsafe if its used elsewhare

-READ Example ...

-*
TABLE FILE CAR
PRINT
COUNTRY
CAR
MODEL
BODYTYPE
SEATS
DEALER_COST
WHERE RECORDLIMIT EQ 1
ON TABLE HOLD AS MY_VARS FORMAT ALPHA
END
? HOLD MY_VARS
-RUN
-READ MY_VARS &VAR1.A10. &VAR2.A16. &VAR3.A24. &VAR4.A12. &VAR5.I3. &VAR6.I7.
-TYPE -------------------------------------------
-TYPE VAR1 ---------- &VAR1
-TYPE VAR2 ---------- &VAR2
-TYPE VAR3 ---------- &VAR3
-TYPE VAR4 ---------- &VAR4
-TYPE VAR5 ---------- &VAR5
-TYPE VAR6 ---------- &VAR6
-TYPE -------------------------------------------

-READFILE Example ...

-*
TABLE FILE CAR
PRINT
COUNTRY
CAR
MODEL
BODYTYPE
SEATS
DEALER_COST
WHERE RECORDLIMIT EQ 1
ON TABLE HOLD AS HLD_VARS
END
? HOLD HLD_VARS
-RUN
-READFILE HLD_VARS
-TYPE --------------------------------
-TYPE COUNTRY --------- &COUNTRY
-TYPE CAR ------------- &CAR
-TYPE MODEL ----------- &MODEL
-TYPE BODYTYPE -------- &BODYTYPE
-TYPE SEATS ----------- &SEATS
-TYPE DEALER_COST ----- &DEALER_COST
-TYPE --------------------------------