Hi Guys,

I know this should be easy but cannot get it at the moment. How do I convert a long date, eg FEBRUARY 02 1982 to YYMD in my fex procedure?

Thanks

This message has been edited. Last edited by: FP Mod Chuck,

Hi ration ,

Can you please confirm what is the date format in data base .

Hi Chaudhary,

Actually not getting it from a database but getting the date in that format from the calendar tool and would like to convert it to YYMD.

Are you trying to change the format of the Calendar selection or the format of the field it populates? I don't think you can change the display format of the Calendar date picker. But if you're trying to change the format of the variable you're populating for display in the report, then you can use a DEFINE to make it display YYMD.

BabaNYC, I'm actually trying to take the date I get from the Calendar (eg April 13, 2018) and subtract 90 days from it. So I'm trying to change the format of the variable so I can do the DATEADD. Can you give me an example of the DEFINE on the variable?

Thanks

Which brings us back to Chaudhary's question. What's the format of the date field you're populating with this variable? So, for instance, if you have a WHERE MYDATE EQ &DATE_VAR then you need to tell us what the format of the field MYDATE is. If you're not sure, you can hover over it in InfoAssist and it'll give you a popup with the format. The calculations will be performed on that field not the &DATE_VAR.

Oh ok. The format would be I8YYMD so 20180413

You'll need something like this:

 90DAYSAGO/I8YMD = AYMD(HIRE_DATE, -90, 90DAYSAGO); 

https://webfocusinfocenter.inf...lang/source/aymd.htm

Thanks BabaNYC and Chaudhary. I was able to get what I wanted.

I see that you already have this taken care of. However, if you'd like my 2¢ then you can look at what I would do to create new variables in an I8YYMD format:

 
-DEFAULTH &DATE_CONVT='';
-DEFAULTH &DATE_90AGO='';

DEFINE FILE CAR
DATE_BEGIN/A17='&DATE_START.(|FORMAT=YYMD).From Date.';
DATE_CONVT/YYMD=HINPUT(17, DATE_BEGIN, 20, 'HYYMD'); 
DATE_90AGO/YYMD=DATEADD(DATE_CONVT, 'D', -90);
END

TABLE FILE CAR
SUM DATE_CONVT DATE_90AGO
BY CAR NOPRINT
WHERE CAR EQ 'AUDI';
ON TABLE HOLD AS NEWAMPERS FORMAT BINARY
END
-RUN
-READFILE NEWAMPERS

-TYPE &|DATE_START [&DATE_START.TYPE&DATE_START.LENGTH] = &DATE_START
-TYPE &|DATE_CONVT [&DATE_CONVT.TYPE&DATE_CONVT.LENGTH] = &DATE_CONVT 
-TYPE &|DATE_90AGO [&DATE_90AGO.TYPE&DATE_90AGO.LENGTH] = &DATE_90AGO 

When selecting today's date I get the following output:

 
0 NUMBER OF RECORDS IN TABLE=        1  LINES=      1 
&DATE_START [A13] = April 20 2018
&DATE_CONVT [N08] = 20180420
&DATE_90AGO [N08] = 20180120

From what I understand (please if someone knows differently, I'm all ears), amper variables can only store alpha or numeric data. So you cannot use an actual date format in a variable and do date calculations in the dialog manager.

This message has been edited. Last edited by: Hallway,

Hallway

You are correct, you would have to create a DEFINE'd field in DATE format to do the calculations.

So I just found this gem by Francis Mariani that explains how to create your own function to do date calculations in DM:

Simplifying the Use of Date Functions in Dialogue Manager

So my example above can be simplified to this:

  
DEFINE FUNCTION UDATEADD(INDATE/A17, INUNIT/A2, INNBR/I4)
INDATE_YYMD/YYMD = HINPUT(17, INDATE, 20, 'HYYMD');
UDATEADD/I8YYMD  = DATEADD(INDATE_YYMD, INUNIT, INNBR);
END
-RUN

-SET &DATE_START = &DATE_START.(|FORMAT=YYMD).From Date.;
-SET &DATE_90AGO = UDATEADD('&DATE_START.EVAL', 'D', -90);

-TYPE &|DATE_START [&DATE_START.TYPE&DATE_START.LENGTH] = &DATE_START
-TYPE &|DATE_90AGO [&DATE_90AGO.TYPE&DATE_90AGO.LENGTH] = &DATE_90AGO

This message has been edited. Last edited by: Hallway,

BEST. SIGNATURE. EVER!! ^^^^^^^^^^

quote:

Originally posted by Hallway:
So I just found this gem by Francis Mariani that explains how to create your own function to do date calculations in DM:

Simplifying the Use of Date Functions in Dialogue Manager

So my example above can be simplified to this:

  
DEFINE FUNCTION UDATEADD(INDATE/A17, INUNIT/A2, INNBR/I4)
INDATE_YYMD/YYMD = HINPUT(17, INDATE, 20, 'HYYMD');
UDATEADD/I8YYMD  = DATEADD(INDATE_YYMD, INUNIT, INNBR);
END
-RUN

-SET &DATE_START = &DATE_START.(|FORMAT=YYMD).From Date.;
-SET &DATE_90AGO = UDATEADD('&DATE_START.EVAL', 'D', -90);

-TYPE &|DATE_START [&DATE_START.TYPE&DATE_START.LENGTH] = &DATE_START
-TYPE &|DATE_90AGO [&DATE_90AGO.TYPE&DATE_90AGO.LENGTH] = &DATE_90AGO

Thanks Hallway for posting the simplified version. Its GREAT!
And I agree with CoolGuy... awesome signature!