I have a report in which i m wrapping data to few inches as well as giving leftgap there but that leftgap is applicable to first line only, how can we add leftgap to subsequent lines of that field

reflection,

I assume you are doing this in a HEADING? Here are a few suggestions.

1) Turn off global BORDER and GRID settings for the report (TYPE=REPORT, [GRID=OFF,] or [BORDER=OFF,]$).

2) Apply GRID settings to DATA and/ot TITLE locally if desired (TYPE=DATA or TYPE=TITLE).

2) In addition to the WRAP setting, use the POSITION setting with absolute positioning to position the left edge of the field in the HEADING which needs to be wrapped.

TYPE=HEADING, LINE=#, OBJECT=FIELD, ITEM=#, POSITION=#.##, WRAP=#.##,$

I have noticed through usage and experience that when the GRID or BORDERS are ON for the HEADING, you can experience problems with LEFTGAPS on HEADING items. I have a case open with IBI in regards to this type of issue.

I hope this helps.

reflection,

Here's a better solution.

It seems the issue with the LEFTGAP happens only for the first item on the HEADING line. Therefore put a dummy blank space on the HEADING line before the field in the HEADING line. Doing this will allow you to keep your global GRID or BORDER line settings.

Try the following to see how this works. Notice the blank space before the "<CNTYTEXT>" field in the HEADING.

TABLE FILE CAR
PRINT DEALER_COST RETAIL_COST SALES
COMPUTE CNTYTEXT/A20='Country: ' | COUNTRY; NOPRINT
BY COUNTRY NOPRINT PAGE-BREAK
BY CAR
BY MODEL
BY BODYTYPE
HEADING
" <CNTYTEXT>"
ON TABLE SET PAGE NOPAGE
ON TABLE SET HTMLCSS ON
ON TABLE PCHOLD FORMAT PDF
ON TABLE SET STYLE *
TYPE=REPORT, ORIENTATION=LANDSCAPE, SQUEEZE=ON, GRID=ON,
LEFTGAP=0.25, RIGHTGAP=.25,$
TYPE=REPORT, COLUMN=CAR , WRAP=1.00,$
TYPE=REPORT, COLUMN=MODEL , WRAP=2.00,$
TYPE=REPORT, COLUMN=BODYTYPE , WRAP=1.25,$
TYPE=REPORT, COLUMN=DEALER_COST, WRAP=1.25,$
TYPE=REPORT, COLUMN=RETAIL_COST, WRAP=1.25,$
TYPE=REPORT, COLUMN=SALES , WRAP=1.00,$
TYPE=HEADING, HEADALIGN=BODY,$
TYPE=HEADING, LINE=1, OBJECT=FIELD, ITEM=1, POSITION=1.75,
WRAP=1.10, JUSTIFY=LEFT,$
ENDSTYLE
END